如何在一篇英文中把含有某个单词的句子都列出来？

jiuyuedefeng · 发表于 2010-10-11 03:49

如附件，WORD给出英文原始文本，
问题一：设计一个查询程序，输入查询的单词比如（number），则在文档结果一中会列出该篇英文中所有包含number的句子。
问题二：给出一个txt文档，里面有单词列表，在原始文章中查询txt中每个单词，把含有这个单词的句子分别列出来，都显示在文档结果二中。
恳请各位高手帮助。

求助.rar (18.78 KB, 下载次数: 84)

yyqq16888 · 发表于 2010-10-11 08:20

复制到EXCEL处理

szh9388 · 发表于 2010-10-11 11:20

2楼老师，具体如何操作

errorjoy · 发表于 2010-10-11 11:28

不知道，帮顶

sylun · 发表于 2010-10-11 12:21

可试试如下代码：
问题一：

Sub test1()
Dim findtext As String, n As Integer, info As String
findtext = InputBox("请输入要查的单词", , "Number")
If findtext <> "" Then
With ActiveDocument.Content.Find
.Text = findtext
.MatchAllWordForms = True
Do While .Execute
n = n + 1
With .Parent
.Expand wdSentence
If .Text Like "*" & Chr(13) Then .End = .End - 1
info = info & n & vbTab & .Text & Chr(13)
.Collapse wdCollapseEnd
End With
Loop
End With
With Documents.Add.Content
.Text = info
End With
End If
End Sub

复制代码

问题二：

Sub test2()
Dim fs, f
Dim Dlg As FileDialog, findtext() As String
Dim i As Integer, n As Integer, c As Long, info As String
Set fs = CreateObject("Scripting.FileSystemObject")
Set Dlg = Application.FileDialog(msoFileDialogFilePicker)
With Dlg
.InitialFileName = ActiveDocument.Path
.AllowMultiSelect = False
If .Show <> -1 Then Exit Sub
Set f = fs.OpenTextFile(.SelectedItems(1))
findtext() = Split(f.ReadAll, vbCrLf)
End With
With ActiveDocument.Content.Find
.MatchAllWordForms = True
For i = 0 To UBound(findtext)
info = info & vbCrLf & findtext(i) & vbCrLf
.Text = findtext(i)
Do While .Execute
n = n + 1
c = c + 1
With .Parent
.Expand wdSentence
If .Text Like "*" & Chr(13) Then .End = .End - 1
info = info & n & vbTab & .Text & Chr(13)
.Collapse wdCollapseEnd
End With
Loop
.Parent.WholeStory
n = 0
Next
End With
info = "共搜索到" & c & "条。" & vbCrLf & info
Documents.Add.Content.Text = info
End Sub

复制代码

honggexjq · 发表于 2010-10-11 12:46

楼上高人，实力不济只简单做了第一个

[ 本帖最后由 honggexjq 于 2010-10-11 16:58 编辑 ]

hhb6085 · 发表于 2010-10-11 12:57

回答问题1
查找number
替换内容空，选择样式：标题（1-8）均可，完成替换后，右击替后的标题，选择格式相同文本，复制粘贴到别的地方即可！

hhb6085 · 发表于 2010-10-11 13:18

请问各位，现在论坛不能传动画文件了么？gif格式的

[ 本帖最后由 hhb6085 于 2010-10-12 01:47 编辑 ]

jiuyuedefeng · 发表于 2010-10-11 21:10

谢谢各位老大的帮助，非常感谢！

jiuyuedefeng · 发表于 2010-10-12 16:49

谢谢sylun老大的解答。烦请老大把问题二的代码再修改一下，比如单词表里有number，……，那么在原文中只要第一次找到含有number的例句，把这个例句摘出来后，就直接搜索下一个单词。也就是每个单词一个例句。应该是改一下循环语句，第一次找到就跳出，但是不会修改，烦请老大帮帮忙。

		自动登录	找回密码
密码			免费注册

[求助] 如何在一篇英文中把含有某个单词的句子都列出来？