[52期]提取最左边的数字

泓() · 发表于 2009-9-9 21:45

174 字
=IF(OR(ISERR(FIND(LEFT(A2,1),"-1234567890")),LEN(A2)=0),"",--LEFT(A2,MATCH(FALSE,ISNUMBER(--MID(IF(ISERROR(FIND(".",A2)),A2,REPLACE(A2,FIND(".",A2),1,0)),ROW($2:$99),1)),0)))

163 字
=IF(OR(ISERR(FIND(LEFT(A2,1),-5^19)),LEN(A2)=0),"",--LEFT(A2,MATCH(FALSE,ISNUMBER(--MID(IF(ISERR(FIND(".",A2)),A2,REPLACE(A2,FIND(".",A2),1,0)),ROW($2:99),1)),0)))

[ 本帖最后由泓() 于 2009-9-10 19:11 编辑 ]

biaotiger1 · 发表于 2009-9-10 01:58

公式比较多哈，有成品有半成品有缺陷品
干脆上传文件了
文件中几个半成品找到了位置，可怎么就不能left了捏

-----------------------------------------------------------------------------

2009-9-13
修改如下
1、将字符串假设为99定长
2、修正了sum+frequency及max+frequency半成品公式（设为定长后frequency就可以用啦

）
3、增加了6、7、8三个公式

------------------------------------------------------------------------------

2009-9-14
修改如下
1、增加min函数同时增加了9、10两个公式
2、第10行中标记应用的主要函数，方便浏览

[ 本帖最后由 biaotiger1 于 2009-9-14 08:18 编辑 ]

jyhxr · 发表于 2009-9-10 15:04

也来凑个热闹...

[ 本帖最后由 jyhxr 于 2009-9-10 15:44 编辑 ]

yongbin · 发表于 2009-9-11 13:14

看似簡單,做起來還真不容易。

[ 本帖最后由 yongbin 于 2009-9-14 09:11 编辑 ]

东方之珠0 · 发表于 2009-9-11 20:19

[ 本帖最后由东方之珠0 于 2009-9-12 13:34 编辑 ]

zengyidin · 发表于 2009-9-13 07:56

供参考。。。数组公式
58字符=LEFT(A2,MATCH(,-TEXT(MID(A2,ROW($1:$60),2),"#.0;;;!0"),))
71字符=LOOKUP(9^9,--LEFT(LEFT(A2,COUNT(-MID(A2,ROW($1:$50),2))),ROW($1:$50)))
72字符=LEFT(A2,MATCH(1,--ISERR(FIND(MID(A2&"a",ROW($1:$99),1),"-."&56^7)),)-1)
73字符=LEFT(A2,MATCH(,-ISNUMBER(FIND(MID(A2&"a",ROW($1:$99),1),"-."&56^7)),)-1)
78字符=LOOKUP(9^9,--LEFT(LEFT(A2,SUM(1-ISERR(-MID(A2,ROW($1:$50),2)))),COLUMN(A:Z)))
97字符=LEFT(A2,MATCH(TRUE,(CODE(MID(REPLACE(LOWER(A2),FIND("%",A2&"%"),1,)&"a",ROW($1:$90),1))>96),)-1)
94字符=LEFT(A2,MATCH(,(CODE(MID(A2&" ",COLUMN(1:1),1))<58)*(CODE(MID(A2&" ",COLUMN(1:1),1))>44),)-1)
98字符=REPLACE(A2,MATCH(,(CODE(MID(A2&" ",COLUMN(1:1),1))<58)*(CODE(MID(A2&" ",COLUMN(1:1),1))>44),),9,)
100字符=LEFT(A2,MATCH(,-ISERR(FIND(MID(UPPER(A2)&"A",ROW($1:$90),1),"ABCDEFGHIJKLMNOPQRSTUVWXYZ%年月日")),)-1)
2009年9月16日补充：
84字符=LEFT(A2,MATCH(TRUE,MID(REPLACE(A2,FIND("%",A2&"%"),1,)&"a",ROW($1:$90),1)>="A",)-1)
89字符=LEFT(A2,MATCH(TRUE,RIGHT(LEFT(REPLACE(A2,FIND("%",A2&"%"),1,)&"a",ROW($1:$99)))>"9",)-1)
2009年9月17日补充：
94字符=LEFT(A2,MATCH(3,ERROR.TYPE((MID(REPLACE(A2,FIND("%",A2&"%"),1,)&"a",COLUMN(1:1),1)&0)*0),)-1)

[ 本帖最后由 zengyidin 于 2009-9-17 14:59 编辑 ]

nyafullee · 发表于 2009-9-13 17:57

请楼主审阅！！！！

再战!!!!!!!!!!

见以下附件：

kowloon · 发表于 2009-9-13 22:43

=--LEFT(A2,MIN(IF(ISERR(FIND(MID(A2&" ",ROW($2:$20),1),"0123456789.")),ROW($1:$19))))
=--REPLACE(A2,MIN(IF(ISERR(FIND(MID(A2&" ",ROW($2:$20),1),"0123456789.")),ROW($2:$20))),99,"")
=--LEFT(A2,MIN(IF(ISERR(FIND(RIGHT(LEFT(A2&" ",ROW($2:$20))),"0123456789.")),ROW($1:$19))))
=--REPLACE(A2,MIN(IF(ISERR(FIND(RIGHT(LEFT(A2&" ",ROW($2:$20))),"0123456789.")),ROW($2:$20))),99,"")
=LOOKUP(9E+307,--LEFT(LEFT(A2,MIN(SEARCH({"|","e","%","年"},A2&"|e%年"))-1),ROW($1:$99)))

===========================================================================
1与3和2与4在思路上没多少区别吧。要说区别仅仅是把简单化为复杂而已。

===wshcw===

===========================================================================
同意版主所言, 1 和 3 及 2 和 4 太相似, 现再加两道公式, 凑够数:
=--LEFT(A2,MIN(IF(ISNUMBER(FIND(MID(A2&"|",ROW($1:$19),1),"1234567890-."))*ISERR(FIND(MID(A2&"|",ROW($2:$20),1),"1234567890-.")),ROW($1:$19))))
=--LEFT(A2,LEN(A2)+1-LOOKUP(2,1/ISERROR(FIND(LEFT(RIGHT(A2&"|",ROW($1:$20))),"1234567890-.")),ROW($1:$20)))

[ 本帖最后由 kowloon 于 2009-9-20 13:18 编辑 ]

veobai · 发表于 2009-9-14 07:52

=LEFT(A2,MATCH(2,FIND(--LEFT(A2,ROW($1:$20)),A2)))

chrisfang · 发表于 2009-9-16 15:40

今天刚看到题目，给出题者提几个意见：
1，关于规则第4条，“公式向下填充时不能出现错误”，不太清楚这条规则是需要说明公式可以向下复制来A列各数据对应的计算结果呢，还是希望当A列数据为空时能够包含排错的处理。其实可以说得更明确一些：当A列为空单元格时，公式应当能够不返回错误值（用什么返回值替代？）
不知道我的规则理解是不是这个意思。
2，关于规则第4条，通用性。对于这类题目通用性有点难以界定，因为字符串的可能性还是很多的，A2:A8只包含了几种情况，还有其他一些情况没有包含进去，例如字符串中包含“-”、“/”、字符串中数字长度大于15位等等。
对于求单个公式解答来说，要求具有广泛的通用性还可以说的过去，但是题目要求多解，那么通用性范围是否能够再明确一些。是否满足A列的几个举例就算合格了？还是有其他通用性的要求？
3，求多个公式。这个又是一件很难界定的事情。虽然规则里面提到核心函数不同才能算不同的公式，但一个公式里面到底哪个算“核心函数”？这个也不太好判断吧。

题目本身没有问题，就是出题规则应该稍稍再明确、严谨一些。这样对答题者答题和评卷者判分都有好处，对吗。

		自动登录	找回密码
密码			免费注册

[Excel 函数与公式] [52期]提取最左边的数字

评分

本帖子中包含更多资源

评分

本帖子中包含更多资源

评分

本帖子中包含更多资源

评分

本帖子中包含更多资源

评分

本帖子中包含更多资源

评分

本帖子中包含更多资源

评分

本帖子中包含更多资源

评分

评分

最新热点 /1