求助提取[结果]表中B列序列号，填写到相同数字对应位置。

3201967906

求助提取[结果]表中B列序列号，填写到相同数字对应位置，有1048576条数据。

民扬

没明白示例

蓝桥玄霜

结果的代码：

3201967906

民扬 发表于 2019-9-17 10:40
没明白示例

把结果表中的B列序号，提取到对应的Sheet1表中的F列啊。里面有代码。

一把小刀闯天下

'"结果"表中有7个重复的，所以输出到F列的结果并不完全正确（重复的保留最后一次出现的）

Option Explicit

Sub test()
  Dim arr, i As Long, j As Long, dic, t As String
  Set dic = CreateObject("scripting.dictionary")
  arr = Sheets("结果").[a1].CurrentRegion.Resize(, 2)
  For i = 1 To UBound(arr, 1)
    dic(Trim(arr(i, 1))) = arr(i, 2)
  Next
  arr = Sheets("sheet1").[a1].CurrentRegion.Resize(, 5)
  ReDim brr(1 To UBound(arr, 1), 1 To 1)
  For i = 1 To UBound(arr, 1)
    t = vbNullString
    For j = 1 To UBound(arr, 2)
      t = t & Space(1) & arr(i, j)
    Next
    t = Mid(t, 2)
    If dic.exists(t) Then brr(i, 1) = dic(t)
  Next
  [f1].Resize(UBound(brr, 1)) = brr
End Sub

月关

一把小刀闯天下 发表于 2019-9-17 10:53
'"结果"表中有7个重复的，所以输出到F列的结果并不完全正确（重复的保留最后一次出现的）

Option Explic ...

厉害厉害！
我发现小刀老师的理解能力都远超常人，我到现在都没看明白到底说的啥，——没看原来的代码，也没看你的代码，想自己先构思一下

3201967906

一把小刀闯天下 发表于 2019-9-17 10:53
'"结果"表中有7个重复的，所以输出到F列的结果并不完全正确（重复的保留最后一次出现的）

Option Explic ...

大师你好
'"结果"表中是有7个重复的，所以输出到F列的结果应保留二位。，辛苦你在把序号所在行增加黄色可以吗？【结果】A列灰色的是重复的数字。

一把小刀闯天下

'重复的连在一起了，，，

'增加了匹配成功后行变色

Option Explicit

Sub test()
  Dim arr, i As Long, j As Long, dic, t As String
  Set dic = CreateObject("scripting.dictionary")
  Application.ScreenUpdating = False
  Sheets("sheet1").Activate
  [a:f].Interior.ColorIndex = xlNone
  arr = Sheets("结果").[a1].CurrentRegion.Resize(, 2)
  For i = 1 To UBound(arr, 1)
    t = Trim(arr(i, 1))
    dic(t) = dic(t) & "," & arr(i, 2)
  Next
  arr = [a1].CurrentRegion.Resize(, 5)
  ReDim brr(1 To UBound(arr, 1), 1 To 1)
  For i = 1 To UBound(arr, 1)
    t = vbNullString
    For j = 1 To UBound(arr, 2)
      t = t & Space(1) & arr(i, j)
    Next
    t = Mid(t, 2)
    If dic.exists(t) Then
      brr(i, 1) = Mid(dic(t), 2)
      Cells(i, 1).Resize(, 6).Interior.Color = vbYellow
    End If
  Next
  [f1].Resize(UBound(brr, 1)) = brr
  Application.ScreenUpdating = true
End Sub

3201967906

一把小刀闯天下 发表于 2019-9-17 11:19
'重复的连在一起了，，，

Option Explicit

谢谢各位大师关注，你们辛苦了。

一把小刀闯天下

月关 发表于 2019-9-17 11:04
厉害厉害！
我发现小刀老师的理解能力都远超常人，我到现在都没看明白到底说的啥，——没看原来的代码， ...

解决这种问题主要得靠猜，，，