快速遍历某一列数量不等的值，判断是否在另一列中出现，返回相应值。

西柚果果

有两列数据分别为PN和CP，且PN行数多于CP行数，PN和CP单元格中包含数量不等的内容。现在要对CP内容进行处理，判断CP单元格内的每个文本（以分号分隔）否包含于PN某一个单元格，如果不包含，直接保留，如果包含，就让PN第一个值代替，如下图所示，其案例如附件所示，多谢大佬。

一把小刀闯天下

Option Explicit

Sub test()
  Dim arr, dic(1), i As Long, j As Long, t
  For i = 0 To UBound(dic)
    Set dic(i) = CreateObject("scripting.dictionary")
  Next
  arr = Range("b2:c" & Cells(Rows.Count, "b").End(xlUp).Row)
  For i = 1 To UBound(arr, 1)
    t = Split(arr(i, 1), ";")
    For j = 0 To UBound(t)
      dic(0)(t(j)) = i
    Next
    dic(1)(i) = t(0)
  Next
  For i = 1 To UBound(arr, 1)
    If Len(arr(i, 2)) = 0 Then Exit For
    t = Split(arr(i, 2), ";")
    For j = 0 To UBound(t)
      If dic(0).exists(t(j)) Then t(j) = dic(1)(dic(0)(t(j)))
    Next
    arr(i, 1) = Join(t, ";")
  Next
  [f2].Resize(i - 1) = arr
End Sub

oritusyo

大牛，厉害！！！

西柚果果

一把小刀闯天下 发表于 2019-12-7 07:20
Option Explicit

Sub test()

多谢大牛指导，牛！

西柚果果

一把小刀闯天下 发表于 2019-12-7 07:20
Option Explicit

Sub test()

你好，我用您上面的代码确实可以实现单个字符的匹配，可是我真实的数据是字符串（以分号分隔），如果换成字符串这个代码就不起作用了，求问大佬如何解决。非常抱歉前期做的案例不是字符串形式的。。。。

西柚果果

西柚果果 发表于 2019-12-7 11:33
你好，我用您上面的代码确实可以实现单个字符的匹配，可是我真实的数据是字符串（以分号分隔），如果换成 ...

大佬，问题已解决，叨扰了

liangmutou01

Sub cl()
  Application.ScreenUpdating = False
  Range("d2:d65536").ClearContents
  ar = Range("a1").CurrentRegion.Value
  For h = 2 To UBound(ar)
    If ar(h, 3) = "" Then Exit For
    ls = Split(ar(h, 3), ";")
    For lsh = 0 To UBound(ls)
      For pnh = 2 To UBound(ar)
        If InStr(ar(pnh, 2), ls(lsh)) > 0 Then
          ar(h, 4) = ar(h, 4) & ";" & ar(pnh, 1)
          Exit For
        End If
      Next pnh
      If ar(h, 4) = "" Then _
       ar(h, 4) = ar(h, 4) & ";" & ls(lsh)
    Next lsh
    ar(h, 4) = Mid(ar(h, 4), 2)
  Next h
  Range("a1").Resize(UBound(ar), UBound(ar, 2)) = ar
  Application.ScreenUpdating = True
End Sub