[52期]提取最左边的数字

wshcw · 发表于 2009-9-16 17:33

版主说的既是，
1、出题时我也意识到了，我应该把字符串的例子举多一些，情况更多一些，答题者有空可钻的机会少一些才是。
2、对于“公式向下填充时不能出现错误”也没进一步解释，现在补充有点晚了，是否有纯字符、空单元格等没说明。
3、一题多解时什么算多解？确实很难界定。

chrisfang · 发表于 2009-9-16 17:38

黄版主的回帖我看不到。如果回帖内容是公示的内容，可以放在顶楼。如果是个人性的内容，可以短信给我。

chrisfang · 发表于 2009-9-16 22:37

以上公式当A列为空白单元格或有数可取的时候都能返回正确结果。其中没有考虑“A列以字母或其他符号打头，没有可以取的数字”的情况，如果题目需要考虑这种情况，可再增加一个left(a2)的判断。

==============================================
判断空白单元格这一点讲,版主公式又进一步,没数字打头可用
COUNT(-LEFT(A2,{1,2}))判断,另外,公式七中的"0123456789-."
可以改成-0.123456789,省略双引号.
===wshcw===
==============================================

黄版主COUNT(-LEFT(A2,{1,2}))的方法很不错。
另外原题字符限制比较宽松，所以没有特别去关注节省字符。-0.123456789可以用3^-4-2替代，节省6个字符。
=====================================================================================
版主缩写-0.123456789的方法太妙了.以后就用3^-4-1

===wshcw===
=====================================================================================

[ 本帖最后由 wshcw 于 2009-9-18 13:59 编辑 ]

trustwxq · 发表于 2009-9-18 11:04

公式一       =--LEFT(A2,MATCH(1,(CODE(MID(A2&"q",ROW($1:$20),1))<45)+(CODE(MID(A2&"q",ROW($1:$20),1))>57),0)-1)
公式二       =--LEFT(A2,MATCH(1,MMULT(N(CODE(MID(A2&REPT("a",20-LEN(A2)),ROW($1:$20),1))*{1,-1}<{45,-57}),{1;1}),0)-1)
公式三       =--LEFT(A2,MATCH(0,TEXT(MID(A2,ROW($1:$20),1),"0;0;!1;!0")+MMULT(N(MID(A2&REPT("a",20-LEN(A2)),ROW($1:$20),1)={"-","."}),{1;1}),0)-1)
公式四       =--LEFT(A2,MATCH(0,IF(ISNUMBER(FIND(MID(A2&"q",ROW($1:$20),1),"1234567890.-")),1,0),0)-1)
公式五       =--LEFT(A2,MIN(MAX(ISNUMBER(--LEFT(A2,ROW($1:$6)))*ROW($1:$6)),FIND("%",A2&"%")-1,FIND("e",A2&"e")-1))
公式六       =--MID(A2,1,MAX(ISNUMBER(--LEFT(REPLACE(REPLACE(A2,FIND("%",A2&"%"),1,"a"),FIND("e",A2&"e"),1,"a"),ROW($1:$6)))*ROW($1:$6)))
公式七       =--MID(A2,1,MATCH("0",TEXT(MID(REPLACE(REPLACE(A2&"q",FIND("-",A2&"q-"),1,"1"),FIND(".",A2&"q."),1,"1"),ROW($1:$18),1),"0;0;!1;!0"),0)-1)
公式八       =CHOOSE(ROW()-1,12,-1.2,532901,3,2,2009,3)
第一次参加竞赛，由于昨天刚刚看到，时间仓促，所以准备的不是很充分，因为看着结束的时间快到了嘛！云南大哥说不让使用SUBSTITUTE函数，可没说不许使用REPLACE,只不过这里用REPLACE要比用SUBSTITUTE复杂一些，这里想出了7个公式，希望能有5个公式符合要求，第8个纯属娱乐凑数，写着玩的，呵呵~~

================================================================
你还有时间编辑修改.
                                                                     ===wshcw===

================================================================
云南大哥能告诉我有几个已经符合要求了吗？
================================================================
希望6,7合并简化为一个,就帅了.
                                                                     ===wshcw===

================================================================
解法果然多多且巧妙啊，而且大家这么多答案几乎没有一模一样的，真是高手多多啊，看来我现在正处于并将长期处于初学者了。

[ 本帖最后由 trustwxq 于 2009-9-23 17:54 编辑 ]

zhoukick · 发表于 2009-9-18 14:07

:P

[ 本帖最后由 zhoukick 于 2009-9-18 14:22 编辑 ]

wddn · 发表于 2009-9-20 14:34

适用于附件所列的数据的数组公式：
核心公式：
C2=--LEFT($A2,MATCH(TRUE,ISERR(FIND(MID($A2&"@",ROW($1:$16),1),-1/17)),)-1)
初步排错：
D2=IF(A2="","",--LEFT($A2,MATCH(TRUE,ISERR(FIND(MID($A2&"@",ROW($1:$16),1),-1/17)),)-1))
完善排错：
E2=IF(ISERR(-(LEFT(A2)&0))+(A2=""),"",--LEFT($A2,MATCH(TRUE,ISERR(FIND(MID($A2&"@",ROW($1:$16),1),-1/17)),)-1))
F2=IF(ISERR(FIND(LEFT($A2&"@"),-1/17)),"",--LEFT($A2,MATCH(TRUE,ISERR(FIND(MID($A2&"@",ROW($1:$16),1),-1/17)),)-1))
其他变化：
把1/17分别换成：1/19,1/38.1/51,1/53,1/57,1/69,1/76，1/85,1/87,1/95

[ 本帖最后由 wddn 于 2009-9-20 17:45 编辑 ]

wjzwang · 发表于 2009-9-22 16:35

今天要结帖了,试给一个参予一下
=LEFT(A2,MATCH(MAX(--TEXT(LEFT(A2,ROW($1:$20))&"e1","0.00;0.00;0;!0")),--TEXT(LEFT(A2,ROW($1:$20))&"e1","0.00;0.00;0;!0"),))
=LEFT(A2,MIN(IF(ISERR(-TEXT(LEFT(A2&"a",ROW($1:$20))&"1e1","0.00;0.00;0;")),ROW($1:$20)))-1)
=LEFT(A2,SUM(N(ISNUMBER(-TEXT(LEFT(A2&"a",ROW($1:$20))&"1e1","0.00;0.00;0;")))))
=LEFT(A2,SUM(N(ISNUMBER(-(REPLACE(A2&"a",ROW($2:$21),21,"")&"1e1")))))
下班了,实在想不到新的,呵呵

[ 本帖最后由 wjzwang 于 2009-9-22 17:28 编辑 ]

wjzwang · 发表于 2009-9-23 09:10

超期再给一个
=LOOKUP(10^14,--TEXT(LEFT(A2&"a",ROW($1:$20))&"0e1","0.00;-0.00;0;"&REPT("!9",15)))/100
=LEFT(A2,SUM(N(ISNUMBER(-(LEFT(A2&"a",ROW($1:$20))&"1e1")))))这个和之前的一样,但更短

[ 本帖最后由 wjzwang 于 2009-9-23 09:15 编辑 ]

lzzgzby · 发表于 2009-9-23 20:52

a2='-12.0.01%%%pmo
a3='-1.2.1.2ero-1.2%
a4='020-88888888
试试

veobai · 发表于 2009-9-24 07:54

楼主我的公式可否？？？
怎么没见评论呢~~~
=LEFT(A2,MATCH(2,FIND(--LEFT(A2,ROW($1:$20)),A2)))
利用--运算将left从左到右依次取出的字符串进行筛选，非数字类型的返回错误值，
在利用find函数将含e和%的数值进行排除，剩下来的数值1中，位于数组最右边的
就是所找的数字~~再使用match将它的位置取出，最后left一下就ok了~~

[ 本帖最后由 veobai 于 2009-9-24 07:59 编辑 ]

		自动登录	找回密码
密码			免费注册

[Excel 函数与公式] [52期]提取最左边的数字

回复 20楼 chrisfang 的帖子

本帖子中包含更多资源

评分

回复 1楼 wshcw 的帖子

本帖子中包含更多资源

评分

本帖子中包含更多资源

评分

本帖子中包含更多资源

评分

本帖子中包含更多资源

评分

本帖子中包含更多资源

评分

最新热点 /1