在这里为什么IF函数实现不了

骑牛西出 · 发表于 2010-12-3 10:59

在这里为什么IF函数实现不了，还请帮助

交叉点 · 发表于 2010-12-3 11:02

=IF(COUNTIF(A2,"*裤*"),"下装","上装")

zhaojiaoyang200 · 发表于 2010-12-3 11:02

=IF(COUNTIF(A2,"*裤*"),"下装","上装")

zhaojiaoyang200 · 发表于 2010-12-3 11:07

=IF(ISNUMBER(FIND("裤",A2)),"下装","上装")

laowuwyx · 发表于 2010-12-3 11:15

=TEXT(COUNT(FIND("裤",A2)),"下装;;上装")

piny · 发表于 2010-12-3 11:24

整理一下添加幾個

32 =IF(COUNTIF(A2,"*裤*"),"下装","上装")
34 =IF(COUNT(FIND("裤",A2)),"下装","上装")
35 =IF(ISERR(-FIND("裤",A2)),"上装","下装")
35 =TEXT(COUNT(FIND("裤",A2)),"下装;;上装")
37 =IF(ISNUMBER(FIND("裤",A2)),"下装","上装")
38 =MID("下装上装",3-2*COUNT(FIND("裤",A2)),2)

wshcw · 发表于 2010-12-3 13:47

35 =IF(ISERR(-FIND("裤",A2)),"上装","下装")
这个不用"-"号了吧?

[ 本帖最后由 wshcw 于 2010-12-3 13:48 编辑 ]

laowuwyx · 发表于 2010-12-3 14:09

再增加几种
=CHOOSE(COUNT(FIND("裤",A2))+1,"上装","下装")
=INDEX({"上装","下装"},COUNT(FIND("裤",A2))+1)
=IF(COUNTIF(A2,"*裤*"),"下装","上装")
=TEXT(COUNTIF(A2,"*裤*"),"下装;;上装")
=INDEX({"上装","下装"},COUNTIF(A2,"*裤*")+1)
=IF(ISNUMBER(MATCH("*裤*",A2,)),"下装","上装")
=CHOOSE(ISNUMBER(MATCH("*裤*",A22,))+1,"上","下")&"装"

[ 本帖最后由 laowuwyx 于 2010-12-3 14:12 编辑 ]

laowuwyx · 发表于 2010-12-3 14:44

呵呵，本来以为版主会给一点技术分的，又泡汤了。

piny · 发表于 2010-12-3 14:58

感謝加分鼓勵加入8樓laowuwyx 老師總整理如下再加幾個

32 =IF(COUNTIF(A2,"*裤*"),"下装","上装")
33 =TEXT(COUNTIF(A2,"*裤*"),"下装;;上装")
34 =IF(COUNT(FIND("裤",A2)),"下装","上装")
34 =IF(ISERR(FIND("裤",A2)),"上装","下装")
35 =TEXT(COUNT(FIND("裤",A2)),"下装;;上装")
36 =TEXT(-ISERR(FIND("裤",A2)),";上装;下装")
37 =IF(ISNUMBER(FIND("裤",A2)),"下装","上装")
38 =MID("下装上装",3-2*COUNT(FIND("裤",A2)),2)
39 =INDEX({"上装","下装"},COUNTIF(A2,"*裤*")+1)
39 =IF(FIND("裤",A2&"裤")>LEN(A2),"上装","下装")
39 =TEXT(-ISNUMBER(FIND("裤",A2)),";下装;上装")
40 =CHOOSE(COUNT(FIND("裤",A2))+1,"上装","下装")
41 =INDEX({"上装","下装"},COUNT(FIND("裤",A2))+1)
41 =IF(ISNUMBER(MATCH("*裤*",A2,)),"下装","上装")
46 =LOOKUP(COUNT(FIND("裤",A2)),{0,1},{"上装","下装"})
47 =IF(LEN(SUBSTITUTE(A2,"裤",))<LEN(A2),"下装","上装")
49 =CHOOSE(ISNUMBER(MATCH("*裤*",A2,))+1,"上","下")&"装"

		自动登录	找回密码
密码			免费注册

[求助] 在这里为什么IF函数实现不了

评分

评分