各位大神帮帮我求A列中包含B列数值公式写法

zhangmiaode · 发表于 2019-6-19 10:27

=COUNTIF(A:A,"*1*2*3*8*") 每个数都要输入

比如A列中  有12358 12389  12378 这个公式  结果就是出现3次
如果我换  1378  就还得输入=COUNTIF(A:A,"*1*3*7*8*")

有没有什么方法  B列数据变了之后    求出现次数自动变
要是=COUNTIF(A:A,"*C1*D1*E1*F1*")  这样写  公式应该怎么变变呢？

liu2336904 · 发表于 2019-6-19 10:33

按你的想法
=COUNTIF(A:A,"*"&C2&"*"&D2&"*"&E2&"*"&F2&"*")

天凉好个球呀 · 发表于 2019-6-19 10:35

=COUNTIF(A:A,TEXT(B2,"!*0!*0!*0!*0!*"))

复制代码

sandays · 发表于 2019-6-19 10:41

=SUM(N(MMULT(--ISNUMBER(FIND(MID(B2,{1,2,3,4},1),$A$2:$A$1997)),{1;1;1;1})=4))

zhangmiaode · 发表于 2019-6-19 10:41

求助求助

zhangmiaode · 发表于 2019-6-19 10:43

liu2336904 发表于 2019-6-19 10:33
按你的想法
=COUNTIF(A:A,"*"&C2&"*"&D2&"*"&E2&"*"&F2&"*")

太感谢了真是行里行外一看就知道

1016373263 · 发表于 2019-6-19 10:48

=COUNTIF($A$2:$A$1997,TEXTJOIN("",1,"*"&MID(B2,COLUMN($A:$D),1)&"*"))

1016373263 · 发表于 2019-6-19 10:48

只需要B列数就可以了

sandays · 发表于 2019-6-19 11:37

天凉好个球呀发表于 2019-6-19 10:35

思路很赞，值得学习。
有个小问题值得讨论：这种方法，限定了B列数字在A列出现的顺序。如果A列有15327，B列有213，使用该公式是会把15327排除在外的。不知道楼主是不是也想按照B列数字出现的顺序来查找。

hcm19522 · 发表于 2019-6-19 15:39

D2:D11=SUM(N(MMULT(ISNUMBER(0/(FIND(MID(C2,COLUMN(A:J),1),"@"&A$2:A$99)-1))*1,Z1:Z10+1)=LEN(C2)))

		自动登录	找回密码
密码			免费注册

[求助] 各位大神帮帮我求A列中包含B列数值公式写法

评分

评分

最新热点 /1