一个看似挺简单的问题，你能通过几种方法来实现

dengjq2000

就是下面一个简单数据表：

姓名	分值	判断
张三	34	34
李四	123	123
李一思		/
小花	102	102
彪哥	0	/
二虎	10	10
胡大	-5	/
王小二	-90	/
二狗	77	77

要求：大于0整数显示数据，小于或等于0时显示“/” 。

我们通常想到是通过IF函数来实现：

1. =IF(B2>0,B2,"/")

复制代码

或：

1. =IF(B2<=0,"/",B2)

复制代码

其实通过TEXT函数或通过：设置单元格格式 - 数字 （自定义）也能很好实现。

下面介绍几种通过TEXT函数来实现的公式与大家分享。同时希望会员跟帖，提供你方法与大家分享。正确将得到一定财富奖励(VBA与SQL语句暂不考虑)。同时要求：公式长度控制在40字符内。

1. =TEXT(B2,"[>0]0;!/")

复制代码

或：

1. =TEXT(B2,"[>];!/")

复制代码

或：

1. =TEXT(B2,"0;!/;!/")

复制代码

或：

1. =TEXT(B2,"[>0]0;\/")

复制代码

或：

1. =TEXT(B2,"[>];\/")

复制代码

或：

1. =TEXT(B2,"0;\/;\/")

复制代码

或：

1. =TEXT(B2,"0;\/")

复制代码

或：

1. =TEXT(B2,"0;!/")

复制代码

该贴已经同步到 dengjq2000的微博

看见星光

感谢斑竹分享。TEXT越用越觉得有趣~~

hyww7453

=CHOOSE((A1>0)+1,"/",A1)

这个可以有么?
跟if差不多......

dengjq2000

hyww7453 发表于 2014-4-23 23:25
=CHOOSE((A1>0)+1,"/",A1)

这个可以有么?

验证有效！当然可以！

1. =CHOOSE((B2>0)+1,"/",B2)

复制代码

看见星光

=SUBSTITUTE(B2*(B2>0),"0","/")

人事难料

1. =IFERROR(B2/(B2>0),"/")

复制代码

07以上版本也能这样写。
先去睡觉了，明天到公司再看看能不能有更多奇思怪想的无聊写法吧，哈哈。

人事难料

看见星光 发表于 2014-4-23 23:40
=SUBSTITUTE(B2*(B2>0),"0","/")

假如是10或者101这种的怎么办

dengjq2000

人事难料 发表于 2014-4-23 23:42
07以上版本也能这样写。
先去睡觉了，明天到公司再看看能不能有更多奇思怪想的无聊写法吧，哈哈。

正确！
把相同类补上去：

1. =IF(ISERR(B2/(B2>0)),"/",B2)

复制代码

1. =IF(ISERROR(B2/(B2>0)),"/",B2)

复制代码

jimcomputer

=IF(B2>0,B2,"/")

=CHOOSE((B2>0)+1,"/",B2)

=SUBSTITUTE(TEXT(B2,"[<=0]!/"),"-",)

=IF(ISNUMBER(B2)*CODE(B2)>48,B2,"/")

呵呵，差不多就这些了

jimcomputer

TEXT也太灵活了吧。