【71期】Piny系列-十二生肖大亂鬥

piny · 发表于 2011-3-20 12:33

原帖由 fangjianp 于 2011-3-20 12:26 发表
“PS：调试几次公式报错，原来是繁体字在做怪。下次希望楼主出贴的时候可以把繁体字给简化下。”
用繁体的原因有：
1、祖国没有统一，大陆国务院不是台湾的，管不了台湾
2、台湾没有简体汉字
3、“烹你”帮主是否认识简体汉字，即使认识，也不一定会输入简体
所以你就包含啦，我们只有这么一个台湾帮主啊，你不克服谁克服？？？

呵感謝諒解我在看EH論壇仍需先轉成繁体閱讀一來是習慣二來是很多簡体字還不認識我所以有時侯反應慢了點

piny · 发表于 2011-3-20 13:04

公式解析

=MID(TEXT(MID("鼠豬狗雞猴羊馬蛇龍兔虎牛鼠",MIN(FIND(A2:C2&TRANSPOSE(A2:C2),"鼠豬狗雞猴羊馬蛇龍兔虎牛鼠a"&A2:C2&TRANSPOSE(A2:C2))),2),"@@@@的下一個生肖是@無相鄰"),8,9)

复制代码

fangjianp老師的解極為接近預設解，再轉個彎就一樣了，考量13X俱樂部成員皆大幅領先技術分2分之字元數門檻，擬予以3分技術分，餘如附件給分，若有疑義請儘速提出。

核心思想一

=MID("甲乙丙丁",4,2)="丁"
=MID("甲乙丙丁",5,2)=""

MID在取數時，若參數1之字元數不足，將預設取回空白

核心思想二

=TEXT("豆花","@@好好吃")="豆花豆花好好吃"
=TEXT("豆花","@@好好吃@")="豆花豆花好好吃豆花"
=TEXT("","@@好好吃@")="好好吃"

TEXT的@參數為重複第一參數全部字串，一個@重複一次，二個@則重複兩次，空白字串不管有多少@仍傳回空白

解析一

FIND(A2:C2&TRANSPOSE(A2:C2),"鼠豬狗雞猴羊馬蛇龍兔虎牛鼠a"&A2:C2&TRANSPOSE(A2:C2))

复制代码

A2至C2之任意兩兩組合，有無符合題意，若符合題意則FIND必傳回1至12，未符合題意則預設傳回15

解析二

MIN(FIND(A2:C2&TRANSPOSE(A2:C2),"鼠豬狗雞猴羊馬蛇龍兔虎牛鼠a"&A2:C2&TRANSPOSE(A2:C2)))

复制代码

解析一將傳回9組數字，取極小值

解析三

MID("鼠豬狗雞猴羊馬蛇龍兔虎牛鼠",MIN(FIND(A2:C2&TRANSPOSE(A2:C2),"鼠豬狗雞猴羊馬蛇龍兔虎牛鼠a"&A2:C2&TRANSPOSE(A2:C2))),2)

复制代码

利用解析二之結果，從"鼠豬狗雞猴羊馬蛇龍兔虎牛鼠"字串取出需要的子字串(此字串係倒取，以與TEXT之@結合
若解析二為1至12，則依序取出為"鼠豬","豬狗","狗雞","雞猴","猴羊","羊馬","馬蛇","蛇龍","龍兔",...,"牛鼠"；若解析二為15，則取出空白字串（參核心思想一）

解析四

TEXT(解析三,"@@@@的下一個生肖是@無相鄰")

复制代码

=TEXT("鼠豬","豬狗","狗雞","雞猴","猴羊","羊馬","馬蛇","蛇龍","龍兔",...,"牛鼠"或空白,"@@@@的下一個生肖是@無相鄰")
="鼠豬鼠豬鼠豬鼠豬的下一個生肖是鼠豬無相鄰",...,或"的下一個生肖是無相鄰"（參核心思想一及二）

解析五

MID(解析四,8,9)

复制代码

即為所求（參核心思想一）

[ 本帖最后由 wangg913 于 2011-3-20 13:27 编辑 ]

wangg913 · 发表于 2011-3-20 14:11

好答案大家学习一下，学完之后，别忘了给老师送几朵鲜花。

哈哈。。。

声明一下，我已经加分了。

Zaezhong · 发表于 2011-3-20 17:08

看了piny老师的讲解后再看自己的答案感觉都想吐了

[ 本帖最后由 Zaezhong 于 2011-3-20 17:09 编辑 ]

lhx120824 · 发表于 2011-3-20 17:20

看到问题时，我虽偶有piny老师的思路，但我的函数功底太浅，想不出如何来表达，尤其是text函数基本上是刚刚接触，缺乏系统的学习，惭愧！太佩服piny老师的灵活变通的能力了。

chenhh803 · 发表于 2011-3-20 17:26

这是偶第一次参加EH的正式竞赛，能拿3分真是一种幸运，感谢piny 老师解析！
还没有资格送鲜花，等有的时候再一起送吧，呵呵。

wshcw · 发表于 2011-3-20 17:48

TEXT的用法又进了一大步.Piny的思路新奇,台湾版主的技术就是超前,学习了.

fangjianp · 发表于 2011-3-20 18:23

怎么送花呢，是不是要用财富分买？在哪儿买？

piny · 发表于 2011-3-20 18:44

原帖由 fangjianp 于 2011-3-20 18:23 发表
怎么送花呢，是不是要用财富分买？在哪儿买？

高級會員就有這個功能了 ^^
http://club.excelhome.net/thread-682160-1-1.html

piny · 发表于 2011-3-20 19:02

明天从26楼继续评分今天的评分点数用完了

		自动登录	找回密码
密码			免费注册

[Excel 函数与公式] 【71期】Piny系列-十二生肖大亂鬥

本帖子中包含更多资源

评分

本帖子中包含更多资源