随机两位数

huangwinson

00-99的100个两位数中，随机生成一定的数量（比如90个、92个、95个不重复两位数），不重复的，有没有哪个高手帮忙设个公式，谢谢。

sbww8800

数组公式=SMALL(IF(COUNTIF(A$1:A1,ROW($1:$100))=0,ROW($1:$100)),INT(RAND()*(100-COUNT(A$1:A1))+1))

Datous

我先开火车。
A2

1. =AGGREGATE(14,6,(ROW($1:$100)-1)/(COUNTIF(A$1:A1,ROW($1:$100)-1)=0),RANDBETWEEN(1,100-COUNT(A$1:A1)))

复制代码

sbww8800

0-99.。。。
=SMALL(IF(COUNTIF(A$1:A1,ROW($1:$100)-1)=0,ROW($1:$100)-1),INT(RAND()*(100-COUNT(A$1:A1))+1))

我走我流

借楼上老师的思路
=SMALL(IF(COUNTIF(A1:$A$1,ROW($1:$100)-1)=0,ROW($1:$100)-1),RANDBETWEEN(1,100-ROW()))
需要A1 输入随机数，，，这个是99个的，100与实际需求的关系是多1个

Datous

其实，大家一个思路，就是先看后看手快手慢

新手路上

选中A1到A95单元格，输入以下数组公式，按【ctrl+shift+enter】即可生成95个不重复的随机在00到99之间的数值

1. =RIGHT(SMALL(RANDBETWEEN(ROW(1:100)^0,10)/1%+ROW(1:100)-1,ROW(1:95)),2)

复制代码

dipperrrr

这种情况，还是高版本excel用着舒服。92个：

1. =INDEX(UNIQUE(RANDARRAY(1000,1,0,99,1)),ROW(1:92))

复制代码

micch

1. =RIGHT(SMALL(RANDBETWEEN(1,ROW(1:100))/1%+ROW(10:109),ROW(1:99)),2)

复制代码

学习一下，就是奇怪的很，rand函数就不行，RANDBETWEEN却可以得到不重复的

AmoKat

下列 E、F 兩式差不多，雖然F式較為精簡，但試驗前50組數字小於50的機率，最好應該是25個左右，E、F公式前50個數字偏小，尤其F公式更為嚴重，不知可有改善空間。

E =RIGHT(SMALL(RANDBETWEEN(ROW(1:100)^0,10)/1%+ROW(1:100)-1,ROW(1:95)),2)
F =RIGHT(SMALL(RANDBETWEEN(1,ROW(1:100))/1%+ROW(10:109),ROW(1:99)),2)

        E        F
1        25        34
2        27        33
3        27        36
4        28        39
5        27        35
6        23        32
7        26        37
8        26        36
9        26        35
10        28        35
平均        26.3        35.2
               
前50數 <=50 個數