如何自动将图片批量插入到单元格

xiongying07

救助各位大神：我的图片放在文件夹里，图片命名方式和数据表第二列的名称相同，实现批量插入图片，图片的大小自动调整按合并单元格的大小自动调整。附件里有表格和图片，急盼各位大神帮助。万分感谢

larer

论坛里这种代码多了去了,自已找找修改一下就好了.如果要求完美,就联系我

liulang0808

http://club.excelhome.net/thread-1441877-1-1.html
这个帖子楼主可以参考下的

一把小刀闯天下

'你这照片文件名数字后面还有空格的

'输出在"数据"工作表，"打印"工作表很多编号没有，方法一样自己修改，，，

Option Explicit

Sub test()
  Dim i, t, pth, rng
  pth = ThisWorkbook.Path & "\"
  With Sheets("数据")
    For Each i In .Shapes
      i.Delete
    Next
    For i = 2 To .Cells(Rows.Count, "b").End(xlUp).Row
      If Len(.Cells(i, "b").Value) = 0 Then Exit For
      t = pth & .Cells(i, "b").Value & ".JPG"
      t = Replace(t, "(", " (")
      If Len(Dir(t)) > 0 Then
        Set rng = .Cells(i, "e")
        With .Pictures.Insert(t)
          .ShapeRange.LockAspectRatio = msoFalse
          .Top = rng.Top + 1
          .Left = rng.Left + 1
          .Height = rng.Height - 1
          .Width = rng.Width - 1
        End With
      End If
    Next
  End With
End Sub

xiongying07

一把小刀闯天下 发表于 2019-11-18 11:39
'你这照片文件名数字后面还有空格的

'输出在"数据"工作表，"打印"工作表很多编号没有，方法一样自己修改 ...

我已经修改过了，请看看。谢谢。

一把小刀闯天下

xiongying07 发表于 2019-11-18 15:24
我已经修改过了，请看看。谢谢。

'文件打开非常慢，估计里面都是公式的吧，，，

员工定制-测试-（按照工号插入图片）a.rar (104.59 KB, 下载次数: 11)

2019-11-18 20:17 上传

点击文件名下载附件

Option Explicit

Sub test()
  Dim i, t, pth, rng As Range
  Application.ScreenUpdating = False
  pth = ThisWorkbook.Path & "\"
  With Sheets("打印")
    For Each i In .Shapes
      i.Delete
    Next
    For Each rng In .UsedRange
      If rng.Value = "工号:" And Len(rng.Offset(, 1).Value) Then
        t = pth & rng.Offset(, 1).Value & ".JPG"
        If Len(Dir(t)) > 0 Then
          Set rng = rng.Offset(-4, -1).Resize(5)
          With .Pictures.Insert(t)
            .ShapeRange.LockAspectRatio = msoFalse
            .Top = rng.Top + 1
            .Left = rng.Left + 1
            .Height = rng.Height - 1
            .Width = rng.Width - 1
          End With
        End If
      End If
    Next
  End With
  Application.ScreenUpdating = True
End Sub

xiongying07

一把小刀闯天下 发表于 2019-11-18 20:18
'文件打开非常慢，估计里面都是公式的吧，，，

是的，公式比较多。有什么优化建议么？

xiongying07

xiongying07 发表于 2019-11-18 21:14
是的，公式比较多。有什么优化建议么？

请老师帮修改，谢谢。

xiongying07

请各位老师，帮忙解决两个问题：
1.图片错位的问题。运行完了之后，从第三行开始没有按照要求对齐。
2.添加清除图片代码，但是保留按钮和公司图标。