关于数值提取的问题

keron911 · 发表于 2017-8-12 10:48

本帖最后由 keron911 于 2017-8-12 10:51 编辑

请教一下，如下编号，提取最后4或5位数值，去掉最后一位字母的结果：
AUR-05-1258 提取 1258
TYU-S-05-2587A 提取2587
OPI-01-1998D 提取1998
W-1857 提取1857
N-W-1857A 提取1857

SU-02-22105 提取22105
SU-S-03-21105 提取21105

keron911 · 发表于 2017-8-12 10:49

SU-02-22105 提取22105

梦幻小丑 · 发表于 2017-8-12 11:15

=ABS(RIGHT(LEFT(A1,LEN(A1)-(RIGHT(A1)>"9")),5))

复制代码

yuqiang123 · 发表于 2017-8-12 11:17

提示: 作者被禁止或删除内容自动屏蔽

准提部林 · 发表于 2017-8-12 11:50

=ABS(LEFT(RIGHT(A1,5),5-(RIGHT(A1)>"9")))

有０開頭的？？
=SUBSTITUTE(LEFT(RIGHT(A1,5),5-(RIGHT(A1)>"9")),"-",)
　
　

佛山小老鼠 · 发表于 2017-8-13 09:39

=LEFT(MID(A1,MATCH(1,0/(MID(A1,ROW($1:99),1)="-"))+1,99)&"A",COUNT(-LEFT(MID(A1,MATCH(1,0/(MID(A1,ROW($1:99),1)="-"))+1,99)&"A",ROW($1:$99))))

复制代码

佛山小老鼠 · 发表于 2017-8-13 09:43

本帖最后由佛山小老鼠于 2017-8-13 09:44 编辑

这种解法短一点

=MID(-LOOKUP(1,-(1&LEFT(TRIM(RIGHT(SUBSTITUTE(A1,"-",REPT(" ",99)),99)),ROW($1:$99)))),2,99)

复制代码

wow08121 · 发表于 2017-8-13 10:00

准提部林发表于 2017-8-12 11:50
=ABS(LEFT(RIGHT(A1,5),5-(RIGHT(A1)>"9")))

有０開頭的？？

请问RIGHT(A1)>"9"这个公式是什么意思，没搞明白

准提部林 · 发表于 2017-8-13 10:13

本帖最后由准提部林于 2017-8-13 10:15 编辑

wow08121 发表于 2017-8-13 10:00
请问RIGHT(A1)>"9"这个公式是什么意思，没搞明白

最右一個字元,
若為"A"~"Z", 必定 >"9",
若為"0"~"9", 則反推，
注意：不可寫為 >9，因為RIGHT取出的是〔文本〕！
　
　

wow08121 · 发表于 2017-8-13 10:22

准提部林发表于 2017-8-13 10:13
最右一個字元,
若為"A"~"Z", 必定 >"9",
若為"0"~"9", 則反推，

谢谢大神，明白！

		自动登录	找回密码
密码			免费注册

yuqiang123 yuqiang123 当前离线性别保密 UID 3446324 阅读权限 0 注册时间 2016-6-9 在线时间小时最后登录 1970-1-1 积分 1056 财富分享技术精华头像被屏蔽 TA的精华主题 TA的得分主题	发表于 2017-8-12 11:17 \| 显示全部楼层 [广告] Excel易用宝 - 提升Excel的操作效率 · Excel / WPS表格插件 ★免费下载 ★ ★ 使用帮助★ 提示: 作者被禁止或删除内容自动屏蔽

	回复举报