5万多条数据 查询提示 溢出 求大神帮忙看一下

215351782

下面是代码  运行到蓝字部分 提示溢出
Private Sub UserForm_Initialize()
  Dim r%, i%
  Dim arr, brr
  Dim itm As ListItem
  Dim d2 As Object
  Set d1 = CreateObject("scripting.dictionary")
  Set d2 = CreateObject("scripting.dictionary")
  Set d3 = CreateObject("scripting.dictionary")
  Set d4 = CreateObject("scripting.dictionary")
  With Worksheets("发货账单")
    r = .Cells(.Rows.Count, 1).End(xlUp).Row
    arr = .Range("a2:f" & r)
    For i = 1 To UBound(arr)
      d1(arr(i, 1)) = ""
      d2(arr(i, 4)) = ""
      d3(arr(i, 5)) = ""
      d4(arr(i, 6)) = ""
    Next
  End With
  With Worksheets("客户信息")
    r = .Cells(.Rows.Count, 1).End(xlUp).Row
    arr = .Range("a1:b" & r)
    For i = 1 To UBound(arr)
      If d1.exists(arr(i, 1)) Then
        d1(arr(i, 1)) = arr(i, 2)
      End If
    Next
  End With
  With 发货统计
    .Caption = " 欢迎使用查询统计系统！今天是：" & Format(Date, "yyyy年mm月dd日")
    .ComboBox1.List = d1.keys
    .ComboBox2.List = d2.keys
    .ComboBox3.List = d3.keys
    .ComboBox4.List = d4.keys
    With .ListView1
      lk = .Width
      .View = lvwReport
      .Gridlines = True
      .FullRowSelect = True
      .HotTracking = True
      .OLEDragMode = 1
      .ColumnHeaders.Clear
      .ListItems.Clear
      With .ColumnHeaders
        .Add 1, , Sheets("发货账单").Cells(1, 1), lk / 7
        .Add 2, , Sheets("发货账单").Cells(1, 2), lk / 6, lvwColumnCenter
        .Add 3, , Sheets("发货账单").Cells(1, 3), lk / 8, lvwColumnCenter
        .Add 4, , Sheets("发货账单").Cells(1, 4), lk / 8, lvwColumnCenter
        .Add 5, , Sheets("发货账单").Cells(1, 5), lk / 8, lvwColumnCenter
        .Add 6, , Sheets("发货账单").Cells(1, 6), lk / 6, lvwColumnCenter
        .Add 7, , Sheets("发货账单").Cells(1, 7), lk / 8, lvwColumnCenter
      End With
    End With
  End With
End Sub

fxl447098457

dim i&,r&
定义变量为long试试

opiona

大连数据查询，建议SQL

ww87725244

整型，其范围为 -32,768 到 32,767 之间

风掠无痕

没有例子。

guoxiaozheng

谢谢分享生活愉快

lsc900707

Dim r%, i%行数不能超过32767行，5万多行的话肯定报错。
Dim r&, i&就好。

215351782

已经修改好了 谢谢各位大神了

215351782

lsc900707 发表于 2018-3-18 21:14
Dim r%, i%行数不能超过32767行，5万多行的话肯定报错。
Dim r&, i&就好。

谢谢版主  按你的方法 修改好了