lookup应用----从字符串取数

andysky · 发表于 2010-8-11 13:48

原帖由 hopeson2010 于 2010-8-11 12:49 发表
但我觉得用lookup,遇到日期格式，或者，1E253这样之类的就会显示错误了！

如果你对Excel多了解些就不会这么看了

日期，肉眼看是文本，例如“5月12日”。其实它是数值“40310”
Excel将日期以文本形式显示给用户，却以数值参与运算。例如“5月12日”参与运算时它不再是“5月12日”，而是40310
那么lookup从它里面取值当然就是40310了，这是理所当然的。
如果你仅信需要“5”这个字符，那么应该选择MONTH这个函数。
所以不能得到你想要的结果，由你选择函数的正确与否决定，不是lookup计算不正确。

而对于“1E+253”这类问题，也可以很简单的处理好，将+替换成*就OK了
=-LOOKUP(1,-LEFT(SUBSTITUTE(1E+253,"+","*"),ROW($1:16)) )

wangg913 · 发表于 2010-8-11 13:57

偏偏excel。
=-LOOKUP(1,-(LEFT(A1,ROW($1:$15))&1000)+1000)%%

piny · 发表于 2010-8-11 14:38

=LEFT(A2,MATCH(-1,-ISERR(-RIGHT(LEFT(A2,ROW($1:$99)))),)-1)
=LEFT(A2,MATCH(,-ISNUMBER(--RIGHT(LEFT(A2,ROW($1:$99)))),)-1)

亦可避免原數據含E之困擾(數字在左時)

wangg913 · 发表于 2010-8-11 16:04

原帖由 piny 于 2010-8-11 14:38 发表
=LEFT(A2,MATCH(-1,-ISERR(-RIGHT(LEFT(A2,ROW($1:$99)))),)-1)
=LEFT(A2,MATCH(,-ISNUMBER(--RIGHT(LEFT(A2,ROW($1:$99)))),)-1)

亦可避免原數據含E之困擾(數字在左時)

小数不行。
=LEFT(A1,MATCH(,1-ISERR(-(0&RIGHT(LEFT(A1,ROW($1:$15))))),)-1)

icelan2008 · 发表于 2010-8-11 16:06

高手们，收藏了，没完全理解。有点复杂。

piny · 发表于 2010-8-11 16:08

原帖由 wangg913 于 2010-8-11 16:04 发表

小数不行。
=LEFT(A1,MATCH(,1-ISERR(-(0&RIGHT(LEFT(A1,ROW($1:$15))))),)-1)

的確還有小數需考慮這種議題總是漸入佳境 ^^

kiddy0793 · 发表于 2010-8-11 16:54

学习了！
楼主！

laowuwyx · 发表于 2010-8-11 17:16

为保险起见，用这个公式的时候，我一般会把第一参数设为1，因为我遇到过失效的时候。

fyamww · 发表于 2010-8-11 18:03

呵呵。各位高手在“华山论剑”呢！做为看客，也能学到一两招！

lhx120824 · 发表于 2010-8-11 19:22

把楼上的方法总结一下，就是各种情况的的提取数字的方法。很全。谢谢众位大师让我们分享学习。

取左边
=-LOOKUP(,-LEFT(A1,ROW($1:16)))
取右边
=-LOOKUP(,-Right(A1,ROW($1:16)))
=-LOOKUP(1,-LEFT(A1,ROW($1:16)))

LEFT(A1,MATCH(1,FIND(--LEFT(A1,ROW($1:$100)),A1)))
=-LOOKUP(,-MID(A1,MATCH(-1,-ISNUMBER(--MID(A1,ROW($1:$99),1)),),ROW($1:$15)))
=-LOOKUP(,-MID(A1,MATCH(,-ISERR(-MID(A1,ROW($1:$99),1)),),ROW($1:$15)))
=-LOOKUP(,-MID(A1,MIN(FIND(ROW($1:$10)-1,A1&5^19)),ROW($1:$30)))

=LEFT(A2,MATCH(-1,-ISERR(-RIGHT(LEFT(A2,ROW($1:$99)))),)-1)
=LEFT(A2,MATCH(,-ISNUMBER(--RIGHT(LEFT(A2,ROW($1:$99)))),)-1)

=LEFT(A1,MATCH(,1-ISERR(-(0&RIGHT(LEFT(A1,ROW($1:$15))))),)-1)
这么多方法，慢慢消化吧。

[ 本帖最后由 lhx120824 于 2010-8-11 19:23 编辑 ]

		自动登录	找回密码
密码			免费注册

[分享] lookup应用----从字符串取数

回复 11楼 andysky 的帖子

回复 12楼 wangg913 的帖子