求根据频率排列的公式

denghaoran0415

  RT  有1 2 3 4 5  5 个数字  A2:N2是这5个数字出现的基本情况  P2:T2是这5个数字的出现次数   怎么根据 P2:T2的次数 按照升序或者降序 在V2:Z2里面把1 2 3 4 5   5个数字排列？


1111.rar (1.84 KB, 下载次数: 9)

2014-8-15 15:59 上传

点击文件名下载附件
111

13732120571

次数升序，同次数，数字大的在前

1. =SUM(RIGHT(SMALL(MMULT({1,10},P1:T2),{1;2;3;4;5}))*10^{0;1;2;3;4})

复制代码

jacky1998

上传附件，模拟你想要的结果。

denghaoran0415

附件已经上传

袁勇

按次数从大到小，V2单元格：

1. =MOD(LARGE($P2:$T2*100+$P$1:$T$1,COLUMN(A1)),100)

复制代码

ctrl+shift+enter三键结束公式。

denghaoran0415

袁勇 发表于 2014-8-15 16:08
按次数从大到小，V2单元格：ctrl+shift+enter三键结束公式。

能具体的用文字解释一下吗 ？

MicrosoftEH

数组公式：
V2=INDEX($P$1:$T$1,MATCH(SMALL($P2:$T2+{1,2,3,4,5}%%,COLUMN(A1)),$P2:$T2+{1,2,3,4,5}%%,))
右拉复制

MicrosoftEH

V2=MATCH(SMALL($P2:$T2+{1,2,3,4,5}%%,COLUMN(A1)),$P2:$T2+{1,2,3,4,5}%%,)
也行

袁勇

denghaoran0415 发表于 2014-8-15 16:21
能具体的用文字解释一下吗 ？

=MOD(LARGE($P2:$T2*100+$P$1:$T$1,COLUMN(A1)),100)


1、$P2:$T2*100+$P$1:$T$1，即次数*100+数字，形成一数组。

2、LARGE($P2:$T2*100+$P$1:$T$1,COLUMN(A1))，上一步的数组取最大的值，右拉时分别取第二大什、第三大值……。

3、MOD(LARGE($P2:$T2*100+$P$1:$T$1,COLUMN(A1)),100),取最大值除以100的余数（即出现次数最多的那个数字），右拉时分别取第二大值、第三大值……除以100的余数。