急求大神老师帮助利用vba字典实现sumif函数功能不同的工作薄

影魅力

急求各位老师大神帮忙将（wish分仓模板）表格里面的W列（结果3）sumif函数用vba字典实现，小女子不才小写了一段，但是对于重复的sku，怎么样都出不来结果（表格里面标黄色部分），麻烦各位大神老师帮看下，谢谢

carlostevez1984

两个表字典顺序换一下  

lsdongjh

1. Sub 读取sku库存()
   
2.     Dim strPath As String, strFileName As String
   
3.     Dim shWISH As Worksheet, shSFO As Worksheet, objWB As Object
   
4.     Dim arrWISH As Variant, arrSFO As Variant
   
5.     Dim objDic  As Object, strKey As String
   
6.     Dim lngRows As Long, lngID As Long
   
7.    
   
8.     strPath = ThisWorkbook.Path & ""
   
9.     strFileName = "sfo库存.xls"
   
10.    
    
11.     Set objDic = CreateObject("scripting.dictionary")
    
12.    
    
13.     Set shWISH = Sheets("WISH 分仓模板")
    
14.     lngRows = shWISH.Range("E" & Rows.Count).End(xlUp).Row
    
15.     arrWISH = shWISH.Range("E2:E" & lngRows)
    
16.     For lngID = LBound(arrWISH) To UBound(arrWISH)
    
17.         strKey = arrWISH(lngID, 1)
    
18.         objDic(strKey) = ""
    
19.     Next
    
20.    
    
21.     Set objWB = GetObject(strPath & strFileName)
    
22.     Set shSFO = objWB.Worksheets(1)
    
23.     lngRows = shSFO.UsedRange.Rows.Count
    
24.     arrSFO = shSFO.Range("A2:F" & lngRows)
    
25.     objWB.Close False
    
26.    
    
27.     For lngID = LBound(arrSFO) To UBound(arrSFO)
    
28.         strKey = arrSFO(lngID, 1)
    
29.         If objDic.exists(strKey) Then
    
30.             objDic(strKey) = Val(objDic(strKey)) + Val(arrSFO(lngID, 6))
    
31.         End If
    
32.     Next
    
33.    
    
34.     For lngID = LBound(arrWISH) To UBound(arrWISH)
    
35.         strKey = arrWISH(lngID, 1)
    
36.         If objDic(strKey) <> "" Then
    
37.             arrWISH(lngID, 1) = objDic(strKey)
    
38.         Else
    
39.             arrWISH(lngID, 1) = ""
    
40.         End If
    
41.     Next
    
42.    
    
43.     shWISH.Range("W2").Resize(UBound(arrWISH), 1) = arrWISH
    
44. End Sub

复制代码

wodewan

代码是模板内的值当字典，循环数据源，不出数据的都是重复值，被字典过滤掉了（也就是你字典赋值时的item值（I）默认为最后一次的行号），你反过来，把数据源当字典（前提是你数据源不能有重复值，不然也会出错），循环模板就可以。

carlostevez1984

Sub 读取sku库存()

  Dim DIC As Object
  Set DIC = CreateObject("scripting.dictionary")

    With Worksheets("TT")
        For i = 2 To .[a65536].End(3).Row
          DIC(CStr(.Cells(i, 1))) = DIC(CStr(.Cells(i, 1))) + .Cells(i, "f").Value
        Next
    End With

  
With Worksheets("WISH 分仓模板")
    For J = 2 To .[e65536].End(3).Row
        If DIC.exists(CStr(.Cells(J, "e"))) Then
            .Cells(J, "W").Value = DIC(CStr(.Cells(J, "e")))
        End If
    Next
  End With
  
End Sub

microyip

lsdongjh 发表于 2019-10-8 14:53

你的参数也开始用标识了？不错不错

carlostevez1984

microyip 发表于 2019-10-8 16:11
你的参数也开始用标识了？不错不错

大侠  参数用标志  怎么玩的？

影魅力

wodewan 发表于 2019-10-8 14:55
代码是模板内的值当字典，循环数据源，不出数据的都是重复值，被字典过滤掉了（也就是你字典赋值时的item值 ...

非常感谢大神老师的指点和帮忙，知识点又上了一级，谢谢

影魅力

lsdongjh 发表于 2019-10-8 14:53

感谢大神老师的帮助，更加清晰明了了

microyip

carlostevez1984 发表于 2019-10-8 16:12
大侠  参数用标志  怎么玩的？

就是 类别+名称 作为参数名而已。
如lsgongjh的代码里，
objWB，obj表示对象，WB就是这个对象用于什么地方，这里是工作簿的意思。
lngRows，lng表示Long类型数，Rows表示行数的意思