数据在A列中，如何分列

寒羽良

数据以空格的分开的方式在A列，（用EXCEL分列数据中的空格选项，无法做到），如何用VBA分开，如表2中的那样。求大神帮助。

一把小刀闯天下

Option Explicit

Sub test()
  Dim arr, i, j, t, n, max
  arr = Sheets("sheet1").[a1].CurrentRegion
  ReDim brr(1 To UBound(arr, 1), 1 To 30)
  For i = 1 To UBound(arr, 1)
    t = Split(arr(i, 1), ChrW(160)): n = 0
    For j = 0 To UBound(t)
      If Len(t(j)) Then n = n + 1: brr(i, n) = t(j)
    Next
    If max < n Then max = n
  Next
  With Sheets("sheet2").[a1]
    .Resize(Rows.Count, max + 1).ClearContents
    .Resize(UBound(brr, 1), max) = brr
  End With
End Sub

寒羽良

一把小刀闯天下 发表于 2019-9-21 07:01
Option Explicit

Sub test()

感谢老师的帮助，完美解决了我工作中的难题。另外我刚开始学习，您写的代码，我看不懂，能加上说明 ，让我学习学习吗？

月关

选中A列，数据→分列→固定宽度，需要分列处单击...完成。  ctrl+f，复制其中一个单元格里较短的不可见符号，全部替换。
以上为自食其力的解法

寒羽良

一把小刀闯天下 发表于 2019-9-21 07:01
Option Explicit

Sub test()

谢谢老师的帮助。想学习一下，可以加个注解吗？入门都，不好意思。

一把小刀闯天下

寒羽良 发表于 2019-9-21 08:22
谢谢老师的帮助。想学习一下，可以加个注解吗？入门都，不好意思。

'没有必要再给你修改代码，因为运行多余一次时结果是不确定的，输出时已经给你考虑好了

'你可以把它复制到需要数据出现的地方，用不了几秒的吧，，，


Option Explicit '变量必须定义（不定义变量会出错，良好的习惯从这里开始）

Sub test() '这就是传说中的过程，过程名叫test，哈哈哈
  Dim arr, i, j, t, n, max '定义变量，但没有指定变量类型（就是变体变量，可以查一下什么是变量类型）
  arr = Sheets("sheet1").[a1].CurrentRegion '跟{a1]连在一起的数据块，当然也可以指定，，，
  ReDim brr(1 To UBound(arr, 1), 1 To 30) '定义一个列足够大的数组，行当然已经确定为ubound(arr,1)
  For i = 1 To UBound(arr, 1)
    t = Split(arr(i, 1), ChrW(160)): n = 0 '按非可见字符ChrW(160)进行分割当前字符串,如果是空格改成space(1)
    For j = 0 To UBound(t) '分割后得到的字符串下标为0（也可在开始处声明从1开始，觉得没有必要），上标为ubound(t)
      If Len(t(j)) Then n = n + 1: brr(i, n) = t(j) '非空时取数据，因为你这ChrW(160)有点多
    Next
    If max < n Then max = n '输出时用，因为前面定义的输出数组列数有点大,也可以不要
  Next
  With Sheets("sheet2").[a1] '指定工作表及输出的第一单元格位置，有很多方法这是最常见的
    .Resize(Rows.Count, max + 1).ClearContents '清除输出区可能存在的数据
    .Resize(UBound(brr, 1), max) = brr '输出数据，max在这里用，当然也可以把它改成ubound(brr,2)
  End With
End Sub