[第101期_2]单词接龙[已总结]

lee1892 · 发表于 2014-1-6 18:13

本帖最后由 delete_007 于 2014-3-10 12:34 编辑

竞赛日期：2014-1-8至2014-2-18

题目内容：

英语老师组织英语课外活动，让同学们用她给出的一些单词玩接龙游戏，接龙的规则是前一个单词的末尾字母要和后一个单词的首字母相同，每一个单词只能用一次，重复的单词要使用其个数次，能够使用全部给定单词连接的称为完成接龙。另，单个字母的首字母同尾字母。老师给每个同学发放了不同的单词表，但有的同学发现无论如何也不能完成接龙。
我们的工作就是帮助老师写一个代码，来判断给定的一组单词是否能完成接龙。

示例：
love excel home 这三个单词可以接龙，home -> excel -> love
hate excel home 这三个单词就不能完成接龙

题目将测试100组单词，每组一万到六万不等，所有单词均以小写字母构成。

答题要求：

Public Function CheckLinkability() As Variable
Dim t#: t = Timer
On Error GoTo END_FUNC
Dim aRes(1 To 3)
Open ThisWorkbook.Path & "\单词接龙_测试数据.csv" For Input Access Read As #1
' ......
END_FUNC:
Close #1
aRes(1) = "" ' <- 你的论坛ID
aRes(2) = Timer - t
If Err Then Err.Clear: aRes(2) = -1: On Error GoTo 0
' aRes(3) 为100个字母 T 或 F 的字符串，T 为能够接龙，F 为不能
CheckLinkability = aRes
End Function

复制代码

所有其它外部的过程、函数、变量、常量、自定义数据类型等等，均必须设置为Private。

答题只接受代码的直接发贴，不接受附件。

测试数据文件由附件代码自动生成。其结构如下：
1、第一行为测试的单词组的数量，自行调试代码时，可将组数设小一点，生成一个短一点的测试数据。
2、其后，每一行对应一个单词组。
3、一行中，有三个数据，第一个为该组单词的单词数量，第二个为该组单词的性质编号，第三个由双引号包含，为该组单词的全部单词并由逗号分割。
4、一组单词的性质编号：0 为完全随机（基本不可能连接）、1 为肯定能够连接、其余数字为可能能够连接，此编号供自行调试代码使用。

测试数据生成器：

评分规则：

1、能够获得正确结果，得 2 分
2、能够在20秒内获得，得 1 分
下述代码作为名义20秒进行对比：

Function Nominal20Sec#()
Dim t#, i&, j&, k#
t = Timer
For i = 1 To 5800
For j = 1 To 10000
Randomize: k = Rnd * Rnd
Next
Next
Nominal20Sec = Timer - t
Debug.Print Nominal20Sec
End Function

复制代码

提示：

我在题目开贴后会另在VBA区专门开贴答疑，敬请关注。

是否参与评论：

可以

参考答案：

另加~

doryan · 发表于 2014-1-16 11:08

放上一个半成品先
该半成品忽略单词与单词间形成了小循环且该循环的所有首尾字符不存在于其他任意单词的首尾部分
这在楼主帖子中是个小概率事件但是我不清楚是否应该考虑
比如 AB BA D 这样的形式 AB BA 形成循环且 "A","B"不存在于其他单词的首尾
但是1W-6W的单词量 26个字母几乎全部涵盖
如果要考虑这种情况这个半成品就是错误答案了

Public Function CheckLinkability() ' As Variable
Dim t#: t = Timer
On Error GoTo END_FUNC
Dim aRes(1 To 3)
Dim nstr As String
Dim n As Integer
Dim s As String
Open ThisWorkbook.Path & "\单词接龙_测试数据.csv" For Input Access Read As #1
Line Input #1, nstr
n = CInt(nstr)
For i = 1 To n
Line Input #1, s
s = Replace(s, Chr(34), "")
arr = Split(s, ",")
Dim brr(): ReDim brr(0 To UBound(arr) - 2)
Dim bt() As Byte
For j = 0 To UBound(brr)
bt = StrConv(arr(j + 2), vbUnicode)
brr(j) = bt
Next
aRes(3) = aRes(3) & enabledo(brr)
Next
END_FUNC:
Close #1
aRes(1) = "doryan" ' <- 你的论坛ID
aRes(2) = Timer - t
If Err Then Err.Clear: aRes(2) = -1: On Error GoTo 0
' aRes(3) 为100个字母 T 或 F 的字符串，T 为能够接龙，F 为不能
Debug.Print aRes(2) & "," & aRes(3)
CheckLinkability = aRes
End Function
Private Function enabledo(arr) As String
Dim huizong(97 To 122)
For i = 0 To UBound(arr)
huizong(arr(i)(0)) = huizong(arr(i)(0)) + 1
pos = arr(i)(UBound(arr(i)) - 3)
huizong(pos) = huizong(pos) - 1
Next
For i = 97 To 122
If huizong(i) <> 0 Then ct = ct + 1
Next
If ct = 2 Then '一个唯一入口一个唯一出口
enabledo = "T"
ElseIf ct = 0 Then '回环形式所有单词绕成一个圈可以从任意单词进入
enabledo = "T"
Else
enabledo = "F"
End If
End Function

复制代码

yangyangzhifeng · 发表于 2014-1-19 18:28

本帖最后由 yangyangzhifeng 于 2014-1-30 09:36 编辑

凑个热闹看看

Public Function CheckLinkability() As Variant Dim t#: t = Timer
On Error GoTo END_FUNC
Dim aRes(1 To 3)
Open ThisWorkbook.Path & "\单词接龙_测试数据.csv" For Input Access Read As #1
Call chk(aRes(3))
END_FUNC:
Close #1
aRes(1) = "yangyangzhifeng" ' <- 你的论坛ID
aRes(2) = Timer - t
If Err Then Err.Clear: aRes(2) = -1: On Error GoTo 0
' aRes(3) 为100个字母 T 或 F 的字符串，T 为能够接龙，F 为不能
CheckLinkability = aRes
End Function
Sub chk(tt)
'算法如下：
'对于首尾字母不相同的单词，以某一字母开始与结尾的单词数量差的总和要不大于2
'若包含首尾字母相同的单词，且包含首尾字母不相同的单词，则此相同字母须在首尾字母不相同的单词中能找到以其开始或结尾的单词
'若全部是首尾字母相同的单词，则开始字母只能是同一个
Dim ar() As Byte, sj, Start_Letters(97 To 122), End_Letters(97 To 122), Same_letter(97 To 122)
Dim n&, jg() As String, i&, j&, Start_End_Differ&, Sum_Differ&, st$, temp
sj = Split(StrConv(InputB(LOF(1), 1), vbUnicode), vbCrLf)
Reset
n = Val(sj(0))
ReDim jg(1 To n)
For i = 1 To UBound(jg)
st = Split(sj(i), Chr(34))(1)
temp = Split(st, ",")
For j = 0 To UBound(temp)
ar = temp(j)
n = UBound(ar)
If ar(0) = ar(n - 1) Then
Same_letter(ar(0)) = 1
Else
Start_Letters(ar(0)) = Start_Letters(ar(0)) + 1
End_Letters(ar(n - 1)) = End_Letters(ar(n - 1)) + 1
End If
Next
If Application.Sum(Start_Letters, End_Letters) = 0 Then
If Application.Sum(Same_letter) = 1 Then jg(i) = "T" Else jg(i) = "F"
Else
For j = 97 To 122
If Start_Letters(j) <> End_Letters(j) Then
Start_End_Differ = Start_End_Differ + 1
If Start_End_Differ > 2 Then Exit For
Sum_Differ = Sum_Differ + Abs(Start_Letters(j) - End_Letters(j))
If Sum_Differ > 2 Then Exit For
End If
If Same_letter(j) > 0 Then
If Start_Letters(j) + End_Letters(j) = 0 Then Exit For
End If
Next
If j = 123 Then jg(i) = "T" Else jg(i) = "F"
End If
Erase Start_Letters: Erase End_Letters: Erase Same_letter
Sum_Differ = 0: Start_End_Differ = 0
Next
tt = Join(jg, "")
End Sub

复制代码

yjh_27 · 发表于 2014-1-20 18:37

本帖最后由 yjh_27 于 2014-1-22 15:05 编辑

Public Function CheckLinkability()
Dim t#: t = Timer
On Error GoTo END_FUNC
Dim aRes(1 To 3)
Open ThisWorkbook.Path & "\单词接龙_测试数据.csv" For Input Access Read As #1
Dim ss(97 To 122, 1 To 3) As Long
Line Input #1, TextLine1
For i = 1 To TextLine1
Line Input #1, TextLine
fl = Split(TextLine, ",")
Erase ss
js1 = 0
js2 = 0
k = UBound(fl)
fl(2) = Mid(fl(2), 2)
fl(k) = Left(fl(k), Len(fl(k)) - 1)
For j = 2 To k
s1 = Asc(Left(fl(j), 1))
s2 = Asc(Right(fl(j), 1))
If s1 = s2 Then
ss(s1, 3) = ss(s1, 3) + 1
Else
ss(s1, 1) = ss(s1, 1) + 1
ss(s2, 2) = ss(s2, 2) + 1
End If
Next
For ii = 97 To 122
If ss(ii, 1) > ss(ii, 2) Then
js1 = js1 + ss(ii, 1) - ss(ii, 2)
ElseIf ss(ii, 1) < ss(ii, 2) Then
js2 = js2 + ss(ii, 2) - ss(ii, 1)
End If
If ss(ii, 3) > 0 Then
If ss(ii, 1) + ss(ii, 2) = 0 Then js1 = 2
End If
If js1 > 1 Or js2 > 1 Then
aRes(3) = aRes(3) & "F"
Exit For
End If
Next
If ii > 122 Then aRes(3) = aRes(3) & "T"
Next
' ......
END_FUNC:
Close #1
aRes(1) = "yjh_27" ' <- 你的论坛ID
aRes(2) = Timer - t
If Err Then Err.Clear: aRes(2) = -1: On Error GoTo 0
' aRes(3) 为100个字母 T 或 F 的字符串，T 为能够接龙，F 为不能
CheckLinkability = aRes
End Function

复制代码

eyeshot · 发表于 2014-1-31 12:40

Public Function CheckLinkability() As Variable
Dim t#: t = Timer
Dim Num_Groups%, StrArr() As String, i%, arr, answer() As String, brr() As String
On Error GoTo END_FUNC
Dim aRes(1 To 3)
Open ThisWorkbook.Path & "\单词接龙_测试数据.csv" For Input Access Read As #1
' ......
Input #1, Num_Groups
ReDim StrArr(1 To Num_Groups, 3)
ReDim answer(1 To Num_Groups)
i = 1
Do While Not EOF(1)
Input #1, StrArr(i, 1)
Input #1, StrArr(i, 2)
Input #1, StrArr(i, 3)
i = i + 1
Loop
For i = 1 To Num_Groups
ReDim brr(StrArr(i, 1) - 1)
arr = Split(StrArr(i, 3), ",")
brr = arr
answer(i) = GetAnswer(brr)
Next
aRes(3) = Join(answer, "")
END_FUNC:
Close #1
aRes(1) = "eyeshot" ' <- 你的论坛ID
aRes(2) = Timer - t
If Err Then Err.Clear: aRes(2) = -1: On Error GoTo 0
' aRes(3) 为100个字母 T 或 F 的字符串，T 为能够接龙，F 为不能
CheckLinkability = aRes
End Function
Private Function GetAnswer(MyArr() As String) As String
Dim x As Long, MyBrr() As String, d1, d2, Flag%
x = UBound(MyArr)
ReDim MyBrr(1 To x + 1, 2)
'初始化
Set d1 = CreateObject("scripting.dictionary")
Set d2 = CreateObject("scripting.dictionary")
Flag = 0
For i = 1 To 26
d1(Chr(96 + i)) = 0
d1(Chr(96 + i)) = 0
Next
For i = 1 To x + 1
If Len(MyArr(i - 1)) = 1 Then
MyBrr(i, 1) = MyArr(i - 1): MyBrr(i, 2) = MyArr(i - 1)
Else
MyBrr(i, 1) = Left(MyArr(i - 1), 1): MyBrr(i, 2) = Right(MyArr(i - 1), 1)
End If
'统计各字母重复次数
d1(MyBrr(i, 1)) = d1(MyBrr(i, 1)) + 1
d2(MyBrr(i, 2)) = d2(MyBrr(i, 2)) + 1
Next
'判断首尾字母个数能否满足接龙,单个字母 |首-尾|>1则直接不能完成接龙,|首-尾|=1超过2个亦不能完成接龙
For i = 1 To 26
Select Case Abs(d1(Chr(96 + i)) - d2(Chr(96 + i)))
Case Is > 1
Flag = 10: Exit For
Case 1
Flag = Flag + 1
If Flag > 2 Then Exit For
End Select
Next
If Flag > 2 Then
GetAnswer = "F"
Else
GetAnswer = "T"
End If
d1.RemoveAll: d2.RemoveAll: Set d1 = Nothing: Set d2 = Nothing
End Function

复制代码

oyzhjr · 发表于 2014-2-14 18:15

楼主的题目没看懂意思，不过就算看懂，这两天也没时间来做了，双节嘛。
说下我的思路。
定义一个长度为26的数组PP（），对应A－Z
读入一个单词，若单词长度为1，跳过，否则读左边第一个字母的ASCII值，换算成1-26，假定第一个字母为N，则数组PP（14）＝PP（14）+1；读最右边一个字母的ASCII值，换算成1-26，假定最右边一个字母为B，则PP（2）＝PP（2）－1
读入完所有单词数据后，检测数组PP，若数组中每个项的值均为0，则读入的单词有多种排列方法。
若读入完所有单词数据后，只有两个项满足一个值为1，一个值为－1，其它的值为0时，假定PP（14）＝1，PP（2）＝－1，若它项为0，则所有单词数据有且仅有一种排列方式，并且接龙的第一个单词必定为N开头，接龙最后一个单词必定以B结尾。
若数组PP（）中不满足上述条件，则所有单词无法构成接龙。
若要构成接龙，需根据数据PP中项的正负值，剔除不符合要求的单词。假定P(1)＝2，P（17）＝－2，共它均为0，则可以查找以a开头，以t结尾，如at,after,accpet 等的单词后再可以接龙。接龙的首单词也必定以a开头，最后一个单词也必定以t结尾。

单词接龙的方法，与经典问题七孔桥差不多。

jsxjd · 发表于 2014-2-14 20:05

本帖最后由 jsxjd 于 2014-2-16 14:06 编辑

有向连通图欧拉路径问题：用Split稳定在 6.5 Secs 左右，用StrConv稳定在 4.5 Secs左右

Public Function CheckLinkability() As Variant
Dim t#: t = Timer
On Error GoTo END_FUNC
Dim aRes(1 To 3)
Open ThisWorkbook.Path & "\单词接龙_测试数据.csv" For Input Access Read As #1
' ......
Dim I&, n&, T1&, T2&, s$
Input #1, n
For I = 1 To n
Input #1, T1, T2, s
aRes(3) = aRes(3) & WordSolitaire(s)
Next
' ......
END_FUNC:
Close #1
aRes(1) = "jsxjd" ' <- 你的论坛ID
aRes(2) = Timer - t
If Err Then Err.Clear: aRes(2) = -1: On Error GoTo 0
' aRes(3) 为100个字母 T 或 F 的字符串，T 为能够接龙，F 为不能
CheckLinkability = aRes
End Function
Private Function WordSolitaire$(WordStr$)
Dim s, I&, J&, FinalVertex&, StartVertex&, nIn&, nOut&, nVertex&
Dim newVertex As Boolean, k, Dict
Dim Edges&(97 To 122, 97 To 122), Vertex&(97 To 122)
For Each s In Split(WordStr, ",")
I = Asc(s)
J = Asc(Right(s, 1))
Vertex(I) = 1: Vertex(J) = 1
Edges(I, J) = Edges(I, J) + 1
Next
WordSolitaire = "F"
For I = 97 To 122
nIn = 0: nOut = 0
For J = 97 To 122
nIn = nIn + Edges(J, I)
nOut = nOut + Edges(I, J)
Next
Select Case nOut - nIn
Case -1
If FinalVertex > 0 Then Exit Function
FinalVertex = I
Case 1
If StartVertex > 0 Then Exit Function
StartVertex = I
Case 0
Case Else
Exit Function
End Select
Next
For I = 97 To 122
If Vertex(I) > 0 Then
nVertex = nVertex + 1
If StartVertex = 0 Then StartVertex = I
End If
Next
Set Dict = CreateObject("Scripting.Dictionary")
Dict(StartVertex) = 0
Do
newVertex = False
For Each k In Dict.keys
J = CLng(k)
If Dict(J) = 0 Then
For I = 97 To 122
If J <> I Then
If Edges(J, I) > 0 Then
If Not Dict.Exists(I) Then Dict(I) = 0: newVertex = True
End If
End If
Next
Dict(J) = 1
End If
Next
Loop Until newVertex = False
If Dict.Count = nVertex Then WordSolitaire = "T"
Set Dict = Nothing
End Function

复制代码

以下不使用split，速度有所提高：稳定在 4.5 Secs 左右

Public Function CheckLinkability() As Variant
Dim t#: t = Timer
On Error GoTo END_FUNC
Dim aRes(1 To 3)
Open ThisWorkbook.Path & "\单词接龙_测试数据.csv" For Input Access Read As #1
' ......
Dim I&, N&, T1&, T2&, s$
Input #1, N
For I = 1 To N
Input #1, T1, T2, s
aRes(3) = aRes(3) & WordSolitaire(s)
Next
' ......
END_FUNC:
Close #1
aRes(1) = "jsxjd" ' <- 你的论坛ID
aRes(2) = Timer - t
If Err Then Err.Clear: aRes(2) = -1: On Error GoTo 0
' aRes(3) 为100个字母 T 或 F 的字符串，T 为能够接龙，F 为不能
CheckLinkability = aRes
End Function
Private Function WordSolitaire$(WordStr$)
Dim N&, I&, J&, FinalVertex&, StartVertex&, nIn&, nOut&, nVertex&
Dim b() As Byte, newVertex As Boolean, k, Dict
Dim Edges&(97 To 122, 97 To 122), Vertex&(97 To 122)
b = StrConv(WordStr, vbFromUnicode)
I = b(LBound(b))
For N = LBound(b) + 1 To UBound(b)
If b(N) = 44 Then
J = b(N - 1)
Vertex(I) = 1: Vertex(J) = 1
Edges(I, J) = Edges(I, J) + 1
I = b(N + 1)
End If
Next
J = b(UBound(b))
Vertex(I) = 1: Vertex(J) = 1
Edges(I, J) = Edges(I, J) + 1
WordSolitaire = "F"
For I = 97 To 122
nIn = 0: nOut = 0
For J = 97 To 122
nIn = nIn + Edges(J, I)
nOut = nOut + Edges(I, J)
Next
Select Case nOut - nIn
Case -1
If FinalVertex > 0 Then Exit Function
FinalVertex = I
Case 1
If StartVertex > 0 Then Exit Function
StartVertex = I
Case 0
Case Else
Exit Function
End Select
Next
For I = 97 To 122
If Vertex(I) > 0 Then
nVertex = nVertex + 1
If StartVertex = 0 Then StartVertex = I
End If
Next
Set Dict = CreateObject("Scripting.Dictionary")
Dict(StartVertex) = 0
Do
newVertex = False
For Each k In Dict.keys
J = CLng(k)
If Dict(J) = 0 Then
For I = 97 To 122
If J <> I And Edges(J, I) > 0 Then
If Not Dict.Exists(I) Then
Dict(I) = 0: newVertex = True
If Dict.Count = nVertex Then Exit Do
End If
End If
Next
Dict(J) = 1
End If
Next
Loop Until newVertex = False
If Dict.Count = nVertex Then WordSolitaire = "T"
Set Dict = Nothing
End Function

复制代码

wcymiss · 发表于 2014-2-16 10:49

本帖最后由 wcymiss 于 2014-2-17 08:29 编辑

Public Function CheckLinkability()
Dim t#: t = Timer
On Error GoTo END_FUNC
Dim aRes(1 To 3)
Open ThisWorkbook.Path & "\单词接龙_测试数据.csv" For Input Access Read As #1
aRes(3) = MyMain(InputB(LOF(1), 1))
END_FUNC:
Close #1
aRes(1) = "wcymiss" ' <- 你的论坛ID
aRes(2) = Timer - t
If Err Then Err.Clear: aRes(2) = -1: On Error GoTo 0
' aRes(3) 为100个字母 T 或 F 的字符串，T 为能够接龙，F 为不能
CheckLinkability = aRes
End Function
Private Function MyMain(ByRef bytCsv() As Byte) As String
Dim i As Long
Dim lngStart As Long, lngEnd As Long
Dim k As Boolean, s As String
k = False
For i = 0 To UBound(bytCsv)
If bytCsv(i) = 34 Then
If k Then
lngEnd = i - 1: k = False
If MyCheck(bytCsv, lngStart, lngEnd) Then s = s & "T" Else s = s & "F"
Else
lngStart = i + 1: k = True
End If
End If
Next
MyMain = s
End Function
Private Function MyCheck(ByRef bytCsv() As Byte, _
ByRef lngStart As Long, ByRef lngEnd As Long) As Boolean
Dim i As Long
Dim aWord(97 To 122, 97 To 122) As Integer
Dim aLetter(97 To 122) As Long
Dim shou As Byte, wei As Byte
shou = bytCsv(lngStart)
For i = lngStart To lngEnd
If bytCsv(i) = 44 Then
wei = bytCsv(i - 1)
aWord(shou, wei) = 1
aLetter(shou) = aLetter(shou) + 1
aLetter(wei) = aLetter(wei) - 1
shou = bytCsv(i + 1)
End If
Next
wei = bytCsv(lngEnd)
aWord(shou, wei) = 1
aLetter(shou) = aLetter(shou) + 1
aLetter(wei) = aLetter(wei) - 1
If Not CheckLetter(aLetter) Then MyCheck = False: Exit Function
If Not CheckWord(aWord, shou, wei) Then MyCheck = False: Exit Function
MyCheck = True
End Function
Private Function CheckLetter(ByRef aLetter) As Boolean
Dim i As Integer
Dim n_1 As Integer, n_2 As Integer
CheckLetter = True
For i = LBound(aLetter) To UBound(aLetter)
If aLetter(i) <> 0 Then
If aLetter(i) = 1 Then
n_1 = n_1 + 1
If n_1 > 1 Then CheckLetter = False: Exit Function
ElseIf aLetter(i) <> -1 Then
CheckLetter = False: Exit Function
End If
End If
Next
End Function
Private Function CheckWord(ByRef aWord, ByRef shou As Byte, ByRef wei As Byte) As Boolean
Dim x As Byte, y As Byte, z As Byte
Dim k As Boolean
Dim aRow() As Boolean, aCol() As Boolean
ReDim aRow(LBound(aWord) To UBound(aWord))
ReDim aCol(LBound(aWord, 2) To UBound(aWord, 2))
aWord(shou, wei) = 2
For z = LBound(aWord) To UBound(aWord)
If aWord(z, shou) = 1 Then aWord(z, shou) = 2
Next
aCol(shou) = True
For z = LBound(aWord, 2) To UBound(aWord, 2)
If aWord(wei, z) = 1 Then aWord(wei, z) = 2
Next
aRow(wei) = True
Do
k = False
For x = LBound(aWord) To UBound(aWord)
For y = LBound(aWord, 2) To UBound(aWord, 2)
If aWord(x, y) = 2 Then
If Not aRow(y) Then
For z = LBound(aWord, 2) To UBound(aWord, 2)
If aWord(y, z) = 1 Then
aWord(y, z) = 2
If Not k Then k = True
End If
Next
aRow(y) = True
End If
If Not aCol(x) Then
For z = LBound(aWord) To UBound(aWord)
If aWord(z, x) = 1 Then
aWord(z, x) = 2
If Not k Then k = True
End If
Next
aCol(x) = True
End If
End If
Next
Next
Loop While k
For x = LBound(aWord) To UBound(aWord)
For y = LBound(aWord, 2) To UBound(aWord, 2)
If aWord(x, y) = 1 Then CheckWord = False: Exit Function
Next
Next
CheckWord = True
End Function

复制代码

delete_007 · 发表于 2014-2-19 09:03

竞赛时间到，请已交卷的同学误再修改答案，以免影响评分，谢谢。
先开贴，待楼主总结评分。

jsxjd · 发表于 2014-2-28 15:29

2至5楼都没有很好地处理“连通性”
2楼、5楼不能处理“a,b”这两个单词
3楼、4楼不能处理“a,ab,cd,dc” 这组单词

8楼通过使用 InputB 函数提升了数据读入效率

		自动登录	找回密码
密码			免费注册

[Excel 程序开发] [第101期_2]单词接龙[已总结]

本帖子中包含更多资源

点评

评分

点评

评分

点评

评分

点评

评分

点评

评分

点评

评分

评分

最新热点 /1