按姓名拆分成多个工作表

jacking03

求助各位大神，我想把教师工作绩效汇总表按B3单元格中的教师姓名，拆分成以他们名字命名的多个工作表，求大神相助,感激不尽!!!

microyip

使用字典分类即可

jacking03

microyip 发表于 2018-1-20 17:25
使用字典分类即可

恳请大侠赐教!

乐乐2006201505

自己修改一下。
Sub NewShts()
    Dim d As Object, sht As Worksheet, arr, brr, r, kr, i&, j&, k&, x&
    Dim Rng As Range, Rg As Range, tRow&, tCol&, aCol&, pd&
    Application.ScreenUpdating = False '关闭屏幕更新
    Application.DisplayAlerts = False '关闭警告信息提示
    Set d = CreateObject("scripting.dictionary") 'set字典
    Set Rg = Application.InputBox("请框选拆分依据列！只能选择单列单元格区域！", Title:="提示", Type:=8)
    '用户选择的拆分依据列
    tCol = Rg.Column '取拆分依据列列标
    tRow = Val(Application.InputBox("请输入总表标题行的行数？"))
    '用户设置总表的标题行数
    If tRow = 0 Then MsgBox "你未输入标题行行数，程序退出。": Exit Sub
    Set Rng = ActiveSheet.UsedRange '总表的数据区域
    arr = Rng '数据范围装入数组arr
    tCol = tCol - Rng.Column + 1 '计算依据列在数组中的位置
    aCol = UBound(arr, 2) '数据源的列数
    For i = tRow + 1 To UBound(arr) '遍历数组arr
        If Not d.exists(arr(i, tCol)) Then
            d(arr(i, tCol)) = i '字典中不存在关键词则将行号装入字典
        Else
            d(arr(i, tCol)) = d(arr(i, tCol)) & "," & i '如果存在则合并行号，以逗号间隔
        End If
    Next
    For Each sht In Worksheets '遍历一遍工作表，如果字典中存在则删除
        If d.exists(sht.Name) Then sht.Delete
    Next
    kr = d.keys '字典的key集
    For i = 0 To UBound(kr) '遍历字典key值
        If kr(i) <> "" Then '如果key不为空
            r = Split(d(kr(i)), ",") '取出item里储存的行号
            ReDim brr(1 To UBound(r) + 1, 1 To aCol) '声明放置结果的数组brr
            k = 0
            For x = 0 To UBound(r)
                k = k + 1 '累加记录行数
                For j = 1 To aCol '循环读取列
                    brr(k, j) = arr(r(x), j)
                Next
            Next
            With Worksheets.Add(, Sheets(Sheets.Count))
            '新建一个工作表，位置在所有已存在sheet的后面
                .Name = kr(i) '表格命名
                .[a1].Resize(tRow, aCol) = arr '放标题行
                .[a1].Offset(tRow, 0).Resize(k, aCol) = brr '放置数据区域
                Rng.Copy '复制粘贴总表的格式
                .[a1].PasteSpecial Paste:=xlPasteFormats, Operation:=xlNone, SkipBlanks:=False, Transpose:=False
                .[a1].Select
            End With
        End If
    Next
    Sheets(1).Activate '激活第一个表格
    Set d = Nothing '释放字典
    Erase arr: Erase brr '释放数组
    MsgBox "数据拆分完成！"
    Application.ScreenUpdating = True '恢复屏幕更新
    Application.DisplayAlerts = True '恢复警示
End Sub

jacking03

乐乐2006201505 发表于 2018-1-20 18:26
自己修改一下。
Sub NewShts()
    Dim d As Object, sht As Worksheet, arr, brr, r, kr, i&, j&, k&, x ...

谢谢乐乐大侠!!

jacking03

乐乐2006201505 发表于 2018-1-20 18:26
自己修改一下。
Sub NewShts()
    Dim d As Object, sht As Worksheet, arr, brr, r, kr, i&, j&, k&, x ...

大侠，我还不会使用，拆分时如何按名字作为工作表名称，另外拆分时可以另建一个新表格吗，把拆分的表格全部放在这张新表中，谢谢

乐乐2006201505

jacking03 发表于 2018-1-20 20:25
大侠，我还不会使用，拆分时如何按名字作为工作表名称，另外拆分时可以另建一个新表格吗，把拆分的表格全 ...

Sub 表格复制()
    Dim i As Integer
    Application.ScreenUpdating = False
    r = Sheets(2).Cells(Rows.Count, 4).End(3).Row
    For i = 2 To r
        Sheets(3).Copy after:=Sheets(Sheets.Count)
        With ActiveSheet
            .Range("B3") = Sheets(2).Range("d" & i)
            .Name = i
        End With
    Next i
    MsgBox "表格复制完毕！"
    Application.ScreenUpdating = True
End Sub
用下面代码。
Sub 表格复制()
    Dim i As Integer
    Application.ScreenUpdating = False
    r = Sheets(2).Cells(Rows.Count, 4).End(3).Row
    For i = 2 To r
        Sheets(3).Copy after:=Sheets(Sheets.Count)
        With ActiveSheet
            .Range("B3") = Sheets(2).Range("d" & i)
            .Range("D3") = Sheets(2).Range("e" & i)
            .Range("H3") = Sheets(2).Range("f" & i)
            .Name = i
        End With
    Next i
    MsgBox "表格复制完毕！"
    Application.ScreenUpdating = True
End Sub

jacking03

乐乐2006201505 发表于 2018-1-20 21:11
Sub 表格复制()
    Dim i As Integer
    Application.ScreenUpdating = False

汇总表中有用到Vlookup 函数，当点击b3单元格时，其他跟B3单元格有关的信息自动匹配到表格中，拆分时要同时能自动匹配得上

t7856

建议看一下EXCELHome出的<EXCEL-SQL>那本书，数据使用SQL语句的distinct确定组数，按组group by以后，按照数据集复制到新的sheet中。