单元格内0-9出现次数多少排序

gaosang123 · 发表于 2019-2-20 13:23

求公式：单个单元格内0-9出现次数排序公式，按照数字出现次数多少排序。
如单元格B4 88888999999911110
在单元格B5中录入公式得出：9810234567
麻烦各位给做个公式。谢谢。

Datous · 发表于 2019-2-20 13:40

=MID(SUM(MOD(LARGE((LEN(B4)-LEN(SUBSTITUTE(B4,ROW($1:$10)-1,)))/1%%+9-ROW($1:$10)/1%+ROW($1:$10),ROW($1:$10)),10)/10^ROW($1:$10))&0,3,10)

复制代码

数组公式

我走我流 · 发表于 2019-2-20 13:52

本帖最后由我走我流于 2019-2-20 13:57 编辑

=SUM(MOD(LARGE(MMULT(N(--MID(B4,COLUMN(INDIRECT("A:"&CHAR(64+LEN(B4)))),1)=10-ROW($1:$10)),ROW(INDIRECT("1:"&LEN(B4)))^0)*100+10-ROW($1:$10),ROW($1:$10)),100)*10^(10-ROW($1:$10)))
数组公式，结果和你的模拟稍微不一样 9810765432
公式可以稍微修改下就可以一样了

gaosang123 · 发表于 2019-2-20 14:09

Datous 发表于 2019-2-20 13:40
数组公式

多谢，公式很好用。

gaosang123 · 发表于 2019-2-20 14:10

我走我流发表于 2019-2-20 13:52
=SUM(MOD(LARGE(MMULT(N(--MID(B4,COLUMN(INDIRECT("A:"&CHAR(64+LEN(B4)))),1)=10-ROW($1:$10)),ROW(INDIR ...

谢谢，公式不太会改。

飞天篮球猪 · 发表于 2019-2-20 14:22

提供一个pq的解法

= Text.Combine(List.Sort({"0".."9"},{each 1/List.Count(Text.PositionOf("88888999999911110",_,2)),each _}))

复制代码

micch · 发表于 2019-2-20 14:29

=MID(SUM(10^11,RIGHT(LARGE(LEN(SUBSTITUTE(B4,ROW(1:10)-1,))/1%+ROW(1:10)-1,ROW(1:10)))*10^ROW(1:10)),2,10)

复制代码

41126238 · 发表于 2019-2-20 14:29

本帖最后由 41126238 于 2019-2-20 14:59 编辑

=text(SUM(MOD(SMALL(LEN(SUBSTITUTE(B4,ROW(1:10)-1,))+(ROW(1:10)-1)%,ROW(1:10)),1)*10^(12-ROW(1:10))),rept(0,10))

复制代码

丢丢表格 · 发表于 2019-2-20 14:45

micch 发表于 2019-2-20 14:29

我习贯用从小到大排：

=MID(SUM(RIGHT(SMALL(LEN(SUBSTITUTE(B4,ROW(1:10)-1,))/1%+ROW(1:10)-1,ROW(1:10)))*10^-ROW(1:10))&0,3,10)

41126238 · 发表于 2019-2-20 14:59

丢丢表格发表于 2019-2-20 14:45
我习贯用从小到大排：

=MID(SUM(RIGHT(SMALL(LEN(SUBSTITUTE(B4,ROW(1:10)-1,))/1%+ROW(1:10)-1,ROW( ...

考虑不周，感谢提醒。

		自动登录	找回密码
密码			免费注册

[求助] 单元格内0-9出现次数多少排序

评分

最新热点 /1