多条件模糊查询

529905149

请问如何实现这样的多条件模糊查询呢？谢谢

abc123281

商品代码是唯一的标识   你只能输入商品代码查询    如果是这样   很容易实现

看见星光

Sub SqlFindData()
    Dim cnn As Object, rst As Object
    Dim Mypath As String, Str_cnn As String, Sql As String
    Dim i As Long, j As Long
    On Error Resume Next
    Set cnn = CreateObject("adodb.connection")
    Mypath = ThisWorkbook.FullName
    Str_cnn = "Provider=Microsoft.ACE.OLEDB.12.0;Extended Properties=Excel 12.0;Data Source=" & Mypath
    cnn.Open Str_cnn
    For j = 1 To 25
        If Len(Cells(3, j).Value) Then Sql = Sql & " AND " & Cells(2, j).Value & " LIKE '%" & Cells(3, j).Value & "%'"
        f = f & ",[" & Cells(2, j).Value & "]"
    Next
    f = Mid(f, 2)
    If Len(Sql) = 0 Then MsgBox "尚未输入任一查询关键值。": Exit Sub
    Sql1 = "(select " & f & " from [数据库1$] union all select " & f & " from [数据库2$])"
    Sql = "SELECT * FROM " & Sql1 & " WHERE " & Mid(Sql, 5)
    Set rst = cnn.Execute(Sql)
    Rows("6:" & Cells.Rows.Count).EntireRow.Delete
    Range("a6").CopyFromRecordset rst
    cnn.Close
    Set cnn = Nothing
End Sub

看见星光

.... 模糊查询求助.rar (24.92 KB, 下载次数: 117)

2018-3-13 11:29 上传

点击文件名下载附件

chengshanming

看见星光 发表于 2018-3-13 11:12
....

大师好！好像这样查询还是查不出结果呢？

看见星光

chengshanming 发表于 2018-3-13 11:45
大师好！好像这样查询还是查不出结果呢？

数据类型的问题，代码修改如下：
Sub SqlFindData()
    Dim cnn As Object, rst As Object
    Dim Mypath As String, Str_cnn As String, Sql As String
    Dim i As Long, j As Long
    On Error Resume Next
    Set cnn = CreateObject("adodb.connection")
    Mypath = ThisWorkbook.FullName
    Str_cnn = "Provider=Microsoft.ACE.OLEDB.12.0;Extended Properties='Excel 12.0;IMEX=1';Data Source=" & Mypath
    cnn.Open Str_cnn
    For j = 1 To 25
        If Len(Cells(3, j).Value) Then Sql = Sql & " AND " & Cells(2, j).Value & " LIKE '%" & Cells(3, j).Value & "%'"
        f = f & ",[" & Cells(2, j).Value & "]"
    Next
    f = Mid(f, 2)
    If Len(Sql) = 0 Then MsgBox "尚未输入任一查询关键值。": Exit Sub
    Sql1 = "(select " & f & " from [数据库1$] union all select " & f & " from [数据库2$])"
    Sql = "SELECT * FROM " & Sql1 & " WHERE " & Mid(Sql, 5)
    Set rst = cnn.Execute(Sql)
    Rows("6:" & Cells.Rows.Count).EntireRow.Delete
    Range("a6").CopyFromRecordset rst
    cnn.Close
    Set cnn = Nothing
End Sub

看见星光

chengshanming 发表于 2018-3-13 11:45
大师好！好像这样查询还是查不出结果呢？

附件参考 模糊查询求助.rar (25.36 KB, 下载次数: 108)

2018-3-13 12:10 上传

点击文件名下载附件

，有问题再看哈~

一把小刀闯天下

Option Explicit

Sub test()
  Dim i, j, k, arr, brr, sht, crr, n, m
  brr = Sheets("查询表").[a3:y3]
  sht = Split("数据库1 数据库2")
  For i = 0 To UBound(sht)
    With Sheets(sht(i))
      crr = .Range("b2:z" & .Cells(Rows.Count, "b").End(xlUp).Row)
      If i = 0 Then ReDim arr(1 To 10 ^ 4, 1 To UBound(crr, 2))
      For j = 1 To UBound(crr, 1)
        n = n + 1
        For k = 1 To UBound(crr, 2)
          arr(n, k) = crr(j, k)
      Next k, j
    End With
  Next
  For i = 1 To n
    For j = 1 To UBound(brr, 2)
      If Len(brr(1, j)) > 0 And brr(1, j) = arr(i, j) Then '满足一项即可，自己修改
        m = m + 1
        For k = 1 To UBound(brr, 2): arr(m, k) = arr(i, k): Next
        Exit For
      End If
  Next j, i
  With Sheets("查询表").[a6]
    .Resize(10 ^ 4, UBound(arr, 2)).ClearContents
    If m > 0 Then .Resize(m, UBound(arr, 2)) = arr
  End With
End Sub

zjdh

简单一点
Sub 高级筛选()
    Sheets("查询表").Range("A6:Y65536").ClearContents
    Sheets("数据库1").Columns("B:Z").AdvancedFilter Action:=xlFilterCopy, _
        CriteriaRange:=Range("A2:Y3"), CopyToRange:=Range("A5:Y5"), Unique:=False
    W = Sheets("查询表").Range("A65536").End(3).Row + 1
    Sheets("数据库2").Columns("B:Z").AdvancedFilter Action:=xlFilterCopy, _
        CriteriaRange:=Range("A2:Y3"), CopyToRange:=Range("A1000:Y1000"), Unique:=False
    Rows(W & ":1000").Delete
End Sub

zjdh

模糊查询求助.rar (22.35 KB, 下载次数: 138)

2018-3-13 14:04 上传

点击文件名下载附件