请问各位 用ADO SQL 提取数据 表名不固定的解决方法

那年的坏人

用SQL 提取销售表的数据，因为是ERP系统导出的原始数据，每次导出sheet名都是乱的。
不知道怎么写~ 求大 ceshi.zip (28.77 KB, 下载次数: 12)

2020-1-2 12:40 上传

点击文件名下载附件

佬们 帮忙~~

那年的坏人

Sub test1()
    Dim cnn As Object, rst As Object
    Dim strPath As String, str_cnn As String, strSQL As String
    Dim i As Long
    Set cnn = CreateObject("adodb.connection")
            str_cnn = "Provider=Microsoft.ACE.OLEDB.12.0;Extended Properties=Excel 12.0;Data Source=" & ThisWorkbook.Path & "/销售.xls"
            cnn.Open str_cnn
            strSQL = "SELECT 店铺代码,店铺名称,店铺供货等级,年份,商品代码 FROM [??$] "
            Set rst = cnn.Execute(strSQL)
            Cells.ClearContents
            For i = 0 To rst.Fields.Count - 1
                Sheet1.Cells(1, i + 1) = rst.Fields(i).Name
            Next
            Sheet1.Range("A2").CopyFromRecordset rst
            cnn.Close
            Set cnn = Nothing
End Sub

我是来讨说法的

strSQL = "SELECT 店铺代码,店铺名称,店铺供货等级,年份,商品代码 FROM [" & activesheet.name & "$] "

罗达

那年的坏人 发表于 2020-1-2 12:41
Sub test1()
    Dim cnn As Object, rst As Object
    Dim strPath As String, str_cnn As String, str ...

用参数解决

那年的坏人

罗达 发表于 2020-1-2 13:02
用参数解决

大佬，能具体点么~~ 小白~~

魂断蓝桥

那年的坏人 发表于 2020-1-2 12:41
Sub test1()
    Dim cnn As Object, rst As Object
    Dim strPath As String, str_cnn As String, str ...

            strSQL = "SELECT 店铺代码,店铺名称,店铺供货等级,年份,商品代码 FROM [@__@$]

wodewan

openschema(20)直接取表名试试看。
Sub test1()
    Dim cnn As Object, rst As Object
    Dim strPath As String, str_cnn As String, strSQL As String
    Dim i As Long, Rst_schema, m As Integer
    Set cnn = CreateObject("adodb.connection")
    str_cnn = "Provider=Microsoft.ACE.OLEDB.12.0;Extended Properties=Excel 12.0;Data Source=" & ThisWorkbook.Path & "\销售.xls"
    cnn.Open str_cnn
    Set Rst_schema = cnn.openschema(20)
    Do Until Rst_schema.EOF
        m = m + 1
        If Rst_schema.Fields("TABLE_TYPE").Value = "TABLE" Then shtname = Rst_schema.Fields("TABLE_NAME").Value
        Rst_schema.MoveNext
    Loop
    If m > 1 Then MsgBox "源数据不止一张表格,请检查！": Exit Sub
    strSQL = "SELECT 店铺代码,店铺名称,店铺供货等级,年份,商品代码 FROM [" & shtname & "]"
    Set rst = cnn.Execute(strSQL)
    Cells.ClearContents
        For i = 0 To rst.Fields.Count - 1
            Sheet1.Cells(1, i + 1) = rst.Fields(i).Name
        Next
    Sheet1.Range("A2").CopyFromRecordset rst
    cnn.Close
    Set cnn = Nothing
End Sub

cui26896

wodewan 发表于 2020-1-2 14:32
openschema(20)直接取表名试试看。
Sub test1()
    Dim cnn As Object, rst As Object

这应该是首选方案，ADO专有的。