分别从A列提取开始和结束行号

WYS67 · 发表于 2019-2-20 07:27

本帖最后由 WYS67 于 2019-2-20 07:59 编辑

分别从A列提取开始和结束行号.zip (11.34 KB, 下载次数: 12)

提示：A列数据源第一个"F:"和第二个":F"只是举例说明，实际中有可能不仅仅限于两个字节，或是有规律的"F:"和":F"，若此，应该怎样写公式才能只提取数字？

lrsh1985 · 发表于 2019-2-20 07:55

B5=MID(A5,2,FIND(":",A5)-2)
C5=MID(A5,FIND(":",A5)+2,10000)

复制代码

renyz2006 · 发表于 2019-2-20 08:04

b5=LEFT(SUBSTITUTE(A5,"F",),FIND(":",SUBSTITUTE(A5,"F",))-1)
c5=SUBSTITUTE(RIGHT(A5,FIND(":",A5)-1),"F","")

renyz2006 · 发表于 2019-2-20 08:08

也可以利用：SUBSTITUTE(A5,"F",),然后再分列也行！

江苏永能朱兴华 · 发表于 2019-2-20 08:11

本帖最后由江苏永能朱兴华于 2019-2-20 08:12 编辑

B5:C5区域数组：
=--MID(SUBSTITUTE(SUBSTITUTE(A5,"F",),":",REPT(" ",20)),{1,21},20)
=SMALL(IF(1-ISERR(FIND("F"&ROW($1:$9999)&":",A5&":")),ROW($1:$9999)),{1,2})

renyz2006 · 发表于 2019-2-20 08:15

示例要有代表性！！

WYS67 · 发表于 2019-2-20 08:31

感谢老师们的热情帮忙！

lg0219 · 发表于 2019-2-20 08:34

本帖最后由 lg0219 于 2019-2-20 08:51 编辑

当第一个字母不是F、或者不止一位、而且数字的位数也不确定时，可用以下公式：
始：=MAX(IFERROR(--RIGHT(MID(A5,1,FIND(":",A5)-1),ROW($1:$5)),0))
末：=MAX(IFERROR(--RIGHT(MID(A5,FIND(":",A5)+1,LEN(A5)-FIND(":",A5)),ROW($1:$5)),0))

两个均为数组公式

lg0219 · 发表于 2019-2-20 08:49

本帖最后由 lg0219 于 2019-2-20 08:52 编辑

如果不想用数组，也可以用下面的公式：
始：=-LOOKUP(1,-RIGHT(MID(A5,1,FIND(":",A5)-1),ROW($1:$5)))
末：=-LOOKUP(1,-RIGHT(MID(A5,FIND(":",A5)+1,LEN(A5)-FIND(":",A5)),ROW($1:$5)))

ROW($1:$5)中的5可以改为数字的最大位数，或者直接改为15。

我走我流 · 发表于 2019-2-20 08:55

考虑通用性的话
B列公式 =-LOOKUP(1,-LEFT(REPLACE(SUBSTITUTE(A5,":",),1,MIN(IF(ISNUMBER(-MID(A5,ROW($1:$99),1)),ROW($1:$99)-1)),),ROW($1:$99))) ---数组公式
C列公式
=-LOOKUP(1,-RIGHT(A5,ROW($1:$99)))

		自动登录	找回密码
密码			免费注册

[求助] 分别从A列提取开始和结束行号

评分

评分

评分

评分

评分

评分

评分

最新热点 /1