怎样的运算能得到数组{11;12;13}与数组{21,31;22,32;23,33}合并成

lhx120824 · 发表于 2011-1-1 19:39

原帖由 wcymiss 于 2011-1-1 17:35 发表
=CHOOSE({1,2,3},{11;12;13},INDEX({21,31;22,32;23,33},0,1),INDEX({21,31;22,32;23,33},0,2))

方法可行，只是能不能不用拆分第二个数组来合并？

doitbest · 发表于 2011-1-1 21:31

好多天没看到这样的好贴了

shaowu459 · 发表于 2011-1-2 00:45

原帖由 lhx120824 于 2011-1-1 19:39 发表

方法可行，只是能不能不用拆分第二个数组来合并？

提供一个解法，不是最简单的，但是按理说能扩展应用来解决问题。不限于单元格引用，可以是常量数组形式或者内存数组。供楼主参考，

lhx120824 · 发表于 2011-1-2 08:25

原帖由 shaowu459 于 2011-1-2 00:45 发表

提供一个解法，不是最简单的，但是按理说能扩展应用来解决问题。不限于单元格引用，可以是常量数组形式或者内存数组。供楼主参考，

谢谢提供了很好的解题思路。值得细细研究研究。
shaowu459提供的附件中
数组扩充截图
数组扩充.gif

[ 本帖最后由 lhx120824 于 2011-1-2 09:21 编辑 ]

lhx120824 · 发表于 2011-1-2 08:46

原帖由 shaowu459 于 2011-1-2 00:45 发表

提供一个解法，不是最简单的，但是按理说能扩展应用来解决问题。不限于单元格引用，可以是常量数组形式或者内存数组。供楼主参考，

先临时总结如下：（继续等待其他的方法）

1、wcymiss 在10楼提供的先分解数组成单列再用CHOOSE({})函数并联的方法：
=CHOOSE({1,2,3},{11;12;13},INDEX({21,31;22,32;23,33},0,1),INDEX({21,31;22,32;23,33},0,2))

2、shaowu459 在13楼提供的分解讲解很细，让人一看就懂：
两个数组都扩展然后数组相加的方法：
=MMULT({11;12;13},{1,0,0})+MMULT({21,31;22,32;23,33},{0,1,0;0,0,1})

3、也可只扩展第二个数组再用if函数并联的方法：
=IF({1,0,0},{11;12;13},MMULT({21,31;22,32;23,33},{0,1,0;0,0,1}))

4、如果第二个数组只有1列，就可以用李兴德在7楼提供的方法：
数组公式：
=IF({1,1,0},A1:B3,C1:C3)

5、如果数组都是有规律的纯数值的话，也可用李兴德在4楼提供的自然数的运算方法直接得出：
=(MOD(ROW()-1,3)+1)*10+ROUNDUP((ROW()-0)/3,)

[ 本帖最后由 lhx120824 于 2011-1-2 09:13 编辑 ]

snowangle211 · 发表于 2011-1-2 10:46

进来学习一下！！！！！

lhx120824 · 发表于 2011-1-2 13:02

由此联想到在数组特辑班学习时胡剑老师留的魔术问题的解答：

两个相同行数的多列数组的并联：
见下图：
要把3列数组ABC与4列数组DEFG合并成7列的数组ABCDEFG，需要把第二个数组扩充成7列的数组，借助于函数MMULT(），需要构建一个辅助数组，见图的右上方，经过矩阵运算
=MMULT(H4:K9,N4:T7)
得到中间的7列的数组，然后借助 if({1,1,1,0,0,0,0},,)
=IF({1,1,1,0,0,0,0},D4:F9,MMULT(H4:K9,N4:T7))
即可实现。

辅助数组（区域N4:T7）可用以下数组公式替代：
=1*(ROW(1:4)+3=COLUMN(1:7))
公式直接变成：
=IF({1,1,1,0,0,0,0},D4:F9,MMULT(H4:K9,1*(ROW(1:4)+3=COLUMN(1:7))))
数组并联图.gif

闲池 · 发表于 2011-1-2 14:07

太经典的帖子了！！！

zzaayy2010 · 发表于 2011-1-2 16:52

=(MOD(ROW()-1,3)+1)*10+ROUNDUP((ROW()-0)/3,)

鬼狐 · 发表于 2011-1-2 21:29

也可以用small，然后对small的第二参数进行构造
不过实用性好像不是很强
不过还是上传了
改了好几次了

=============
改最后一次了~~

[ 本帖最后由鬼狐于 2011-1-3 00:22 编辑 ]

		自动登录	找回密码
密码			免费注册

[讨论] 怎样的运算能得到数组{11;12;13}与数组{21,31;22,32;23,33}合并成