ppt学习资料

weiyingde · 发表于 2015-12-12 18:10

Arrange方法
在工作空间排列所有打开的文档窗口。
expression.Arrange(arrangeStyle)
expression  必选。该表达式返回“应用于”列表中的对象之一。
arrangeStyle  可选。PpArrangeStyle 类型。指定窗口的排列方式是层叠还是平铺。
PpArrangeStyle 可以是下列 PpArrangeStyle 类型常数之一。
ppArrangeCascade
ppArrangeTiled 默认值
VBA示例
本示例创建一个新窗口，然后排列所有打开的文档窗口。
Application.ActiveWindow.NewWindow
Windows.Arrange ppArrangeCascade
AutomaticLength方法
指定在移动标注时标注线的第一段（附加到文本标注框的段）自动缩放。使用CustomLength方法指定在移动标注时标注线的第一段保持由Length属性返回的固定长度。仅应用于标注线包含多段的标注（msoCalloutThree 和 msoCalloutFour 类型）。
expression.AutomaticLength
expression  必选。该表达式返回一个 CalloutFormat对象。
说明
应用此方法会将AutoLength属性设为 True。
VBA示例
本示例用来切换使第一段的长度可以调整或使用myDocument 上第一个形状标注线的固定长度。要执行本示例，第一个形状必须是标注。
Set myDocument = ActivePresentation.Slides(1)
With myDocument.Shapes(1).Callout
If .AutoLength Then
      .CustomLength 50
Else
      .AutomaticLength
End If
End With
Background方法
指定形状的填充与幻灯片背景相匹配。如果将此方法应用于填充后又更改了幻灯片背景色，该填充会随之改变。
说明
请注意，将 Background方法应用于形状的填充与设置该形状的透明填充不完全相同，也不完全等同于将形状填充设为与背景相同。请参见第二个示例。
VBA示例
本示例将活动演示文稿第一张幻灯片第一个形状的填充设为与幻灯片背景相匹配。
ActivePresentation.Slides(1).Shapes(1).Fill.Background
本示例将活动演示文稿第一张幻灯片的背景设为一个预设的过渡填充，在幻灯片中添加一个矩形，然后在该矩形前面放置三个椭圆。第一个椭圆的填充与幻灯片背景相匹配，第二个的填充为透明，而第三个使用的填充方式与背景相同。请注意三个椭圆外观的不同。
With ActivePresentation.Slides(1)
.FollowMasterBackground = False
.Background.Fill.PresetGradient _
      msoGradientHorizontal, 1, msoGradientDaybreak
With .Shapes
      .AddShape msoShapeRectangle, 50, 200, 600, 100
      .AddShape(msoShapeOval, 75, 150, 150, 100) _
         .Fill.Background
      .AddShape(msoShapeOval, 275, 150, 150, 100).Fill _
         .Transparency = 1
      .AddShape(msoShapeOval, 475, 150, 150, 100) _
         .Fill.PresetGradient _
         msoGradientHorizontal, 1, msoGradientDaybreak
End With
End With
BeginConnect方法
将指定连接符的起点附加到指定形状。如果该连接符的起点已经连接到另一个形状，则断开原连接；如果该连接符起点没有位于指定的连接位置，此方法将它移到该位置，并调整连接符的大小和位置。使用EndConnect方法将连接符的终点附加到形状。
expression.BeginConnect(ConnectedShape, ConnectionSite)
expression  必选。该表达式返回一个 ConnectorFormat对象。
ConnectedShape 必选。Shape对象。将连接符起点附加到的形状。指定的 Shape对象必须与该连接符在同一 Shapes集合内。
ConnectionSite  必选。Long 类型。由 ConnectedShape 指定的形状上的连接位置。必须是从 1 到指定形状的 ConnectionSiteCount属性返回值之间的一个整数。如果要连接符自动选取两个形状间的最短路径，请为此参数指定任何有效整数值，并在连接符的两端都连到形状之后使用RerouteConnections方法。
说明
将连接符附加到对象后，如有必要，会自动调整该连接符的大小和位置。
VBA示例
本示例将两个矩形框添加到活动演示文稿第一张幻灯片，并用曲线连接符将它们连接。请注意 RerouteConnections方法使应用于 ConnectionSite参数的值与 BeginConnect 和 EndConnect方法无关。
Set myDocument = ActivePresentation.Slides(1)
Set s = myDocument.Shapes
Set firstRect = s.AddShape(msoShapeRectangle, 100, 50, 200, 100)
Set secondRect = s.AddShape(msoShapeRectangle, 300, 300, 200, 100)
With s.AddConnector(msoConnectorCurve, 0, 0, 100, 100) _
      .ConnectorFormat
.BeginConnect ConnectedShape:=firstRect, ConnectionSite:=1
.EndConnect ConnectedShape:=secondRect, ConnectionSite:=1
.Parent.RerouteConnections
End With

weiyingde · 发表于 2015-12-12 18:11

BeginDisconnect方法
将指定的连接符起点与所连接的形状断开。该方法不改变该连接符的大小或位置。该连接符起点仍然在连接位置上，但已不再相连。使用EndDisconnect方法将连接符的终点与形状断开。
expression.BeginDisconnect
expression  必选。该表达式返回一个 ConnectorFormat对象。
VBA示例
本示例将两个矩形框添加到当前演示文稿第一张幻灯片，用连接符将它们连接，并自动地把连接符的路径修改为最短路径，然后断开连接符与矩形框之间的连接。
Set myDocument = ActivePresentation.Slides(1)
Set s = myDocument.Shapes
Set firstRect = s.AddShape(msoShapeRectangle, 100, 50, 200, 100)
Set secondRect = s.AddShape(msoShapeRectangle, 300, 300, 200, 100)
With s.AddConnector(msoConnectorCurve, 0, 0, 0, 0).ConnectorFormat
.BeginConnect firstRect, 1
.EndConnect secondRect, 1
.Parent.RerouteConnections
.BeginDisconnect
.EndDisconnect
End With
BuildFreeform方法
创建一个任意多边形对象。创建时返回一个代表该任意多边形的FreeformBuilder对象。使用AddNodes方法向该任意多边形添加段。向该任意多边形添加至少一个段后，就可以使用ConvertToShape方法将 FreeformBuilder对象转化为一个Shape对象，该对象具有在 FreeformBuilder对象中定义的几何说明。
expression.BuildFreeform(EditingType, X1, Y1)
expression  必选。该表达式返回“应用于”列表中的对象之一。
EditingType  必选。MsoEditingType 类型。第一个结点的编辑属性。
MsoEditingType 可以是下列 MsoEditingType 类型常数之一（不能是 msoEditingSmooth 或 msoEditingSymmetric）。
msoEditingAuto
msoEditingCorner
X1  必选。Single 类型。任意多边形第一个结点相对于幻灯片左边缘的水平位置（以磅为单位）。
Y1  必选。Single 类型。任意多边形第一个结点相对于幻灯片上边缘的垂直位置（以磅为单位）。
VBA示例
本示例向myDocument 中添加具有四个段的任意多边形。
Set myDocument = ActivePresentation.Slides(1)
With myDocument.Shapes.BuildFreeform(EditingType:=msoEditingCorner, _
X1=360, Y1=200)
.AddNodes SegmentType:=msoSegmentCurve, EditingType:=msoEditingCorner, _
      X1:=380, Y1:=230, X2:=400, Y2:=250, X3:=450, Y3:=300
.AddNodes SegmentType:=msoSegmentCurve, EditingType:=msoEditingAuto, _
      X1:=480, Y1:=200
.AddNodes SegmentType:=msoSegmentLine, EditingType:=msoEditingAuto, _
      X1:=480, Y1:=400
.AddNodes SegmentType:=msoSegmentLine, EditingType:=msoEditingAuto, _
      X1:=360, Y1:=200
.ConvertToShape
End With
CanCheckIn方法
值为 True 时，Microsoft PowerPoint 可以将指定的演示文稿签入到服务器。可读写。Boolean 类型。
expression.CanCheckIn
expression  必选。该表达式返回“应用于”列表中的对象之一。
说明
若要利用 PowerPoint 中的协作功能，演示文稿必须保存在 Microsoft SharePoint Portal Server 上。
VBA示例
本示例检查服务器是否可以签入指定的演示文稿；如果可以，它将关闭此演示文稿并且将其签回到服务器中。
Sub CheckInPresentation(strPresentation As String)
If Presentations(strPresentation).CanCheckIn = True Then
      Presentations(strPresentation).CheckIn
      MsgBox strPresentation & " has been checked in."
Else
      MsgBox strPresentation & " cannot be checked in " & _
      "at this time.  Please try again later."
End If
End Sub
若要调用上述子程序，请使用下列子程序并用在上面说明部分中提到的服务器上的实际文件替换“http://servername/workspace/report.ppt”文件名。
Sub CheckPPTIn()
Call CheckInPresentation(strPresentation:= _
      "http://servername/workspace/report.ppt")
End Sub

weiyingde · 发表于 2015-12-12 18:11

CanCheckOut方法
值为 True 时，Microsoft PowerPoint 可以将指定的演示文稿从服务器签出。可读写。Boolean 类型。
expression.CanCheckOut(FileName)
expression  必选。该表达式返回“应用于”列表中的对象之一。
FileName  必选。String 类型。演示文稿的服务器路径和名称。
说明
若要利用 PowerPoint 中的协作功能，演示文稿必须保存在 Microsoft SharePoint Portal Server 上。
VBA示例
本示例验证演示文稿是否可以签出且未被其他用户签出。如果演示文稿可以签出，则将演示文稿复制到本地计算机以进行编辑。
Sub CheckOutPresentation(strPresentation As String)
If Presentations.CanCheckOut(strPresentation) = True Then
      Presentations.CheckOut FileName:=strPresentation
Else
      MsgBox "You are unable to check out this " & _
      "presentation at this time."
End If
End Sub
若要调用上述子程序，请使用下列子程序并用在上面说明部分中提到的服务器上的实际文件替换“http://servername/workspace/report.ppt”文件名。
Sub CheckPPTOut()
Call CheckOutPresentation(strPresentation:= _
      "http://servername/workspace/report.doc")
End Sub
Cell方法
expression.Cell(Row, Column)
expression  必选。返回 Table对象的表达式。
Row  必选。Long 类型。表格中将要返回的行数。其值是一个整数，最小值为 1，最大不超过表格中的行数。
Column  必选。Long 类型。表格中将要返回的列数。其值是一个整数，最小值为 1，最大不超过表格中的列数。
VBA示例
本示例在新演示文稿的新幻灯片上创建一个 3x3 的表格，并向表格的第一个单元格中插入文本。
With Presentations.Add
With .Slides.Add(1, ppLayoutBlank)
      .Shapes.AddTable(3, 3).Select
      .Shapes(1).Table.Cell(1, 1).Shape.TextFrame _
         .TextRange.Text = "Cell 1"
End With
End With
本示例将第二行第一列单元格的下边框粗细设置为 2 磅。
ActivePresentation.Slides(2).Shapes(5).Table _
.Cell(2, 1).Borders(ppBorderBottom).Weight = 2
ChangeCase方法
改变指定文本的大小写。
expression.ChangeCase(Type)
expression  必选。该表达式返回一个 TextRange对象。
Type  必选。PpChangeCase 类型。指定更改大小写的方法。
PpChangeCase 可以是下列 PpChangeCase 类型常数之一。
ppCaseLower
ppCaseSentence
ppCaseTitle
ppCaseToggle
ppCaseUpper
VBA示例
本示例将活动演示文稿的第一张幻灯片的标题设为大写。
Application.ActivePresentation.Slides(1).Shapes.Title.TextFrame _
.TextRange.ChangeCase ppCaseTitle
Characters方法
返回一个 TextRange对象，该对象代表指定字符的子字符串。关于计算或浏览一段文本中字符的详细信息，请参阅TextRange对象。
expression.Characters(Start, Length)
expression  必选。该表达式返回一个 TextRange对象。
Start  可选。Long 类型。返回的文本区域的第一个字符。
Length  可选。Long 类型。要返回的字符数。
说明
如果省略 Start参数和 Length参数，返回的内容为指定组中第一个字符到最后一段。
如果指定 Start参数但省略 Length参数，返回的内容为一个字符。
如果指定 Length参数但省略 Start参数，返回的内容从指定组的第一个字符开始。
如果 Start参数大于指定文本中的字符数，返回的内容从指定组的最后一个字符开始。
如果 Length参数大于文本中从指定的起始字符到文本末尾的字符数，返回的内容包括全部字符。
VBA示例
本示例设置活动演示文稿中第一张幻灯片的第二个形状的文本，并将第二个字符设为偏移 20% 的下标。
Dim charRange As TextRange
With Application.ActivePresentation.Slides(1).Shapes(2)
Set charRange = .TextFrame.TextRange.InsertBefore("H2O")
charRange.Characters(2).Font.BaselineOffset = -0.2
End With
本示例将第一张幻灯片上第二个形状的所有下标字符的格式设为加粗。
With Application.ActivePresentation.Slides(1).Shapes(2) _
.TextFrame.TextRange
For i = 1 To .Characters.Count
      With .Characters(i).Font
         If .Subscript Then .Bold = True
      End With
Next
End With

weiyingde · 发表于 2015-12-12 18:12

CheckIn方法
从本地计算机将演示文稿返回到服务器，并且设置本地文件为只读，以便使得其不能在本地编辑。
expression.CheckIn(SaveChanges, Comments, MakePublic)
expression  必选。该表达式返回“应用于”列表中的对象之一。
SaveChanges  可选。Boolean 类型。值为 True 时，将演示文稿保存到服务器上相应的位置。默认值为 False。
Comments  可选。Variant 类型。被签入的演示文稿的版本注释（仅在 SaveChanges 为 True 时应用）。
MakePublic  可选。Variant 类型。值为 True 时，允许用户在签入之后完成对演示文稿的发布。这会将文档提交给批准过程，它最终会导致给拥有只读权限的用户发布一种版本的演示文稿。（仅在 SaveChanges 为 True 时应用）。
说明
若要利用 Microsoft PowerPoint 中的协作功能，演示文稿必须保存在 Microsoft SharePoint Portal Server 上。
VBA示例
本示例检查服务器是否可以签入指定的演示文稿；如果可以，它将关闭此演示文稿并且将其签回到服务器中。
Sub CheckInPresentation(strPresentation As String)
If Presentations(strPresentation).CanCheckIn = True Then
      Presentations(strPresentation).CheckIn
      MsgBox strPresentation & " has been checked in."
Else
      MsgBox strPresentation & " cannot be checked in " & _
      "at this time.  Please try again later."
End If
End Sub
若要调用上述子程序，请使用下列子程序并用在上面说明部分中提到的服务器上的实际文件替换“http://servername/workspace/report.ppt”文件名。
Sub CheckInPresentation()
Call CheckInPresentation(strPresentation:= _
      "http://servername/workspace/report.ppt")
End Sub
CheckOut方法
从服务器向本地计算机复制指定演示文稿以进行编辑。返回表示签出演示文稿的本地路径和文件名的 String 类型值。
expression.CheckOut(FileName)
expression  必选。该表达式返回“应用于”列表中的对象之一。
FileName  必选。String 类型。演示文稿的服务器路径和名称。
说明
若要利用 Microsoft PowerPoint 中的协作功能，演示文稿必须保存在 Microsoft SharePoint Portal Server 上。
VBA示例
本示例验证演示文稿是否可以签出且未被其他用户签出。如果演示文稿可以签出，则将演示文稿复制到本地计算机以进行编辑。
Sub CheckOutPresentation(strPresentation As String)
Dim strFileName As String
With Presentations
If .CanCheckOut(strPresentation) = True Then
      .CheckOut FileName:=strPresentation
      .Open FileName:=strFileName
Else
      MsgBox "You are unable to check out this " & _
      "presentation at this time."
End If
End Sub
若要调用上述子程序，请使用下列子程序并用在上面说明部分中提到的服务器上的实际文件替换“http://servername/workspace/report.ppt”文件名。
Sub CheckPPTOut()
Call CheckOutPresentation(strPresentation:= _
      "http://servername/workspace/report.doc")
End Sub

weiyingde · 发表于 2015-12-13 12:15

Clear方法
从标尺中清除指定的制表位并将其从 TabStops集合中删除。
VBA示例
本示例清除活动演示文稿中第一张幻灯片的第二个形状的文本中的所有制表位。
With Application.ActivePresentation.Slides(1).Shapes(2).TextFrame _
.Ruler.TabStops
For i = .Count To 1 Step -1
      .Item(i).Clear
Next
End With
ClearAll方法
从 PrintRanges集合中清除所有打印范围。使用 PrintRanges集合的Add方法向集合添加打印范围。
expression.ClearAll
expression  必选。该表达式返回一个 PrintRange对象。
VBA示例
本示例清除活动演示文稿中所有以前定义的打印范围；创建新的打印范围，其中包含第一张，第三张到第五张，第八张和第九张幻灯片；打印新定义的幻灯片范围；然后清除新定义的打印范围。
With ActivePresentation.PrintOptions
.RangeType = ppPrintSlideRange
With .Ranges
      .ClearAll
      .Add 1, 1
      .Add 3, 5
      .Add 8, 9
      .Parent.Parent.PrintOut
      .ClearAll
End With
End With
Clone方法
应用于 Designs对象的 Clone方法。
创建Design对象的副本。
expression.Clone(pOriginal, Index)
expression  必选。该表达式返回一个Designs对象。
pOriginal  必选。Design对象。原始设计。
Index  可选。Long 类型。将设计复制到其中的 Designs集合中的索引位置。如果忽略 Index，复制的设计将被添加到 Designs集合的末尾。
应用于 Sequence对象的 Clone方法。
创建Effect对象的副本，并按指定索引将其添加到Sequences集合中。
expression.Clone(Effect, Index)
expression  必选。该表达式返回一个Sequence对象。
Effect  必选。Effect 类型。要复制的动画效果。
Index  可选。Long 类型。将复制的动画效果添加到 Sequences集合中的位置。默认值为 -1（添加到末尾）。
VBA示例
应用于 Designs对象。
本示例创建一个设计并复制一个新建的设计。
Sub CloneDesign()
Dim dsnDesign1 As Design
Dim dsnDesign2
Set dsnDesign1 = ActivePresentation.Designs _
      .Add(designName:="Design1")
Set dsnDesign2 = ActivePresentation.Designs _
      .Clone(pOriginal:=dsnDesign1, Index:=1)
End Sub
应用于 Sequence对象。
本示例复制一个动画效果。本示例假定存在一个名为“effDiamond”的动画效果。
Sub CloneEffect()
ActivePresentation.Slides(1).TimeLine.MainSequence _
      .Clone Effect:=effDiamond, Index:=-1
End Sub

weiyingde · 发表于 2015-12-13 12:15

CloneNode方法
复制图示节点。
expression.CloneNode(CopyChildren, TargetNode, Pos)
expression 必选。该表达式返回“应用于”列表中的对象之一。
CopyChildren 必选。Boolean 类型。如果参数为 True，则包含图示子节点。
TargetNode 可选。DiagramNode对象。该表达式返回一个 DiagramNode对象，它将作为已复制的图示节点的源节点。
Pos 可选。MsoRelativeNodePosition 类型。如果已指定 TargetNode，则指定的值表示新添加的节点相对于 TargetNode 的位置。
MsoRelativeNodePosition 可以是下列 MsoRelativeNodePosition 常数之一。
msoAfterLastSibling
msoAfterNode 默认值
msoBeforeFirstSibling
msoBeforeNode
VBA示例
以下示例创建一个图示并复制一个最新创建的节点。
Sub CloneANode()
Dim dgnNode As DiagramNode
Dim shpDiagram As Shape
Dim intNodes As Integer
'Adds cycle diagram and first child node
Set shpDiagram = ActivePresentation.Slides(1).Shapes.AddDiagram _
      (Type:=msoDiagramCycle, Left:=10, Top:=15, _
      Width:=400, Height:=475)
Set dgnNode = shpDiagram.DiagramNode.Children.AddNode
'Adds three additional nodes to diagram
For intNodes = 1 To 3
      dgnNode.AddNode
Next intNodes
'Automatically formats the diagram
dgnNode.Diagram.AutoFormat = msoTrue
'Clones the first child node without cloning associated child nodes
dgnNode.CloneNode CopyChildren:=False
End Sub
Close方法
关闭指定的文档窗口、演示文稿或打开的任意多边形。
警告  使用此方法，PowerPoint 关闭打开的演示文档，并且不提示用户保存所做的工作。为防止工作丢失，您应在使用 Close方法之前使用 Save 或 SaveAs方法。
expression.Close
expression  必选。该表达式返回一个 DocumentWindow 或 Presentation对象。
VBA示例
本示例关闭除活动窗口外的所有窗口。
With Application.Windows
For i = 2 To .Count
      .Item(i).Close
Next
End With
本示例不保存更改，关闭 Pres1.ppt 文件。
With Application.Presentations("pres1.ppt")
.Saved = True
.Close
End With
本示例关闭所有打开的演示文稿。
With Application.Presentations
For i = .Count To 1 Step -1
      .Item(i).Close
Next
End With
Colors方法
返回一个RGBColor对象，该对象代表配色方案中的一种颜色。
expression.Colors(SchemeColor)
expression  必选。该表达式返回一个 ColorScheme对象。
SchemeColor  必选。PpColorSchemeIndex 类型。指定的配色方案中的一种颜色。
PpColorSchemeIndex 可以是下列 PpColorSchemeIndex 类型常数之一。
ppAccent1
ppAccent2
ppAccent3
ppBackground
ppFill
ppForeground
ppNotSchemeColor
ppSchemeColorMixed
ppShadow
ppTitle
VBA示例
本示例设置活动演示文稿中第一张和第三张幻灯片的标题颜色。
Set mySlides = ActivePresentation.Slides.Range(Array(1, 3))
mySlides.ColorScheme.Colors(ppTitle).RGB = RGB(0, 255, 0)

weiyingde · 发表于 2015-12-13 12:16

Convert方法
将图示转换为另一种类型。
expression.Convert(Type)
expression 必选。该表达式返回“应用于”列表中的对象之一。
Type 必选。MsoDiagramType 类型。要转换的图示类型。
MsoDiagramType 可以是下列 MsoDiagramType 类型常数之一。
msoDiagramCycle
msoDiagramMixed
msoDiagramOrgChart
msoDiagramPyramid
msoDiagramRadial
msoDiagramTarget
msoDiagramVenn
说明
如果目标图示的Type属性值为一组织结构图 (msoDiagramTypeOrgChart)，该方法将产生一个错误。
VBA示例
以下示例将一个棱锥图添加到幻灯片中并将其转换为射线图。
Sub ConvertPyramidDiagram()
Dim dgnNode As DiagramNode
Dim shpDiagram As Shape
Dim intNodes As Integer
'Adds pryamid diagra and first child node
Set shpDiagram = ActivePresentation.Slides(1).Shapes.AddDiagram _
      (Type:=msoDiagramPyramid, Left:=10, Top:=15, _
      Width:=400, Height:=475)
Set dgnNode = shpDiagram.DiagramNode.Children.AddNode
'Adds three additional child nodes
For intNodes = 1 To 3
      dgnNode.AddNode
Next intNodes
'Automatically formats the diagram and converts it to a radial diagram
With dgnNode.Diagram
      .AutoFormat = msoTrue
      .Convert  Type:=msoDiagramRadial
End With
End Sub
ConvertToAfterEffect方法
指定效果结束后的变化。返回一个代表动画播放后效果的Effect对象。
expression.ConvertToAfterEffect(Effect, After, DimColor, DimSchemeColor)
expression  必选。该表达式返回一个Sequence对象。
Effect  必选。Effect对象。将添加动画播放后效果的效果。
After  必选。MsoAnimAfterEffect 类型。动画播放后效果的动作。
MsoAnimAfterEffect 可以是下列 MsoAnimAfterEffect 类型常数之一。
msoAnimAfterEffectDim
msoAnimAfterEffectHide
msoAnimAfterEffectHideOnNextClick
msoAnimAfterEffectMixed
msoAnimAfterEffectNone
DimColor  可选。MsoRGBType 类型。应用动画播放后效果的单种颜色。
DimSchemeColor  可选。PpColorSchemeIndex 类型。应用于动画播放后效果的预定义配色方案。
PpColorSchemeIndex 可以是下列 PpColorSchemeIndex 类型常数之一。
ppAccent1
ppAccent2
ppAccent3
ppBackground
ppFill
ppForeground
ppNotSchemeColor 默认值
ppSchemeColorMixed
ppShadow
ppTitle
说明
在此方法的一次调用中不能同时使用 DimColor 和 DimSchemeColor参数。动画播放后效果可能具有一种颜色，或使用预定义配色方案，但不能同时使用这两种颜色。
VBA示例
以下示例为当前演示文稿中第一张幻灯片第一个形状上的动画播放后效果设置一种暗色。本示例假定第一张幻灯片中有一个形状。
Sub ConvertToDim()
Dim shpSelected As Shape
Dim sldActive As Slide
Dim effConvert As Effect
Set sldActive = ActivePresentation.Slides(1)
Set shpSelected = sldActive.Shapes(1)
' Add an animation effect.
Set effConvert = sldActive.TimeLine.MainSequence.AddEffect _
      (Shape:=shpSelected, effectId:=msoAnimEffectBounce)
' Add a dim after effect.
Set effConvert = sldActive.TimeLine.MainSequence.ConvertToAfterEffect _
      (Effect:=effConvert, After:=msoAnimAfterEffectDim, _
      DimColor:=RGB(Red:=255, Green:=255, Blue:=255))
End Sub

weiyingde · 发表于 2015-12-13 12:17

ConvertToAnimateBackground方法
确定背景是否脱离文本单独动画显示。返回一个Effect对象，该对象代表一个刚修改过的动画效果。
expression.ConvertToAnimateBackground(Effect, AnimateBackground)
expression  必选。该表达式返回一个Sequence对象。
Effect  必选。Effect 类型。应用于该背景的动画效果。
AnimateBackground  必选。MsoTriState 类型。确定文本是否脱离背景单独动画显示。
MsoTriState 可以是下列 MsoTriState 类型常数之一。
msoCTrue
msoFalse 脱离背景单独动画显示文本。
msoTriStateMixed
msoTriStateToggle
msoTrue 背景与文本一同动画显示。
VBA示例
本示例为当前演示文稿中第一张幻灯片的第一个形状创建一个文本效果，并脱离背景单独动画显示该文本。本示例假定第一张幻灯片上有一个形状，并且该形状内具有文本。
Sub AnimateText()
Dim timeMain As TimeLine
Dim shpActive As Shape
Set shpActive = ActivePresentation.Slides(1).Shapes(1)
Set timeMain = ActivePresentation.Slides(1).TimeLine
' Add a blast effect to the text, and animate the text separately
' from the background.
timeMain.MainSequence.ConvertToAnimateBackground _
      Effect:=timeMain.MainSequence.AddEffect(Shape:=shpActive, _
         effectid:=msoAnimEffectBlast), _
      AnimateBackGround:=msoFalse
End Sub
ConvertToAnimateInReverse方法
确定文本是否按相反的顺序动画显示。返回一个代表文本动画的Effect对象。
expression.ConvertToAnimateInReverse(Effect, animateInReverse)
expression  必选。该表达式返回一个Sequence对象。
Effect  必选。Effect 类型。应用反向的动画效果。
animateInReverse  必选。MsoTriState 类型。确定文本动画的顺序。
MsoTriState 可以是下列 MsoTriState 类型常数之一。
msoCTrue
msoFalse 文本按正常顺序动画显示。
msoTriStateMixed
msoTriStateToggle
msoTrue 文本按相反顺序动画显示。
VBA示例
本示例在幻灯片上创建一个带文本的形状并向该形状中添加一个随机动画，并确保形状的文本按相反顺序动画显示。
Sub AnimateInReverse()
Dim sldActive As Slide
Dim timeMain As TimeLine
Dim shpRect As Shape
' Create a slide, add a rectangular shape to the slide, and
' access the slide's animation timeline.
With ActivePresentation
      Set sldActive = .Slides.Add(Index:=1, Layout:=ppLayoutBlank)
      Set shpRect = sldActive.Shapes.AddShape(Type:=msoShapeRectangle, _
         Left:=100, Top:=100, Width:=300, Height:=150)
      Set timeMain = sldActive.TimeLine
End With
shpRect.TextFrame.TextRange.Text = "This is a rectangle."
' Add a random animation effect to the rectangle,
' and animate the text in reverse.
With timeMain.MainSequence
      .ConvertToAnimateInReverse _
         Effect:=.AddEffect(Shape:=shpRect, effectId:=msoAnimEffectRandom), _
         AnimateInReverse:=msoTrue
End With
End Sub

weiyingde · 发表于 2015-12-13 12:17

ConvertToBuildLevel方法
更改指定动画效果的创建级别信息。返回 Effect对象，该对象代表创建级别信息。
expression.ConvertToBuildLevel(Effect, Level)
expression  必选。该表达式返回一个Sequence对象。
Effect  必选。Effect对象。指定的动画效果。
Level  必选。MsoAnimateByLevel 类型。动画的创建级别。
MsoAnimateByLevel 可以是下列 MsoAnimateByLevel 类型常数之一。
msoAnimateChartAllAtOnce
msoAnimateChartByCategory
msoAnimateChartByCategoryElements
msoAnimateChartBySeries
msoAnimateChartBySeriesElements
msoAnimateDiagramAllAtOnce
msoAnimateDiagramBreadthByLevel
msoAnimateDiagramBreadthByNode
msoAnimateDiagramClockwise
msoAnimateDiagramClockwiseIn
msoAnimateDiagramClockwiseOut
msoAnimateDiagramCounterClockwise
msoAnimateDiagramCounterClockwiseIn
msoAnimateDiagramCounterClockwiseOut
msoAnimateDiagramDepthByBranch
msoAnimateDiagramDepthByNode
msoAnimateDiagramDown
msoAnimateDiagramInByRing
msoAnimateDiagramOutByRing
msoAnimateDiagramUp
msoAnimateLevelMixed
msoAnimateTextByAllLevels
msoAnimateTextByFifthLevel
msoAnimateTextByFirstLevel
msoAnimateTextByFourthLevel
msoAnimateTextBySecondLevel
msoAnimateTextByThirdLevel
msoAnimationLevelNone
说明
更改一个效果的创建级别信息将使任何现有的效果失效。
VBA示例
以下示例更改一个动画效果的创建级别信息，这将使其原效果失效。
Sub ConvertBuildLevel()
Dim sldFirst As Slide
Dim shpFirst As Shape
Dim effFirst As Effect
Dim effConvert As Effect
Set sldFirst = ActiveWindow.Selection.SlideRange(1)
Set shpFirst = sldFirst.Shapes(1)
Set effFirst = sldFirst.TimeLine.MainSequence _
      .AddEffect(Shape:=shpFirst, EffectID:=msoAnimEffectAscend)
Set effConvert = sldFirst.TimeLine.MainSequence _
      .ConvertToBuildLevel(Effect:=effFirst, _
      Level:=msoAnimateTextByFirstLevel)
End Sub
ConvertToShape方法
创建一个具有指定 FreeformBuilder对象的几何特性的形状。返回一个代表新形状的Shape对象。

注意  使用 ConvertToShape方法之前，必须对 FreeformBuilder对象使用过至少一次AddNodes方法。
expression.ConvertToShape
expression  必选。该表达式返回一个 FreeformBuilder对象。
VBA示例
本示例向当前演示文稿的第一张幻灯片中添加一个具有五个顶点的任意多边形。
Set myDocument = ActivePresentation.Slides(1)
With myDocument.Shapes.BuildFreeform(msoEditingCorner, 360, 200)
.AddNodes msoSegmentCurve, _
      msoEditingCorner, 380, 230, 400, 250, 450, 300
.AddNodes msoSegmentCurve, msoEditingAuto, 480, 200
.AddNodes msoSegmentLine, msoEditingAuto, 480, 400
.AddNodes msoSegmentLine, msoEditingAuto, 360, 200
.ConvertToShape
End With

weiyingde · 发表于 2015-12-13 12:18

ConvertToTextUnitEffect方法
返回Effect对象，该对象代表文本动画显示的方式。
expression.ConvertToTextUnitEffect(Effect, unitEffect)
expression  必选。该表达式返回一个Sequence对象。
Effect  必选。Effect对象。要应用于文本单元的动画效果。
unitEffect  必选。MsoAnimTextUnitEffect 类型。文本应如何动画显示。
MsoAnimTextUnitEffect 可以是下列 MsoAnimTextUnitEffect 类型常数之一。
msoAnimTextUnitEffectByCharacter
msoAnimTextUnitEffectByParagraph
msoAnimTextUnitEffectByWord
msoAnimTextUnitEffectMixed
VBA示例
本示例在给定形状中添加一个动画，并按字符动画显示其所包含的文本。
Sub NewTextUnitEffect()
Dim shpFirst As Shape
Dim tmlMain As TimeLine
Set shpFirst = ActivePresentation.Slides(1).Shapes(1)
Set tmlMain = ActivePresentation.Slides(1).TimeLine
tmlMain.MainSequence.ConvertToTextUnitEffect _
      Effect:=tmlMain.MainSequence.AddEffect(Shape:=shpFirst, _
         EffectID:=msoAnimEffectRandomEffects), _
      unitEffect:=msoAnimTextUnitEffectByCharacter
End Sub
Copy方法
将指定对象复制到剪贴板。
expression.Copy
expression  必选。该表达式返回一个 Selection、Shape、ShapeRange、Slide、SlideRange 或 TextRange对象。
说明
使用Paste方法将内容粘贴到剪贴板。
VBA示例
本示例在第一个窗口中拷贝选定幻灯片到剪贴板然后将其粘贴到第二窗口的视图中。如果剪贴板的内容不能粘贴到第二个窗口的视图中（例如，如果试图将一个形状粘贴到幻灯片浏览视图中），则本示例失败。
Windows(1).Selection.Copy
Windows(2).View.Paste
本示例将活动演示文稿中第一张幻灯片的第一个和第二个形状复制到剪贴板，然后将该副本粘贴到第二张灯片。
With ActivePresentation
.Slides(1).Shapes.Range(Array(1, 2)).Copy
.Slides(2).Shapes.Paste
End With
本示例将活动演示文稿的第一张幻灯片复制到剪贴板。
ActivePresentation.Slides(1).Copy
本示例将活动演示文稿中第一张幻灯片的第一个形状复制到剪贴板。
ActivePresentation.Slides(1).Shapes(1).TextFrame.TextRange.Copy

		自动登录	找回密码
密码			免费注册

[分享] ppt学习资料

最新热点 /1