如何用VBA代码计算文档中单词出现的频次及单词数

tangqingfu · 发表于 2010-8-15 11:21

请教：
如何通过VBA代码把英文文档中所有的单词列出来，出现一次或多次的都只列入一次，并在单词后面用括号标出其出现的频次；在下一段出现如这样的信息：
本文档出现的单词数共计X个。

sqhsqhli · 发表于 2010-8-17 15:31

Sub Macro3()
On Error Resume Next '忽略错误继续执行VBA代码,避免出现错误消息
Selection.WholeStory
Dim myString2 As String, ppp
Dim myArray2() As String
Dim strFind2 As String
Dim myArray3() As String

aaa = Selection.Words.Count
ppp = ""
For fb = 1 To aaa

strFind2 = Selection.Words(fb)
myString2 = ActiveDocument.Content.Text
myArray2 = Split(myString2, strFind2)
mm = UBound(myArray2)

myArray3 = Split(ppp, "一共有" & mm & "个 ")
mmm = UBound(myArray3)
If Not mmm > 0 Then
ppp = ppp & Selection.Words(fb) & "一共有" & mm & "个 "

End If
Next
msgbox "本文档出现的单词数共计" & aaa & "个"
MsgBox ppp
End Sub
我是菜鸟，仅写了这一段，还应该排除标点的，另外我不知道怎么全部列出，msgbox有字数限制吧

[ 本帖最后由 sqhsqhli 于 2010-8-17 16:03 编辑 ]

tangqingfu · 发表于 2010-8-17 18:21

谢谢sqhsqhli 兄！
能否将列出的单词及频次生成在活动文档中？
这里的单词数不是指单词总数，即如果一个单词出现2次或2次以上的，按一个单词计算；以此来计算单词的数量
请各位再帮帮忙!

[ 本帖最后由 tangqingfu 于 2010-8-17 18:35 编辑 ]

tangqingfu · 发表于 2010-8-18 17:08

期待ing,各位帮帮忙!

chinablank · 发表于 2010-8-19 14:39

呵呵，可以参考守柔的正则查找（速度快）！也可以用错误次数来统计！

sylun · 发表于 2010-8-20 17:51

可试试如下代码：
Option Compare Text
Sub test()
Dim a As String, Dic As Object
Dim myReg As Object, Matches As Object, Match As Object
Dim k, i As Long, j As Long, temp As String, c As String

a = ActiveDocument.Content.Text
Set Dic = CreateObject("Scripting.Dictionary")
Dic.CompareMode = vbTextCompare
Set myReg = CreateObject("VBScript.RegExp")
With myReg
      .Pattern = "[A-Za-z]+"  '匹配模式：由纯字母组成的字符串
      .Global = True
      Set Matches = .Execute(a)
      For Each Match In Matches  '统计频次
         With Match
            If Dic.Exists(.Value) Then Dic(.Value) = Dic(.Value) + 1 Else Dic.Add .Value, 1
         End With
      Next
      k = Dic.Keys  '获取各“单词”
      For i = 0 To UBound(k) - 1 '排序
         For j = i + 1 To UBound(k)
            If k(i) > k(j) Then
                  temp = k(i)
                  k(i) = k(j)
                  k(j) = temp
            End If
         Next
      Next
      For i = 0 To UBound(k)  '合并以用于输出
         c = c & k(i) & vbTab & Dic(k(i)) & Chr(13)
      Next
      Documents.Add.Content.Text = "共有如下" & Dic.Count & "个英文单词（含频次）：" & Chr(13) & c
End With
End Sub

sylun · 发表于 2010-8-21 09:49

原帖由 tangqingfu 于 2010-8-20 23:23 发表
谢谢sylun兄！
比如don't , I'm
代码将don't视为两个单词:don和t；I'm视为两个单词I和m，像上面的这两个单词我don't和I'm应视为一个单词处理.
请sylun兄再帮帮忙！

怎么样才算一个英文单词？其判断标准如何？我想这是一个复杂的问题。比如名词复数，加“s"后，两者是不是不同的单词？
前面的代码只针对纯字母字符串，也就是说，其对单词的判断标准很简单：只是字母组合。至于中间带标点的单词不予考虑。
如一定要将don't , I'm之类的组合计算在内（不含'与s的组合），可试将上面的匹配模式代码改为“[A-Za-z]+('[A-RT-Za-rt-z]+|[A-Za-z]?)”。

tangqingfu · 发表于 2010-8-20 23:23

谢谢sylun兄！
比如don't , I'm
代码将don't视为两个单词:don和t；I'm视为两个单词I和m，像上面的这两个单词我don't和I'm应视为一个单词处理.
请sylun兄再帮帮忙！

tangqingfu · 发表于 2010-8-21 10:23

好像有些问题：
比如：
I'm OK. I like English. I’d like English. English is my favorite. That's Ok. That is right. Those are buses. These are bikes
用sylun兄8楼所说的操作，计算结果如下：
共有如下17个英文单词（含频次）：
are 2
bikes 1
buses 1
d 1
English 3
favorite 1
I 3
is 2
like 2
m 1
my 1
OK 2
right 1
s 1
That 2
These 1
Those 1
如何让计算结果变成：
共有如下17个英文单词（含频次）：
are 2
bikes 1
buses 1
I'd 1
English 3
favorite 1
I 1
is 2
like 2
I'm 1
my 1
OK 2
right 1
That 1
That's 1
These 1
Those 1

[ 本帖最后由 tangqingfu 于 2010-8-21 10:25 编辑 ]

tangqingfu · 发表于 2010-8-21 10:08

如sylun兄所言，要界定一个英语单词的判断标准，的确有些难度。除了名词外，动词原形与动词的第三人人称单词或ing形式是否算一个单词？是吧，好像也不是。只能说是仁者见仁，智者见智。
谢谢sylun兄的帮忙，好像sylun兄用到正则表达式，看不太懂，有些难度……

[ 本帖最后由 tangqingfu 于 2010-8-21 10:27 编辑 ]

		自动登录	找回密码
密码			免费注册

[求助] 如何用VBA代码计算文档中单词出现的频次及单词数