如何改变EXCEL公式从右往左计算的规则

gooday0516

偶然发现，EXCEL公式在计算查找某单元格的时候，是将单元格内容字符从右往左计算的，有没有什么办法能够改变这个顺序，让EXCEL公式在查找的时候从左往右运算？例如：下面这个公式是从地址最右边的字符开始匹配，导致江西的匹配成上海的。

PS:不要说在单位后面加上省、市单位增加精确性这种解决办法，附件只是举了一个简单的例子，实际情况更加复杂，不能上传网络，我就是想知道EXCEL公式如何让他从单元格最左边的字符开始计算。

示例0314.rar (8.92 KB, 下载次数: 11)

2019-3-14 13:04 上传

点击文件名下载附件

丢丢表格

掐头 就可行了~~~~
=LOOKUP(,-FIND($E$1:$E$5,LEFT(A2,3)),$F$1:$F$5)

再来一个 掐头的：
=LOOKUP(1,0/COUNTIF(A2,E$2:E$5&"*"),F$2:F$5)

三掐头了~~
=LOOKUP(1,FIND($E$1:$E$5,A2),$F$1:$F$5)

不好意思  又来掐头了…………
=MOD(MIN(FIND(E$2:E$5,A2&E$2:E$5)*10^7+F$2:F$5),10^7)

象山海鲜

1. =LOOKUP(,0/FREQUENCY(1,MOD(FIND(E$2:E$5,A2&E$2:E$5),LEN(A2)+1)),$F$2:$F$5)

复制代码

dipperrrr

1. =VLOOKUP(E2&"*",A:B,2,)

复制代码

sayhi95

1. =INDEX(F:F,MATCH(1,FIND($E$1:$E$5,A2)^0,))

复制代码

丢丢表格

dipperrrr 发表于 2019-3-14 13:26

思路正确，改动一下：

=VLOOKUP(LEFT(A2,2)&"*",E:F,2,)

dipperrrr

丢丢表格 发表于 2019-3-14 13:31
思路正确，改动一下：

=VLOOKUP(LEFT(A2,2)&"*",E:F,2,)

看花眼了，还以为是右边根据左边来取值。

gooday0516

=LOOKUP(,-FIND($E$1:$E$5,LEFT(A2,3)),$F$1:$F$5)
查找范围限制在了地址的前3个字符上，实际情况中前面有其他字符，例如“地址在江西省南昌市上海路”、“中国江西省南昌市上海路”。

=LOOKUP(1,0/COUNTIF(A2,E$2:E$5&"*"),F$2:F$5)
地址开头有其他字符就不行。

=LOOKUP(1,FIND($E$1:$E$5,A2),$F$1:$F$5)
同上。

=MOD(MIN(FIND(E$2:E$5,A2&E$2:E$5)*10^7+F$2:F$5),10^7)
算出来的值不对

=LOOKUP(,0/FREQUENCY(1,MOD(FIND(E$2:E$5,A2&E$2:E$5),LEN(A2)+1)),$F$2:$F$5)
全符合，比原公式还精准，现在还没有太多时间研究公式的意思，先谢过了！！

=INDEX(F:F,MATCH(1,FIND($E$1:$E$5,A2)^0,))
结果是#VALUE!或#N/A

=VLOOKUP(LEFT(A2,2)&"*",E:F,2,)
查找范围限制在了地址的前2个字符上。

AmoKat

=LOOKUP(,0/FIND(E$2:E$5,A2),F$2:F$5)
一般公式

應該很標準的查詢方式

gooday0516

象山海鲜 发表于 2019-3-14 13:12

大神，我回来求助您了，使用您的公式碰到一个小问题，希望您能帮优化一下：
比如"普陀区"需要单独归类到数值"50"、"上海市"需要单独归类到数值"200"，我在E:F列添加了关键字“上海市普陀区”50、“普陀区”50 ，但公式对地址为“上海市普陀区”的归类到了“200”，有什么办法解决这个问题吗？
还有“上海市***普陀区”中间有其他字符的想要匹配到50应该怎么办呢？