求计算起止时间内每个月所占的天数

whataya筱 · 发表于 2015-9-18 18:22

求大神帮忙直接把函数或公式写在我们的工作表里具体见附件万分感谢

zsx200308 · 发表于 2015-9-18 22:41

C2=MEDIAN(EOMONTH(DATE(2014,COLUMN(A2),1),0),INT($B2),DATE(2014,COLUMN(A2),1)-1)-MEDIAN(INT($A2)-1,DATE(2014,COLUMN(A2),1)-1,EOMONTH(DATE(2014,COLUMN(A2),1),0))
向右向下拖动。

象山海鲜 · 发表于 2015-9-18 23:06

C2

=FREQUENCY(ROW(INDIRECT(INT($A2)&":"&INT($B2))),EOMONTH("2014-1",COLUMN(A1)-{1,2}))

复制代码

右拉下拉

whataya筱 · 发表于 2015-9-20 09:32

zsx200308 发表于 2015-9-18 22:41
C2=MEDIAN(EOMONTH(DATE(2014,COLUMN(A2),1),0),INT($B2),DATE(2014,COLUMN(A2),1)-1)-MEDIAN(INT($A2)-1,D ...

好的非常感谢

whataya筱 · 发表于 2015-9-20 09:34

象山海鲜发表于 2015-9-18 23:06
C2

右拉下拉

问题解决了非常感谢

glcc- · 发表于 2019-1-15 11:48

zsx200308 发表于 2015-9-18 22:41
C2=MEDIAN(EOMONTH(DATE(2014,COLUMN(A2),1),0),INT($B2),DATE(2014,COLUMN(A2),1)-1)-MEDIAN(INT($A2)-1,D ...

赞，，，，，，，，，，，

新手路上 · 发表于 2019-1-15 12:33

象山海鲜发表于 2015-9-18 23:06
C2

右拉下拉

海鲜哥能用frequency函数解决问题的，坚决不用其它函数！

新手路上 · 发表于 2019-1-15 13:16

象山海鲜发表于 2015-9-18 23:06
C2

右拉下拉

大哥，能够解释一下您公式的思路？谢谢O(∩_∩)O！您的精华贴我也看了

丢丢表格 · 发表于 2019-1-15 13:57

zsx200308 发表于 2015-9-18 22:41
C2=MEDIAN(EOMONTH(DATE(2014,COLUMN(A2),1),0),INT($B2),DATE(2014,COLUMN(A2),1)-1)-MEDIAN(INT($A2)-1,D ...

把你的公式简化一下：

=MAX(MIN(INT($B2)+1,DATE(2014,COLUMN(B1),1))-MAX(INT($A2),DATE(2014,COLUMN(A1),1)),)

复制代码

象山海鲜 · 发表于 2019-1-15 14:00

本帖最后由象山海鲜于 2019-1-15 14:03 编辑

新手路上发表于 2019-1-15 13:16
大哥，能够解释一下您公式的思路？谢谢O(∩_∩)O！您的精华贴我也看了

=FREQUENCY(ROW(INDIRECT(INT($A2)&":"&INT($B2))),EOMONTH("2014-1",COLUMN(A1)-{1,2}))
1.ROW(INDIRECT(INT($A2)&":"&INT($B2)))
时间日期就是数值的另一种表现方式，不过有范围而已
把两个日期间的每天用row()数组表现
2.EOMONTH("2014-1",COLUMN(A1)-{1,2})
日期(数值)降序数组
3.FREQUENCY(数组,降序数组）
这里的计频结果实际为3个，
            1. EOMONTH("2014-1",COLUMN(A1)-2) （不包括）到 EOMONTH("2014-1",COLUMN(A1)-1) 的个数
            2. 小于等于EOMONTH("2014-1",COLUMN(A1)-2) 的个数，
            3.大于EOMONTH("2014-1",COLUMN(A1)-1)的个数。
这就是乱序计频！
因为一个单元格只能显示一个结果。所以没啥问题。
http://club.excelhome.net/forum. ... 839&pid=8270648

		自动登录	找回密码
密码			免费注册

[求助] 求计算起止时间内每个月所占的天数

评分

最新热点 /1