WORD中怎么可以利用宏把小写金额数字转换为大写金额？

liuyizhong

求助：WORD中怎么可以利用宏把小写金额数字转换为大写金额？

月关

liuyizhong

Option Explicit
Sub 小写金额变大写()
  Dim Numeric As Currency, IntPart As Long, DecimalPart As Byte, MyField As Field, Lable As String
  Dim Jiao As Byte, Fen As Byte, Oddment As String, Odd As String, MyChinese As String
  Const ZWDX As String = "壹贰叁肆伍陆柒捌玖零"   '定义一个中文大写汉字常量
  On Error Resume Next   '错误忽略
  With Selection
    Numeric = VBA.Round(VBA.Val(.Text), 2)   '四舍五入保留小数点后两位
    '判断是否在表格中
    If .Information(wdWithInTable) Then _
.MoveRight unit:=wdCell Else .MoveRight unit:=wdCharacter
    '对数据进行判断,是否在指定的范围内
    If VBA.Abs(Numeric) > 2147483647 Then MsgBox "数值超过范围!", _
                                  vbOKOnly + vbExclamation, "Warning": Exit Sub
    IntPart = Int(VBA.Abs(Numeric))   '定义一个正整数
    Odd = VBA.IIf(IntPart = 0, "", "圆")   '定义一个STRING变量
    '插入中文大写前的标签
    Lable = VBA.IIf(Numeric = VBA.Abs(Numeric), "人民币金额大写:　", "人民币金额大写:　负")
    '对小数点后面二位数进行择定
    DecimalPart = (VBA.Abs(Numeric) - IntPart) * 100
    Select Case DecimalPart
    Case Is = 0   '如果是0,即是选定的数据为整数
        Oddment = VBA.IIf(Odd = "", "", Odd & "整")
    Case Is < 10   '<10,即是零头是分
        Oddment = VBA.IIf(Odd <> "", "圆零" & VBA.Mid(ZWDX, DecimalPart, 1) & "分", _
                    VBA.Mid(ZWDX, DecimalPart, 1) & "分")
    Case 10, 20, 30, 40, 50, 60, 70, 80, 90   '如果是角整
        Oddment = "圆" & VBA.Mid(ZWDX, DecimalPart / 10, 1) & "角整"
    Case Else   '既有角,又有分的情况
        Jiao = VBA.Left(CStr(DecimalPart), 1)   '取得角面值
        Fen = VBA.Right(CStr(DecimalPart), 1)   '取得分面值
        Oddment = Odd & VBA.Mid(ZWDX, Jiao, 1) & "角"   '转换为角的中文大写
        Oddment = Oddment & VBA.Mid(ZWDX, Fen, 1) & "分"   '转换为分的中文大写
    End Select
    '指定区域插入中文大写格式的域
    Set MyField = .Fields.Add(Range:=.Range, Text:="= " & IntPart & " *CHINESENUM2")
    MyField.Select   '选定域(最后是用指定文本覆盖选定区域)
    '如果仅有角分情况下,Mychinese为""
    MyChinese = VBA.IIf(MyField.Result <> "零", MyField.Result, "")
    .Text = Lable & MyChinese & Oddment
  End With
End Sub



网上有VBA，但是我试了下，出现错误提示：未定义的书签

liuyizhong

请哪位大侠看一下VBA代码，不知道为什么会出现错误？

413191246se

楼主，请注意板块！既然是在 Word 中，就不要在 Excel 板块提问。楼主，请参见我的宏代码，其中《人民币中文大写》宏可以满足你的要求。
http://club.excelhome.net/thread-1503844-1-1.html

zyc2006

liuyizhong 发表于 2019-10-17 16:53
Option Explicit
Sub 小写金额变大写()
  Dim Numeric As Currency, IntPart As Long, DecimalPart As By ...

Set MyField = .Fields.Add(Range:=.Range, Text:="= " & IntPart & " *CHINESENUM2")差一个\
你改为
Set MyField = .Fields.Add(Range:=.Range, Text:="= " & IntPart & " \*CHINESENUM2")