【更新完毕】用VBA代码写嵌套域的方法简化

loquat

守柔wordvba编程代码集里面有一个写嵌套域的例子，很有用。

但是写嵌套域当然不限定老大讲的这一种方法。例如下例。

1. Sub 嵌套域()
   
2. Application.ScreenUpdating = False
   
3. Dim aRange As Range, aField As Field, bField As Field
   
4. With ActiveDocument
   
5.     Selection.EndKey wdStory
   
6.     Set aField = .Fields.Add(Selection.Range, wdFieldEmpty)  '生成内侧域
   
7.     aField.Select
   
8.     Application.Run "InsertFieldChars"      '生成外侧域
   
9.     Set bField = .Fields(aField.Index - 1)  '获取外侧域
   
10.     aField.Code.Text = "NumPages"           '设置内侧域代码
    
11.     Set aRange = bField.Code                '获取外侧域代码Range对象
    
12.     .Range(aRange.Start, aRange.Start).Text = "="   '在外侧域左侧加上文字
    
13.     .Range(aRange.End, aRange.End).Text = "-1"    '在外侧域右侧加上文字
    
14. End With
    
15. Application.ScreenUpdating = True
    
16. End Sub

复制代码

loquat

当然可能还有其他简单方法，欢迎交流。

loquat

简化一下：

1. Sub 嵌套域1()
   
2. Dim aField As Field, bField As Field
   
3. Dim aRange As Range
   
4. Set aField = Selection.Fields.Add(Range:=Selection.Range, Type:=wdFieldEmpty, PreserveFormatting:=False)
   
5. Set bField = Selection.Fields.Add(Range:=Selection.Range, Type:=wdFieldEmpty, PreserveFormatting:=False)
   
6. With ActiveDocument
   
7.     bField.Code.Text = "NumPages"
   
8.     Set aRange = aField.Code
   
9.     .Range(aRange.Start, aRange.Start).Text = "="
   
10.     .Range(aRange.End, aRange.End).Text = "-1"
    
11. End With
    
12. End Sub

复制代码

loquat

已经简化，且去掉Select方法
下一步去掉Selection对象

loquat

再次简化，去掉Selection对象，方便移植。

1. Sub 嵌套域2()
   
2. Dim aField As Field, bField As Field
   
3. Dim aRange As Range
   
4. With ActiveDocument
   
5.     Set aRange = .Range(.Content.End - 1, .Content.End - 1)
   
6.     Set aField = aRange.Fields.Add(aRange, wdFieldEmpty, "", False)
   
7.     Set aRange = .Range(aField.Code.Start, aField.Code.End)
   
8.     Set bField = aRange.Fields.Add(aRange, wdFieldEmpty, "NumPages", False)
   
9.     Set aRange = aField.Code
   
10.     .Range(aRange.Start, aRange.Start).Text = "="
    
11.     .Range(aRange.End, aRange.End).Text = "-1"
    
12.     aField.Update
    
13. End With
    
14. End Sub

复制代码

lk19910225

曲高和寡,不明觉厉

loquat

思路没遍，写法再次精简了。
下一步研究在页眉页脚中写嵌套域。。。

1. Sub 嵌套域3()
   
2. Dim aField As Field, bField As Field
   
3. Dim aRange As Range
   
4. With ActiveDocument
   
5.     Set aRange = .Range(.Content.End - 1, .Content.End - 1)   '活动文档末尾
   
6.     Set aField = aRange.Fields.Add(aRange, wdFieldEmpty, "=-1", False)  '创建空白域，并写入域代码
   
7.     Set aRange = .Range(aField.Code.Start + 2, aField.Code.Start + 2)      '取=号后面的位置为新aRange对象
   
8.     Set bField = aRange.Fields.Add(aRange, wdFieldEmpty, "NumPages", False)  '在aRange对象位置插入域
   
9.     aField.Update  '更新域，效果等同于显示域结果
   
10. End With
    
11. End Sub

复制代码

loquat

搞定收工

1. Sub 嵌套域4_写入页眉()
   
2. Dim aRange As Range, aField As Field
   
3. With ActiveDocument.Sections(1).Headers(wdHeaderFooterPrimary)
   
4.     Set aRange = .Range
   
5.     Set aField = aRange.Fields.Add(aRange, wdFieldEmpty, "=-1", False)
   
6.     aRange.SetRange 3, 3  '取aRange对象的第3到第3位作为新的aRange对象
   
7.     Set bField = aRange.Fields.Add(aRange, wdFieldEmpty, "NumPages", False)
   
8.     aField.Update
   
9. End With
   
10. End Sub

复制代码

zhanglei1371

感谢分享嵌套域的VBA，有空研究下

xyz74sc

有空学习一下，感谢楼主的分享