ExcelHome技术论坛

 找回密码
 免费注册

QQ登录

只需一步,快速开始

快捷登录

搜索
EH技术汇-专业的职场技能充电站 妙哉!函数段子手趣味讲函数 Excel服务器-会Excel,做管理系统 Excel Home精品图文教程库
HR薪酬管理数字化实战 Excel 2021函数公式学习大典 Excel数据透视表实战秘技 打造核心竞争力的职场宝典
300集Office 2010微视频教程 数据工作者的案头书 免费直播课集锦 ExcelHome出品 - VBA代码宝免费下载
用ChatGPT与VBA一键搞定Excel WPS表格从入门到精通 Excel VBA经典代码实践指南
查看: 851|回复: 4

[求助] 删除第4列 大于60的数据

[复制链接]

TA的精华主题

TA的得分主题

发表于 2019-10-2 11:40 | 显示全部楼层 |阅读模式
[广告] Excel易用宝 - 提升Excel的操作效率 · Excel / WPS表格插件       ★免费下载 ★       ★ 使用帮助
各位老师好:问题如下
QQ截图20191002113312.jpg
如题,我要删除第四列大于60的数据
但是因为数据有点多,大概有6万多行,有时可能会更多,
Sub Macro1()
'
' Macro1 Macro
'
Dim a As Long '
For a = 2 To 64387
    If Cells(a, 4) > 50 Then
    Rows(a & ":" & a).Select
    Selection.Delete Shift:=xlUp
    Cells(a, 4).Select
    End If
    a = a - 1
Next
End Sub
这是我的代码,运行起来,接近死机
test.rar (1.65 MB, 下载次数: 5)

这个是我的附件,希望各位老师可以改良一下,并希望继续利用VBA来实现,谢谢

TA的精华主题

TA的得分主题

发表于 2019-10-2 11:47 | 显示全部楼层
没有下载附件,写了一段给你参考
  1. Sub 删除()
  2.     Dim vData As Variant, nRow As Double, rDel As Range
  3.     Application.ScreenUpdating = False
  4.     With Sheet1
  5.         vData = .UsedRange.Offset(3).Resize(, 1).Value
  6.         For nRow = 2 To UBound(vData)
  7.             If Val(vData(nRow, 1)) > 50 Then
  8.                 If rDel Is Nothing Then
  9.                     Set rDel = .Cells(nRow, 4)
  10.                 Else
  11.                     Set rDel = Union(rDel, .Cells(nRow, 4))
  12.                 End If
  13.             End If
  14.         Next
  15.         If Not rDel Is Nothing Then rDel.EntireRow.Delete Shift:=xlUp
  16.     End With
  17.     Application.ScreenUpdating = True
  18. End Sub
复制代码

TA的精华主题

TA的得分主题

发表于 2019-10-2 12:43 | 显示全部楼层
本帖最后由 moonlit123 于 2019-10-2 12:48 编辑

首先你代码里的 .Select 是没必要的,(录制宏代码的后遗症),改掉这些.Select后会快不少,
其次不断对单元格操作和行操作会影响效率。几万行下来是很卡的。
建议学习下数组,把数据先读取到内存中,利用计算机内存处理 ,处理完再一次性返回到表格上,执行速度快。

  1. Sub Macro1()
  2. Dim arr(), i As Long, j As Long, m As Long, R As Long
  3. R = Sheet1.[A65536].End(xlUp).Row
  4. arr = Sheet1.Range("A2:D" & R).Value
  5. ReDim brr(1 To UBound(arr, 1), 1 To UBound(arr, 2))
  6. m = 0
  7. For i = 1 To UBound(arr)
  8. If arr(i, 4) <= 50 Then
  9.    m = m + 1
  10.    For j = 1 To UBound(arr, 2)
  11.      brr(m, j) = arr(i, j)
  12.    Next j
  13. End If
  14. Next i

  15. Sheet1.[A2].Resize(UBound(brr, 1), UBound(brr, 2)).Value = brr
  16. Erase arr
  17. Erase brr
  18. End Sub
复制代码

TA的精华主题

TA的得分主题

 楼主| 发表于 2019-10-2 13:43 | 显示全部楼层
[广告] Excel易用宝 - 提升Excel的操作效率 · Excel / WPS表格插件       ★免费下载 ★       ★ 使用帮助
moonlit123 发表于 2019-10-2 12:43
首先你代码里的 .Select 是没必要的,(录制宏代码的后遗症),改掉这些.Select后会快不少,
其次不断对单 ...

不错,万分感谢
不过,我还有很多类似的代码

TA的精华主题

TA的得分主题

发表于 2019-10-3 14:07 | 显示全部楼层
Option Explicit
Sub 删除指定数据(Lie As Long, TiaoJian As Double)
    Dim sh As Worksheet, ar, rg As Range, i&, s$
    Set sh = ThisWorkbook.Sheets("Sheet1")
    With sh
            ar = .Range("a1").CurrentRegion
            For i = 2 To UBound(ar)
                    s = ar(i, Lie)
                    If s > TiaoJian Then
                            If rg Is Nothing Then
                                    Set rg = .Range("a" & i)
                            Else
                                Set rg = Union(rg, .Range("a" & i))
                            End If
                    End If
            Next
            If Not rg Is Nothing Then rg.EntireRow.Delete
    End With
End Sub
Sub mytest()
        删除指定数据 4, 60
End Sub
您需要登录后才可以回帖 登录 | 免费注册

本版积分规则

手机版|关于我们|联系我们|ExcelHome

GMT+8, 2024-3-29 05:25 , Processed in 0.034116 second(s), 10 queries , Gzip On, Redis On.

Powered by Discuz! X3.4

© 1999-2023 Wooffice Inc.

沪公网安备 31011702000001号 沪ICP备11019229号-2

本论坛言论纯属发表者个人意见,任何违反国家相关法律的言论,本站将协助国家相关部门追究发言者责任!     本站特聘法律顾问:李志群律师

快速回复 返回顶部 返回列表