IF函数 多个条件

jojgeleven

求助一下，我想在洲区这一列中实现用订单号来判断是哪个洲区的.也就是说
如果订单号是A开头的      就返回 亚太
如果订单号是B开头的      就返回 欧洲
如果订单号是C7开头的    就返回 北美
如果订单号是C5开头的    就返回 南美
如果订单号是D开头的      就返回 西亚非
如果订单号是H开头的    就返回 独联体

我自己写的公式是=IF(B3="A*","亚太",IF(B3="B*","欧洲",IF(B3="C7*","北美",IF(B3="C5*","南美",IF(B3="D*","西亚非",IF(B3="H*","独联体",0))))))
但是好像返回的都不对

请高手们帮我看看是哪里不对？  正确的公式是什么？

不胜感谢！

wswfzwswfz

IF单独不支持通配符

踏雪访梅

1. =LOOKUP(LEFT(B3,2),{"A","亚太";"B","欧洲";"C5","南美";"C7","北美";"D","西亚非";"H","独联体"})

复制代码

或者：

1. =INDEX({"亚太";"欧洲";"南美";"北美";"西亚非";"独联体"},MATCH(B3,{"A";"B";"C5";"C7";"D";"H"}))

复制代码

13732120571

IF函数不能用通配符
支持通配符函数：SUMIF  COUNTIF  MATCH  VLOOKUP  SEARCH等

1. =LOOKUP(1,0/(FIND({"","A","B","C7","C5","D","H"},B3)=1),{0,"亚太","欧洲","北美","南美","西亚非","独联体"})

复制代码

wswfzwswfz

1. =IF(LEFT(B3,2)="C5","南美",IF(LEFT(B3,2)="C7","北美",CHOOSE(FIND(LEFT(B3),"ABDH"),"亚太","欧洲","西亚非","独联体")))

复制代码

先就这样吧

jojgeleven

谢谢各位，真的学习到了东西！   每次来都能得到好心朋友的帮助！    谢谢

踏雪访梅

用VLOOKUP也可以：
=VLOOKUP(LEFT(B3,2),{"A","亚太";"B","欧洲";"C5","南美";"C7","北美";"D","西亚非";"H","独联体"},2)

baimaxiaozi

踏雪访梅 发表于 2015-3-29 10:37
用VLOOKUP也可以：
=VLOOKUP(LEFT(B3,2),{"A","亚太";"B","欧洲";"C5","南美";"C7","北美";"D","西亚非";" ...

请教一下，为什么A1可以匹配亚太？

踏雪访梅

baimaxiaozi 发表于 2015-3-29 11:59
请教一下，为什么A1可以匹配亚太？

这里VLOOKUP省略了第四参数，模糊匹配。

baimaxiaozi

踏雪访梅 发表于 2015-3-29 13:02
这里VLOOKUP省略了第四参数，模糊匹配。

省略应该是精确匹配，函数解释是这样子的，奇怪了都！