请各位看看关于sql数据分析的求助,谢谢了!

袁先生

我把那个宏"重庆仓库库"存修改了一下,在第一个表"数据分析表"中加了一个按钮,能实现你要的对应查询结果,

袁先生

J列"重庆门店寄存"的查询,在原宏赋值后面,增加以下代码;  Sql2 = "select b.总库存数 from ((select 商品条码 from [Excel 12.0;imex=0;Database=" & ActiveWorkbook.FullName & "].[数据分析表$c1:c1018]) as a " & _
    "LEFT JOIN (select * from [库存汇总查询1$] where 仓库 like '%重庆%') as b on a.商品条码 = b.条码)"
    [J2].CopyFromRecordset cnn.Execute(Sql2)

chr78228

袁先生 发表于 2019-4-12 11:30
J列"重庆门店寄存"的查询,在原宏赋值后面,增加以下代码;  Sql2 = "select b.总库存数 from ((select 商品条 ...

首先谢谢楼上热心帮助,然后有个疑问想弄明白 就是后半段的区别在哪里?,在我的理解看来,上面一句只是没有指定select范围 而下面袁先生提供的是指定了select范围
如果上面一句存在sql语法错误,能否指出错在哪里吗?谢谢!

chr78228

是excel里不能 on ...and语句吗?同样的语句 在vb6里能通过额

chr78228

其他跟我一样不甚明白的朋友和会sql的朋友也可以探讨几句哈

chr78228

我相信只要弄明白了错误的原因 后面的数据提取就逐步会解决,就是不知道我的语句错在哪里了,就缺"一句点醒梦中人"的朋友了.

袁先生

1.用字法计算比较快的，我把代码改了一下；用第三个表的数据源，没有从外面工作簿取数据
"Sub 读取库存与销售数据()
Application.ScreenUpdating = False
Set d = CreateObject("scripting.dictionary") '引用字典
    Sheets("数据分析表").Range("i2:w5000").ClearContents '重新计算前,清除原先该区域数据
    arr = Sheets("数据分析表").[a1].CurrentRegion '重新取得以空行与空列的组合为边界的区域,与清除前区域未变
    For i = 2 To UBound(arr)
        If Len(arr(i, 3)) > 0 Then
            d(Trim(arr(i, 3))) = i '把第三列循环结果赋给字典d
        End If
    Next i
    brr = Sheets("库存汇总查询1").Range("a1").CurrentRegion '定义数组brr
    ReDim br(1 To UBound(brr), 1 To UBound(brr, 2)) '定义数组br
    ReDim cr(1 To UBound(brr), 1 To UBound(brr, 2))
    For i = 2 To UBound(brr)
        If Trim(brr(i, 1)) = "B重庆仓库CQ" Then
            n = n + 1 '获取已有数据的笔数
            For j = 1 To UBound(brr, 2) '循环"库存汇总查询1"表的第二列的行数
                br(n, j) = brr(i, j) '赋值br为已有数笔数对应库存汇总查询1表行数和列数的字典
            Next j
        End If
        If InStr(Trim(brr(i, 1)), "CQ") > 0 Then '这种查询包含了前面一种结果,
        'Trim清删除第一列仓库单元格前后空字符,InStr指定一字符串在另一字符串中最先出现的位置。string1 为零长度返回零
            m = m + 1 '获取包含CQ内容的笔数
             For j = 1 To UBound(brr, 2)
                cr(m, j) = brr(i, j) '赋值cr为包含CQ内容的笔数为字典
            Next j
        End If
    Next i '退出i的循环
    For i = 1 To n '再循环已查询重庆仓库的次数
        m1 = d(Trim(br(i, 4))) '把br第四列赋给字典m1
        If m1 <> "" Then
            arr(m1, 9) = arr(m1, 9) + br(i, 10)
        End If
    Next i
    For i = 1 To m
        m2 = d(Trim(cr(i, 4))) '把cr第四列赋给字典m2
        If m2 <> "" Then
            arr(m2, 10) = (arr(m2, 10) + cr(i, 10))
        '第10列的值等于字典的值,
        End If
    Next i
    For i = 2 To UBound(arr)
        arr(i, 10) = arr(i, 10) - arr(i, 9) '包含CQ内容的数量减去已含"B重庆仓库CQ"第九列的数量
    Next i
    Sheets("数据分析表").[a1].CurrentRegion = arr '重新赋值区域,原区域9-10列添加数据后
Application.ScreenUpdating = True
End Sub"

袁先生

2.用sql查询语句如下；
Sub 重庆仓库库存()
    Application.ScreenUpdating = False
    Dim cnn As ADODB.Connection
    Dim Mypath As String, Str_cnn As String, Sql As String
    Dim i As Long, sht_name As String
    Set cnn = New ADODB.Connection
    Mypath = ThisWorkbook.FullName
    If Application.Version < 12 Then
        Str_cnn = "Provider=Microsoft.jet.OLEDB.4.0;Extended Properties=Excel 8.0;Data Source=" & Mypath
    Else
        Str_cnn = "Provider=Microsoft.ACE.OLEDB.12.0;Extended Properties=Excel 12.0;Data Source=" & Mypath
    End If
    cnn.Open Str_cnn
      Sql = "select t2.总库存数,b.总库存数-iif(t2.总库存数 is null,0,t2.总库存数)-iif(寄存数 is null,0,寄存数) as 结存,寄存数 from (((select 商品条码 from [数据分析表$c1:c1018]) as t1 " & _
"LEFT JOIN (select * from [库存汇总查询1$] where 仓库= 'B重庆仓库CQ') as t2 on t1.商品条码 = t2.条码) LEFT JOIN " & _
"(select 条码,sum(总库存数) as 总库存数 from [库存汇总查询1$] where 仓库 like '%CQ%' group by 条码) as b on t1.商品条码 = b.条码) LEFT JOIN " & _
"(select 条码,sum(寄存数) as 寄存数 from [库存汇总查询1$] where 仓库 like '%CQ%' group by 条码) as c on t1.商品条码 = c.条码"
        Sheets("数据分析表").Range("i2:k5000").ClearContents '清除区域数据
        [I2].CopyFromRecordset cnn.Execute(Sql)
    cnn.Close
     Set cnn = Nothing
Application.ScreenUpdating = True
End Sub

袁先生

I列+J列+K列=第三表“*CQ”门店结存，不知道我理解的意思对不对？

袁先生

用函数公式验证结果也是正确的
AB2=SUMIFS(库存汇总查询1!I$2:I$14041, 库存汇总查询1!A$2:A$14041, "=*CQ", 库存汇总查询1!D$2:D$14041, 数据分析表!Z2)