ExcelHome技术论坛

 找回密码
 免费注册

QQ登录

只需一步,快速开始

快捷登录

搜索
EH技术汇-专业的职场技能充电站 妙哉!函数段子手趣味讲函数 Excel服务器-会Excel,做管理系统 Excel Home精品图文教程库
HR薪酬管理数字化实战 Excel 2021函数公式学习大典 Excel数据透视表实战秘技 打造核心竞争力的职场宝典
300集Office 2010微视频教程 数据工作者的案头书 免费直播课集锦 ExcelHome出品 - VBA代码宝免费下载
用ChatGPT与VBA一键搞定Excel WPS表格从入门到精通 Excel VBA经典代码实践指南
查看: 1890|回复: 8

[求助] 数据量庞大,VBA运行超级慢

[复制链接]

TA的精华主题

TA的得分主题

发表于 2019-10-11 12:38 | 显示全部楼层 |阅读模式
微信图片_20191011123420.png
实现判断销售日期在哪个时间范围内,然后显示对应的销售员是谁
(同一产品同一门店,起止日期是不会重复的)


这是精简过的表,原始表的数据左表有6000多条,右表多达11W条,不知道有没有办法精简一下已达到加速目的,万分感谢

附件已上传
  1. Sub TEXT()
  2. ARR = Range("A1").CurrentRegion
  3. BRR = Range("H1").CurrentRegion
  4. For I = 2 To UBound(BRR)
  5.     S1 = BRR(I, 2) & "+" & BRR(I, 3)
  6.     For J = 2 To UBound(ARR)
  7.         S2 = ARR(J, 3) & "+" & ARR(J, 4)
  8.         If S1 = S2 Then
  9.             If BRR(I, 1) >= ARR(J, 1) And BRR(I, 1) <= ARR(J, 2) Then
  10.                BRR(I, 5) = ARR(J, 5): BRR(I, 6) = ARR(J, 6) * BRR(I, 4)
  11.             End If
  12.         End If
  13.     Next
  14. Next
  15. Range("H1").CurrentRegion = BRR
  16. End Sub
复制代码


求助.rar

21.47 KB, 下载次数: 26

TA的精华主题

TA的得分主题

发表于 2019-10-11 12:50 | 显示全部楼层
[广告] Excel易用宝 - 提升Excel的操作效率 · Excel / WPS表格插件       ★免费下载 ★       ★ 使用帮助
把你那6000的和11w的文件传上来玩一下

TA的精华主题

TA的得分主题

发表于 2019-10-11 13:07 | 显示全部楼层
'假设C、D列有序,然后A列升序,,,

Option Explicit

Sub test()
  Dim arr, brr, dic(1), i As Long, j As Long, s As String
  For i = 0 To UBound(dic)
    Set dic(i) = CreateObject("scripting.dictionary")
  Next
  arr = [a1].CurrentRegion.Offset(1).Resize(, 6).Value
  For i = 1 To UBound(arr, 1) - 1
    s = arr(i, 3) & arr(i, 4)
    If dic(0).exists(s) = False Then dic(0)(s) = i
    dic(1)(s) = dic(1)(s) + 1
  Next
  brr = [h1].CurrentRegion.Offset(1).Resize(, 6).Value
  For i = 1 To UBound(arr, 1) - 1
    s = brr(i, 2) & brr(i, 3)
    If dic(0).exists(s) Then
      For j = dic(0)(s) To dic(0)(s) + dic(1)(s) - 1
        If brr(i, 1) >= arr(j, 1) And brr(i, 1) <= arr(j, 2) Then
          brr(i, 5) = arr(j, 5): brr(i, 6) = arr(j, 6) * brr(i, 4)
          Exit For
        End If
      Next
      If j = dic(0)(s) + dic(1)(s) Then
        brr(i, 5) = vbNullString: brr(i, 6) = brr(i, 5)
      End If
    Else
      brr(i, 5) = vbNullString: brr(i, 6) = brr(i, 5)
    End If
  Next
  [q2].Resize(UBound(brr, 1) - 1, UBound(brr, 2)) = brr
End Sub

评分

2

查看全部评分

TA的精华主题

TA的得分主题

发表于 2019-10-11 13:23 | 显示全部楼层

TA的精华主题

TA的得分主题

发表于 2019-10-11 13:25 | 显示全部楼层
[广告] VBA代码宝 - VBA编程加强工具 · VBA代码随查随用  · 内置多项VBA编程加强工具       ★ 免费下载 ★      ★使用手册
'A-F列可以无序,,,

Option Explicit

Sub test()
  Dim arr, brr, dic(1), i As Long, j As Long, s As String
  For i = 0 To UBound(dic)
    Set dic(i) = CreateObject("scripting.dictionary")
  Next
  arr = [a1].CurrentRegion.Offset(1).Resize(, 7).Value
  For i = 1 To UBound(arr, 1) - 1
    arr(i, 7) = arr(i, 3) & arr(i, 4)
  Next
  Call qsort(arr, 1, UBound(arr, 1) - 1, 1, UBound(arr, 2), 7)
  For i = 1 To UBound(arr, 1) - 1
    If arr(i, 7) <> arr(i + 1, 7) Then
      Call qsort(arr, j + 1, i, 1, UBound(arr, 2), 1)
      dic(0)(arr(i, 7)) = j + 1: dic(1)(arr(i, 7)) = i - j: j = i
    End If
  Next
  brr = [h1].CurrentRegion.Offset(1).Resize(, 6).Value
  For i = 1 To UBound(arr, 1) - 1
    s = brr(i, 2) & brr(i, 3)
    If dic(0).exists(s) Then
      For j = dic(0)(s) To dic(0)(s) + dic(1)(s) - 1
        If brr(i, 1) >= arr(j, 1) And brr(i, 1) <= arr(j, 2) Then
          brr(i, 5) = arr(j, 5): brr(i, 6) = arr(j, 6) * brr(i, 4)
          Exit For
        End If
      Next
      If j = dic(0)(s) + dic(1)(s) Then
        brr(i, 5) = vbNullString: brr(i, 6) = brr(i, 5)
      End If
    Else
      brr(i, 5) = vbNullString: brr(i, 6) = brr(i, 5)
    End If
  Next
  [h2].Resize(UBound(brr, 1) - 1, UBound(brr, 2)) = brr
End Sub

Sub qsort(arr, first, last, left, right, key)
  Dim i As Long, j As Long, k As Long, x As String, t
  i = first: j = last: x = arr((first + last) / 2, key)
  While i <= j
    While StrComp(arr(i, key), x, vbTextCompare) = -1: i = i + 1: Wend
    While StrComp(x, arr(j, key), vbTextCompare) = -1: j = j - 1: Wend
    If i <= j Then
      For k = left To right
        t = arr(i, k): arr(i, k) = arr(j, k): arr(j, k) = t
      Next
      i = i + 1: j = j - 1
    End If
  Wend
  If first < j Then qsort arr, first, j, left, right, key
  If i < last Then qsort arr, i, last, left, right, key
End Sub

评分

2

查看全部评分

TA的精华主题

TA的得分主题

 楼主| 发表于 2019-10-11 13:53 | 显示全部楼层
[广告] Excel易用宝 - 提升Excel的操作效率 · Excel / WPS表格插件       ★免费下载 ★       ★ 使用帮助
一把小刀闯天下 发表于 2019-10-11 13:25
'A-F列可以无序,,,

Option Explicit

QAQ感谢老师,可以正常使用,不过因为菜鸟看着有些懵,需要慢慢自己琢磨下

TA的精华主题

TA的得分主题

发表于 2019-10-11 14:21 | 显示全部楼层
用字典,不要用中间数组
否则如果数据再多点,直接内存溢出

TA的精华主题

TA的得分主题

发表于 2019-10-11 15:28 | 显示全部楼层
'中间觉得用二分匹配比用纯循环效率高得多

'如果A、B列日期数据有交叉或有包含的会跟用前面的方法得到的结果有所不同,否则结果应该相同

'有空帮我测试比较一下效率,包括准确性,,,

Option Explicit

Sub test()
  Dim arr, brr, dic(1), i As Long, j As Long, s As String
  Dim left As Long, right As Long, mid As Long
  For i = 0 To UBound(dic)
    Set dic(i) = CreateObject("scripting.dictionary")
  Next
  arr = [a1].CurrentRegion.Offset(1).Resize(, 7).Value
  For i = 1 To UBound(arr, 1) - 1
    arr(i, 7) = arr(i, 3) & arr(i, 4)
  Next
  Call qsort(arr, 1, UBound(arr, 1) - 1, 1, UBound(arr, 2), 7)
  For i = 1 To UBound(arr, 1) - 1
    If arr(i, 7) <> arr(i + 1, 7) Then
      Call qsort(arr, j + 1, i, 1, UBound(arr, 2), 1)
      dic(0)(arr(i, 7)) = j + 1: dic(1)(arr(i, 7)) = i - j: j = i
    End If
  Next
  brr = [h1].CurrentRegion.Offset(1).Resize(, 6).Value
  For i = 1 To UBound(arr, 1) - 1
    s = brr(i, 2) & brr(i, 3)
    If dic(0).exists(s) Then
      left = dic(0)(s): right = dic(0)(s) + dic(1)(s) - 1
      mid = (left + right) / 2
      Do While left <= right
        If brr(i, 1) >= arr(mid, 1) And brr(i, 1) <= arr(mid, 2) Then
          brr(i, 5) = arr(mid, 5): brr(i, 6) = arr(mid, 6) * brr(i, 4)
          Exit Do
        ElseIf brr(i, 1) < arr(mid, 1) Then
          right = mid - 1
        Else
          left = mid + 1
        End If
        mid = (left + right) / 2
      Loop
      If left > right Then brr(i, 5) = vbNullString: brr(i, 6) = brr(i, 5)
    Else
      brr(i, 5) = vbNullString: brr(i, 6) = brr(i, 5)
    End If
  Next
  [h2].Resize(UBound(brr, 1) - 1, UBound(brr, 2)) = brr
End Sub

Sub qsort(arr, first, last, left, right, key)
  Dim i As Long, j As Long, k As Long, x As String, t
  i = first: j = last: x = arr((first + last) / 2, key)
  While i <= j
    While StrComp(arr(i, key), x, vbTextCompare) = -1: i = i + 1: Wend
    While StrComp(x, arr(j, key), vbTextCompare) = -1: j = j - 1: Wend
    If i <= j Then
      For k = left To right
        t = arr(i, k): arr(i, k) = arr(j, k): arr(j, k) = t
      Next
      i = i + 1: j = j - 1
    End If
  Wend
  If first < j Then qsort arr, first, j, left, right, key
  If i < last Then qsort arr, i, last, left, right, key
End Sub

评分

2

查看全部评分

TA的精华主题

TA的得分主题

发表于 2019-10-11 15:30 | 显示全部楼层
[广告] Excel易用宝 - 提升Excel的操作效率 · Excel / WPS表格插件       ★免费下载 ★       ★ 使用帮助
数据多用VBA SQL速度快吧?
您需要登录后才可以回帖 登录 | 免费注册

本版积分规则

手机版|关于我们|联系我们|ExcelHome

GMT+8, 2024-3-28 22:18 , Processed in 0.059462 second(s), 16 queries , Gzip On, Redis On.

Powered by Discuz! X3.4

© 1999-2023 Wooffice Inc.

沪公网安备 31011702000001号 沪ICP备11019229号-2

本论坛言论纯属发表者个人意见,任何违反国家相关法律的言论,本站将协助国家相关部门追究发言者责任!     本站特聘法律顾问:李志群律师

快速回复 返回顶部 返回列表