依次提取文本中的数字

Leon大神 · 发表于 2019-5-15 12:16

如A1单元格内容为:张三18张三丰15上官婉儿123丽娜因巴斯2458ABC，设置公式右拉依次提取数字:18、15、123、2458，这个公式以前见过，忘了

象山海鲜 · 发表于 2019-5-15 12:30

欢迎老会员~！
为了问题更快更好的得到解决，并且节省帮助的坛友的时间~！
请说明问题，模拟结果，并上传压缩附件~！
请阅读：
EXCEL函数与公式版：新人必读之发贴要素

jivy1212 · 发表于 2019-5-15 12:43

=IFERROR(-LOOKUP(1,-MID($A1,SMALL(IF(MMULT(1-ISNUMBER(-MID($A1,ROW($1:$50)+{0,1},1)),{1;-1})=1,ROW($2:$51)),COLUMN(A1)),COLUMN(1:1))),"")

复制代码

数组右拉只能取整数

micch · 发表于 2019-5-15 12:57

=IFERROR(-LOOKUP(,-MID($A1,SMALL(IF(MMULT(-TEXT(MID($A1,ROW(1:33)+{0,1},1),"1;;;!0"),{1;-1})=1,ROW(2:34)),COLUMN(A1)),ROW(1:9))),"")

复制代码

学习3楼老师

sayhi95 · 发表于 2019-5-15 13:09

=IFERROR(-LOOKUP(,-MID($A1,SMALL(IFERROR(IF((LENB(MID($A1,ROW($1:$98),2))=3)*MID($A1,ROW($2:$99),1)^0,ROW($2:$99)),4^8),COLUMN(A1)),ROW($1:$9))),"")

复制代码

有点长，支持小数

jivy1212 · 发表于 2019-5-15 13:15

其实都是同一思路，先取每个数首在的位置，然后分别再取出来。

micch · 发表于 2019-5-15 13:22

=IFERROR(-LOOKUP(,-MID($A1,SMALL(IF(MMULT(LEN(TEXT(MID($A1,ROW(1:33)+{0,1},1),)),{1;-1})=1,ROW(2:34)),COLUMN(A1)),ROW(1:9))),"")

复制代码

学习海鲜老师text区分文本数字的方法

jivy1212 · 发表于 2019-5-15 13:30

micch 发表于 2019-5-15 13:22
学习海鲜老师text区分文本数字的方法

一个月后能用起来就算掌握了。。现在还鲜些呢。我是感觉记不了那么多，记性一直很差。

sayhi95 · 发表于 2019-5-15 13:31

micch 发表于 2019-5-15 13:22
学习海鲜老师text区分文本数字的方法

试试有小数的情况

sayhi95 · 发表于 2019-5-15 13:34

jivy1212 发表于 2019-5-15 13:30
一个月后能用起来就算掌握了。。现在还鲜些呢。我是感觉记不了那么多，记性一直很差。

是啊，大佬们套路太多了，学不过来也记不住，感谢花花，今天没花了，改日回赠。

		自动登录	找回密码
密码			免费注册

[已解决] 依次提取文本中的数字