[准提方帖]情人節系列--根據日期條件判斷, 取得相應結果

准提部林

根據送禮及回禮日期，為每對情侶判斷其交往狀況

2月14日(西洋情人節)
3月14日(白色情人節)
你(妳)會在哪個時間表達心意呢？

提前幾天：表示你(妳)希望那天兩個人可以一起做些什麼？

當天吉日：表示你(妳)們已經正在做什麼。

隔天及時：是"晚了"，但還不是"完了"，補救得宜 ，最多被罵：你在忙什麼？

曠日忘時：只讀不回，問天...為什麼？

　

情人節快到了，不要忘了向她(他)表達心意哦！

　

　

基本架構：
１．Ｆ１為〔西洋情人節〕日期：2017/02/14
２．Ａ／Ｂ列為〔送禮〕或〔回禮〕的日期
３．沒有限定男送女，女送男也是可以的
４．送禮的就不會是回禮的，只能為單方
５．有送禮才可能有回禮，但也可能沒有回禮
６．回禮的日期不會小于送禮日期
　
條件判斷：
１【當日來回】．送禮日及回禮日同時＝2/14，以"Ａ"表示
２【早去早回】．送禮日及回禮日同時＜2/14，以"Ｂ"表示
３【早去當回】．送禮日＜2/14，回禮日＝2/14當日，以"Ｃ"表
４【有去晚回】．送禮日＜＝2/14，回禮日＞2/14，以"Ｄ"表示
５【晚去晚回】．送禮日及回禮日同時＞2/14，以"Ｅ"表示
６【有去無回】．有送禮日，沒有回禮日，以"Ｎ"表示
７【午夜夢回】．送禮日及回禮日都缺，以"Ｘ"表示
　
　
參考附件：
TT20170211-01.rar (2.75 KB, 下载次数: 18)

2017-2-11 20:09 上传

点击文件名下载附件

　
請各位高手不吝指教，提供智慧結晶供後進觀摩學習，
公式長短及版本不拘（２００７以上版本恕無法驗證），
鮮花有限，若有遺漏請包涵！
　
　

piny

122字元

1. =CHOOSE(SUM(COUNTIF(A:A,D2:E2))+1,"X","N",MID("BCDA0D00E",PRODUCT(-TEXT(VLOOKUP(T(IF({1},D2:E2)),A:B,2,)-F$1,"3;1;2")),1))

复制代码

118字元

1. =CHOOSE(SUM(COUNTIF(A:A,D2:E2))+1,"X","N",MID("0BCADD0E",SUM(--TEXT(VLOOKUP(T(IF({1},D2:E2)),A:B,2,)-F$1,"4;1;2")),1))

复制代码

113字元 2007版函數

1. =MID("XBCAD0EN",IFERROR(SUM(2,TEXT(VLOOKUP(T(IF({1},D2:E2)),A:B,2,)-F$1,"8;1;3")/3),8^SUM(COUNTIF(A:A,D2:E2))),1)

复制代码

LSL1128xgw

=MID("XBCADDNE",IF(SUM(N(A:A=D2:E2))>1,SUM(--TEXT(SUMIF(A:A,D2:E2,B$1)-F$1,"4;1;2")),SUM(N(A:A=D2:E2))*6+1),1)



=MID("XBCADDNE",TEXT(SUM(N(A:A=D2:E2))-1,""&SUM(--TEXT(SUMIF(A:A,D2:E2,B$1)-F$1,"4;1;2"))&";1;7"),1)

红旗雪

1. =MID("AACBDDEENNNNXXXX",SUM(--TEXT(TEXT(SUMIF(A:A,D2:E2,B:B)-F$1,"[<-4^7]A;-0;0"),"4;2;1;\8")),1)

复制代码

准提部林

piny 发表于 2017-2-12 00:58
122字元

第三式, 我是2003版, 改一下給與我同樣老版本的參考:
=MID("XBCAD0EN",LOOKUP(9,IF({1,0},SUM(2,TEXT(VLOOKUP(T(IF({1},D2:E2)),A:B,2,)-F$1,"8;1;3")/3),8^SUM(COUNTIF(A:A,D2:E2)))),1)

版主是我在奇摩知識+的啟蒙前輩之一, 其公式素為簡短有效,
我出題目的, 以[學習]為主要, 所以, 希望有各種不同解法,
在實務上, 也許就剛好可以運用在這裡學到的東西!

取得[雙日期], 除了 SUMIF , 版主也提供了 VLOOKUP, 這兩個各有妙用, 謝謝!

准提部林

LSL1128xgw 发表于 2017-2-12 09:44
=MID("XBCADDNE",IF(SUM(N(A:A=D2:E2))>1,SUM(--TEXT(SUMIF(A:A,D2:E2,B$1)-F$1,"4;1;2")),SUM(N(A:A=D2:E2 ...

提供了我都還沒想到的解法,
謝謝你的參與~~

准提部林

红旗雪 发表于 2017-2-12 10:48

用兩层TEXT轉換值, 看起來更簡潔,
謝謝你的參與!!

piny

红旗雪 发表于 2017-2-12 10:48

好公式, 搭配原先我的公式, 公式可以再簡

1. =MID("ACBDNENX",SUM(1,TEXT(TEXT(F$1-SUMIF(A:A,D2:E2,B:B),"[>4^7]A;0"),"3;8;1;\1\1")/3),1)

复制代码

象山海鲜

凑合下

1. =MID("AACBBDDNNENNNX",SUM(FREQUENCY(SUMIF(A:A,D2:E2,B:B),F$1-{365,1,0})*{7;2;1;5}),1)

复制代码

最暴力

1. =MID("XNBNCCAAANDDDDDDDDE",SUM(IF(A:A=D2:E2,3^SIGN(B:B-F$1)*3))+1,1)

复制代码

准提部林

象山海鲜 发表于 2017-2-12 13:36
凑合下

最暴力

FREQUENCY 及 SIGN 又是另一仙界極品!!!