求合并单元格后的金额

魂断蓝桥 · 发表于 2010-7-19 16:04

=C2*INDEX(I:I,MATCH(LOOKUP("座",$A$2:A2)&B2,LOOKUP(ROW($G$2:$G$22),IF($G$2:$G$22<>"",ROW($G$2:$G$22)),$G$2:$G$22)&$H$2:$H$22,)+1)
数组公式。

foodorwater · 发表于 2010-7-19 16:05

原帖由 魂断蓝桥 于 2010-7-19 16:04 发表
=C2*INDEX(I:I,MATCH(LOOKUP("座",$A$2:A2)&B2,LOOKUP(ROW($G$2:$G$22),IF($G$2:$G$22"",ROW($G$2:$G$22)),$G$2:$G$22)&$H$2:$H$22,)+1)
数组公式。

請看8樓，座字不夠大呢，最好用char(65535)代替，不然有些地方出錯。

MicrosoftEH · 发表于 2010-7-19 16:18

也可以用数组公式：
D2=INDEX(I:I,MATCH(B2,OFFSET(H$1,MAX((LOOKUP("座",A$2:A2)=G$2:G$22)*ROW($2:$22))-1,,20),)+MAX((LOOKUP("座",A$2:A2)=G$2:G$22)*ROW($2:$22))-1)*C2 下拉

魂断蓝桥 · 发表于 2010-7-19 16:21

佩服楼主仔细，在下马虎了。

用"﨨"

[ 本帖最后由魂断蓝桥于 2010-7-19 16:28 编辑 ]

wangg913 · 发表于 2010-7-19 16:28

=INDEX(I:I,MATCH(LOOKUP("座",A$1:A2)&B2,LOOKUP(ROW($1:$22),ROW($1:$22)+0/LEN(G$1:G$22),G:G)&H:H,))*C2

hopeson2010 · 发表于 2010-7-19 17:25

=INDEX($I$2:$I$22,MATCH(LOOKUP("翕",$A$2:A3)&B3,LOOKUP(ROW($1:$20),IF($G$2:$G$22<>"",ROW($1:$20)),$G$2:$G$22)&$H$2:$H$22,))*C3
数组公式！

bsjjk · 发表于 2010-7-19 18:36

唉，真是高手如云啊，我啥时候才能像你们一样有问必答啊。　佩服佩服

bsjjk · 发表于 2010-7-20 09:18

今天到单位用各位的方法套用后，全都不能正常显示，或者显示出的结果也是错误的，这问题出在哪里啊，用CTRL+SHIFT+ENTER，后也不能正常显示。

laowuwyx · 发表于 2010-7-20 10:18

D2
=VLOOKUP(LOOKUP("座",$A$2:A2)&B2,IF({1,0},LOOKUP(ROW($G$2:$G$22),MATCH($G$2:$G$22,$G$2:$G$22,)+1,$G$2:$G$22)&$H$2:$H$22,$I$2:$I$22),2,)*C2数组公式下拉。如果没有合并单元格，公式不知道要简单多少。

bsjjk · 发表于 2010-7-20 10:57

原帖由 laowuwyx 于 2010-7-20 10:18 发表
D2
=VLOOKUP(LOOKUP("座",$A$2:A2)&B2,IF({1,0},LOOKUP(ROW($G$2:$G$22),MATCH($G$2:$G$22,$G$2:$G$22,)+1,$G$2:$G$22)&$H$2:$H$22,$I$2:$I$22),2,)*C2数组公式下拉。如果没有合并单元格，公式不知道要简单多少。

谢谢你，就是因为这个有难度，所以才编出来向大家请教，我对单元格合并后的函数不太会运用，所以才编了这个向高手求教，虽然结果是对的，过程我还是有些蒙。呵呵，我功力还尚浅。最后谢谢给予解答的朋友。

		自动登录	找回密码
密码			免费注册

[求助] 求合并单元格后的金额

回复 12楼 foodorwater 的帖子