如何将字符串中的参数代入字符串公式中进行计算

aman1516

参数格式：总高:1920；总宽:690；吊脚:20；墙厚:190  等
公式格式：总高+37=2 等
如何将字符串中的参数代入字符串公式中进行计算，详见附件： 如何将参数代入字符串公式中进行计算.rar (13.92 KB, 下载次数: 26)

2017-3-4 19:07 上传

点击文件名下载附件

请老师帮忙下，谢谢！

jsgj2023

都看不懂是什么意思,关注!

cbm

楼主只想要单元格内的内容拆分成变量名和变量值吗？

zax010

Sub zz()
    Dim d, ar, br
    Set d = CreateObject("Scripting.Dictionary")
    ar = [j1].CurrentRegion
    br = Range("a1:h" & [e65536].End(3).Row)
    For i = 2 To UBound(ar)
        s = Split(ar(i, 2), "；")
        ReDim aa(1 To UBound(s) + 1, 1 To 2)
        For x = 0 To UBound(s)
            aa(x + 1, 1) = Split(s(x), ":")(0): aa(x + 1, 2) = Split(s(x), ":")(1)
        Next
        d(ar(i, 1)) = aa
    Next
    On Error Resume Next
    For i = 2 To UBound(br)
        If d.exists(br(i, 1)) Then k = d(br(i, 1))
        kk = br(i, 5)
        For x = 1 To UBound(k)
            If InStr(kk, k(x, 1)) Then
                kk = Replace(kk, k(x, 1), k(x, 2))
            End If
        Next
        If InStr(kk, "=") Then
            br(i, 6) = Evaluate(Split(kk, "=")(0))
            br(i, 7) = Val(Split(kk, "=")(1))
            br(i, 8) = br(i, 6) * br(i, 7): kk = ""
        End If
    Next
    [a1].Resize(UBound(br), UBound(br, 2)) = br
End Sub

zax010

如何将参数代入字符串公式中进行计算.rar (20.74 KB, 下载次数: 28)

2017-3-4 22:05 上传

点击文件名下载附件

aman1516

zax010 发表于 2017-3-4 22:05

非常感谢，正是这个意思，忘记说明，若无此参数时，默认为零……烦请老师帮忙再改一下
我之前只想用Split及 InStr进行纯字符串处理再转变量，结果复杂判断绕乱了，公式运算也不知如何转置，
老师的字符串处理与字典数组结合得太完美了，堪称经典！关键是思路决定出路，太利害了，值得好好研究学习了

aman1516

        For x = 1 To UBound(k)
            If InStr(kk, k(x, 1)) Then
                kk = Replace(kk, k(x, 1), k(x, 2))
            End If
        Next
这个是将对应的参数代入公式，但公式中有而参数中无，则要返过来判断一次了，想了个笨办法加入以下代码：
        gg = Split(Replace(Replace(Split(kk, "=")(0), "+", ","), "-", ","), ",")
        For x = 1 To UBound(k)
            ss = ss & k(x, 1)
        Next
        For g = 0 To UBound(gg)
            If Asc(gg(g)) < 0 And Not InStr(ss, gg(g)) Then
               kk = Replace(kk, gg(g), 0)
            End If
        Next
        If InStr(kk, "=") Then
           ………

aman1516

最终结果： 如何将参数代入字符串公式中进行计算.rar (23.61 KB, 下载次数: 26)

2017-3-5 00:16 上传

点击文件名下载附件

zax010

aman1516 发表于 2017-3-5 00:16
最终结果：

你的“返过来判断”办法不错（If Asc(gg(g)) < 0 And Not InStr(ss, gg(g)) Then 是关键语句）。

最初还以为是把那个参数疏漏了。

zax010

aman1516 发表于 2017-3-4 23:24
For x = 1 To UBound(k)
            If InStr(kk, k(x, 1)) Then
                kk = Replace ...

偶然翻看昨天回复帖子的附件，感觉你的返过来判断法还可简化一下：
......................
        gg = Split(Replace(Replace(Split(kk, "=")(0), "+", ","), "-", ","), ",")
        For g = 0 To UBound(gg)
            If IsNumeric(gg(g)) = False Then
               kk = Replace(kk, gg(g), 0)
            End If
        Next
...................

理由：
1、既然后面用Evaluate求值，则gg(g)必须为数字，否则以0替换，避免出错；
2、前面用数组k的元素替换完了kk里的相关内容，则 kk内必无 k的元素内容，直接以1、的方法处理即可，没必要再与数组k的元素比对。
3、Asc(gg(g)) < 0 既用了1、办法，这个条件也无必要了。

其实你的办法已足够用，以上不知对否，仅供参考。