第一列相同，将第二列字符合并，怎么处理？

albert3210 · 发表于 2011-2-5 15:34

如下，有下面这样的表格
A列  B列
AA    C1
BB    C2
AB    C3
AA    C1
AA    C4
BB    C5

要变成下面这样的样子
A列  B列
AA    C1 C1 C4
BB    C2 C5
AB    C3

上次也问过类似的问题，有人说用sumproduct，可是在vba里用那个总是出问题，请问大神么应该怎样处理，thx!

wudixin96 · 发表于 2011-2-5 15:43

VBA里这类问题用字典是最方便的

zhaogang1960 · 发表于 2011-2-5 15:48

原帖由 albert3210 于 2011-2-5 15:34 发表
如下，有下面这样的表格
A列  B列
AA    C1
BB    C2
AB    C3
AA    C1
AA    C4
BB    C5

要变成下面这样的样子
A列  B列
AA    C1 C1 C4
BB    C2 C5
AB    C3

上次也问过类似的问 ...

Sub Macro1()
Dim d As Object, arr, i&
arr = [a1].CurrentRegion
Set d = CreateObject("scripting.dictionary")
For i = 1 To UBound(arr)
      If Not d.Exists(arr(i, 1)) Then
         m = m + 1
         d(arr(i, 1)) = m
         arr(m, 1) = arr(i, 1)
         arr(m, 2) = arr(i, 2)
      Else
         arr(d(arr(i, 1)), 2) = arr(d(arr(i, 1)), 2) & " " & arr(i, 2)
      End If
Next
[a1].CurrentRegion.ClearContents
[a1].Resize(m, 2) = arr
End Sub

albert3210 · 发表于 2011-2-5 15:54

您真是位热心肠的人，上次的问题也是您帮着解答的，先表示感谢了，再下去实际验证下~~

chinjingo · 发表于 2011-2-5 16:21

弄一公式版.................

yaojil · 发表于 2011-2-5 16:26

Sub HEB()
Dim d As Object, i&, arr
Set d = CreateObject("scripting.dictionary")
arr = [a1].CurrentRegion
For i = 1 To UBound(arr)
      If Not d.Exists(arr(i, 1)) Then
         d(arr(i, 1)) = arr(i, 2)
      Else
         d(arr(i, 1)) = d(arr(i, 1)) & " " & arr(i, 2)
      End If
Next
[c1].Resize(d.Count, 1) = Application.Transpose(d.keys)
[d1].Resize(d.Count, 1) = Application.Transpose(d.items)
End Sub

zhaogang1960 · 发表于 2011-2-5 19:31

原帖由 yaojil 于 2011-2-5 16:26 发表
Sub HEB()
Dim d As Object, i&, arr
Set d = CreateObject("scripting.dictionary")
arr = [a1].CurrentRegion
For i = 1 To UBound(arr)
If Not d.Exists(arr(i, 1)) Then
...

楼上把代码改为典型字典用法，想必没有理解我避开Transpose函数的意图吧，运行下面附件试试看：

Book1.rar (91.14 KB, 下载次数: 306)

yaojil · 发表于 2011-2-6 16:42

谢谢 zhaogang 大侠，受教了，慢慢学习

douzizidou · 发表于 2015-12-28 17:00

求问这种问题中，如果想让B列的内容有重复时只显示一次应该如何在原有代码上处理呢？
如  1  C1
   2 C2
   1 C1
   3 C4
显示成 1  C1
         2  C2
         3 C4
C1只显示一次而非两次。

百步亭 · 发表于 2018-7-24 12:48

新兵学习中

		自动登录	找回密码
密码			免费注册

[求助] 第一列相同，将第二列字符合并，怎么处理？

评分

回复 3楼 zhaogang1960 的帖子

回复 7楼 zhaogang1960 的帖子