求助：VBA获取满足条件的行到指定工作表

放逐理想

老师，您好！         
        我的文件中一共有三个表
         1、单码型体表-条件表
         2、数据源表-数据来源
         3、单码-数据获取后存储表
        我需要先查找数据源表E列，看"-"符号前的字符串是否在单码型体表中出现，如果出现就获取该行，然后存储到"单码"表中.
        我有采用字典+数组和数组+vlookup函数的方法，但是要么数据全部提取要么全部提取不到。
        请老师帮忙看下哪里出现问题，谢谢。

abc123281

Sub 订单筛选()
Dim arr
Set d = CreateObject("scripting.dictionary")
With Sheets("单码型体")
   r = .[a65536].End(xlUp).Row
   arr = .Range("a2:a" & r)
   For i = 1 To UBound(arr)
     d(arr(i, 1)) = i
   Next
End With
With Sheets("数据源")
   r = .[a65536].End(xlUp).Row
   arr = .Range("a3:ac" & r)
   ReDim brr(1 To 10000, 1 To UBound(arr, 2))
   For i = 1 To UBound(arr)
     arr(i, 5) = Val(Split(arr(i, 5), "-")(0))
     If d.exists(arr(i, 5)) Then
       n = n + 1
       For j = 1 To UBound(arr, 2)
        brr(n, j) = arr(i, j)
       Next
     End If
   Next
End With
If n > 0 Then
  With Sheets("单码")
   .UsedRange.Offset(2).ClearContents
   .Range("A3").Resize(n, UBound(brr, 2)) = brr
  End With
Else
  MsgBox "没有符合要求的数据！", 64
  Exit Sub
End If
MsgBox "OK!", 64
End Sub

abc123281

求助123.rar (36.71 KB, 下载次数: 34)

2019-3-12 22:50 上传

点击文件名下载附件

放逐理想

abc123281 发表于 2019-3-12 22:50

老师，您好，这里arr(i, 5) = Val(Split(arr(i, 5), "-")(0))  增加了一个Val函数，如果不加就无法获取数据，Split(arr(i, 5), "-")(0))直接出来的数据和val后出来有什么差异了？

放逐理想

abc123281 发表于 2019-3-12 22:50

非常感谢老师您的帮助，关于这句arr(i, 5) = Val(Split(arr(i, 5), "-")(0))，向向您在请教下，要加val函数，是否说Split(arr(i, 5), "-")(0)直接出来的数据不是数值型？或者有其他什么说法

abc123281

对  要么两个都是数值类型   要么都是字符串或是文本都行   统一就行

abc123281

你好  
   你的工作表“单码型体”中的a列数据是数值型       工作表“数据源”中的e列数据  中间都有“-” 写入数组时   
  程序自动判断为字符型   所以需要使用函数val将其转换为数值型   这样才能与字典对应

lsc900707

测试参考附件：