ExcelHome技术论坛

 找回密码
 免费注册

QQ登录

只需一步,快速开始

快捷登录

搜索
EH技术汇-专业的职场技能充电站 妙哉!函数段子手趣味讲函数 Excel服务器-会Excel,做管理系统 Excel Home精品图文教程库
HR薪酬管理数字化实战 Excel 2021函数公式学习大典 Excel数据透视表实战秘技 打造核心竞争力的职场宝典
300集Office 2010微视频教程 数据工作者的案头书 免费直播课集锦 ExcelHome出品 - VBA代码宝免费下载
用ChatGPT与VBA一键搞定Excel WPS表格从入门到精通 Excel VBA经典代码实践指南
查看: 14559|回复: 48

[讨论] 最小公倍数&最大公约数[已结]

  [复制链接]

TA的精华主题

TA的得分主题

发表于 2014-6-16 09:12 | 显示全部楼层 |阅读模式
本帖已被收录到知识树中,索引项:TEXT
本帖最后由 delete_007 于 2014-7-1 11:37 编辑

小题.jpg

最小公倍.rar (18.32 KB, 下载次数: 508)

直接跟帖回复公式即可。

请大家仔细阅读题目要求(C2:D11的内存数组),很多回帖都是不满足这个要求的。

评分(公式长度含等号):
小于60字符,50财富。
小于50字符,1技术分。

2014年6月30日 12:00开贴评分。
评分如下:
公倍数和公约数.jpg




点评

知识树索引内容位于41楼附件  发表于 2014-10-22 10:57
附件无法正常解析扩展名  发表于 2014-6-16 09:21

评分

3

查看全部评分

TA的精华主题

TA的得分主题

发表于 2014-6-16 09:54 | 显示全部楼层
最小公倍数C2,数组公式
=MIN(IF(MOD(A2*ROW(INDIRECT("1:"&B2)),B2)=0,ROW(INDIRECT("1:"&B2))))*A2
最大公约数D2
=A2*B2/C2

点评

请仔细阅读题目要求,需要C2:D11的内存数组公式。  发表于 2014-6-16 11:35

评分

1

查看全部评分

TA的精华主题

TA的得分主题

发表于 2014-6-16 09:55 | 显示全部楼层
[广告] Excel易用宝 - 提升Excel的操作效率 · Excel / WPS表格插件       ★免费下载 ★       ★ 使用帮助
本帖最后由 人事难料 于 2014-6-16 09:57 编辑

傻办法做的,等会有空了再优化。
选中C2:D11,输入公式
  1. =IF(MOD(COLUMN(),2),LCM(INDIRECT("A"&ROW()&":B"&ROW())),GCD(INDIRECT("A"&ROW()&":B"&ROW())))
复制代码
CTRL+回车完成,不是三键数组哦,请测试。

点评

请仔细阅读题目要求,需要C2:D11的内存数组公式。  发表于 2014-6-16 11:36

评分

1

查看全部评分

TA的精华主题

TA的得分主题

发表于 2014-6-16 11:53 | 显示全部楼层
[广告] Excel易用宝 - 提升Excel的操作效率 · Excel / WPS表格插件       ★免费下载 ★       ★ 使用帮助
C2=LCM(A2:B2) D2=GCD(A2:B2)下拉

评分

1

查看全部评分

TA的精华主题

TA的得分主题

发表于 2014-6-16 12:51 | 显示全部楼层
本帖最后由 橙桔仔 于 2014-6-16 20:18 编辑

C2=A2*MATCH(,MOD($A2*ROW(INDIRECT("1:"&$B2)),$B2),)^(7-COLUMN()*2)

右拉,下拉
已经知道上面写得不是内存数组了,可是实在想不出来正确的。。。重在参与啦~~只能等开贴了~~

评分

1

查看全部评分

TA的精华主题

TA的得分主题

发表于 2014-6-16 13:26 | 显示全部楼层
[广告] Excel易用宝 - 提升Excel的操作效率 · Excel / WPS表格插件       ★免费下载 ★       ★ 使用帮助
本帖最后由 tianyunjie 于 2014-6-16 13:36 编辑
  1. =MAX((MOD(A2,ROW($1:$999))=0)*(MOD(B2,ROW($1:$999))=0)*ROW($1:$999))
复制代码
最大公约数
  1. =A2*B2/D2
复制代码
最小公倍数

最小公倍数&最大公约数.rar

22.11 KB, 下载次数: 38

评分

1

查看全部评分

TA的精华主题

TA的得分主题

发表于 2014-6-16 13:34 | 显示全部楼层
[广告] Excel易用宝 - 提升Excel的操作效率 · Excel / WPS表格插件       ★免费下载 ★       ★ 使用帮助
先来一个最大公约数
  1. =MAX(IF(MMULT(MOD(A2:B2,ROW($1:$999)),{1;1})=0,ROW($1:$999),))
复制代码

评分

1

查看全部评分

TA的精华主题

TA的得分主题

发表于 2014-6-16 13:43 | 显示全部楼层
本帖最后由 周小事儿 于 2014-6-16 13:54 编辑
  1. =B2:B11*MID(TEXT(A2:A11/B2:B11,"000/000"),{1,5},3)^{1,-1}
复制代码

点评

正确答案。小事儿很强大。  发表于 2014-6-16 16:25

评分

1

查看全部评分

TA的精华主题

TA的得分主题

发表于 2014-6-16 14:37 | 显示全部楼层
[广告] VBA代码宝 - VBA编程加强工具 · VBA代码随查随用  · 内置多项VBA编程加强工具       ★ 免费下载 ★      ★使用手册
先试一下,内存数组,78字符
  1. =IF({1,0},A2:A11*B2:B11,1)*TEXT(GCD(OFFSET(A1:B1,ROW(1:10),)),{"\0 1\/0","0"})
复制代码
2010版测试通过,实在测试不了GCD在2003的效果了~

评分

1

查看全部评分

TA的精华主题

TA的得分主题

发表于 2014-6-16 15:23 | 显示全部楼层
[广告] VBA代码宝 - VBA编程加强工具 · VBA代码随查随用  · 内置多项VBA编程加强工具       ★ 免费下载 ★      ★使用手册
支持7班~57字符
  1. =(A2:A11*B2:B11)^{1,0}*GCD(OFFSET(A1,ROW()-1,,,2))^{-1,1}
复制代码

点评

你最好找一个03版本测试一下,GCD好像不支持数组。我现在也不能确定,验证之后才能明确。  发表于 2014-6-16 16:24

评分

1

查看全部评分

您需要登录后才可以回帖 登录 | 免费注册

本版积分规则

手机版|关于我们|联系我们|ExcelHome

GMT+8, 2024-3-29 19:07 , Processed in 0.086699 second(s), 23 queries , Gzip On, Redis On.

Powered by Discuz! X3.4

© 1999-2023 Wooffice Inc.

沪公网安备 31011702000001号 沪ICP备11019229号-2

本论坛言论纯属发表者个人意见,任何违反国家相关法律的言论,本站将协助国家相关部门追究发言者责任!     本站特聘法律顾问:李志群律师

快速回复 返回顶部 返回列表