[开_118][已结}结贴在1楼]大写金额逆转换为数字金额

wshcw · 发表于 2009-7-26 22:54

原帖由 gouweicao78 于 2009-7-26 05:22 发表
根据wshcw兄题目的数据，5、7楼公式是可以的。但都没考虑：叁万元整、肆仟元整、玖百元整、贰拾元整等情况。
=SUM((FIND(MID(SUBSTITUTE(A2,"元",IF(COUNT(FIND({"万";"仟";"百";"拾"}&"元",A2)),"零元","元")),FIN ...

按你的思路,简10字(238字)
=SUM((FIND(MID(SUBSTITUTE(A2,"元",IF(COUNT(FIND({"万";"仟";"佰";"拾"}&"元",A2)),,"元")),FIND(MID("万仟佰拾元角分",ROW($1:$7),1),SUBSTITUTE(A2,"元",IF(COUNT(FIND({"万";"仟";"佰";"拾"}&"元",A2)),,"元"))&"零万零仟零佰零拾零元零角零分")-1,1),"零壹贰叁肆伍陆柒捌玖")-1)*10^(5-ROW($1:$7)))
我的公式257,217字.

gouweicao78 · 发表于 2009-7-26 23:44

我按我的思路简化后175字。

wshcw · 发表于 2009-7-26 23:46

最终简化至195字

x.f.zhao · 发表于 2009-7-27 07:40

原帖由 gouweicao78 于 2009-7-26 04:53 发表
=SUM((FIND(MID(A2,FIND(MID("万仟佰拾元角分",COLUMN(A:G),1),A2&"零万零仟零佰零拾零元零角零分")-1,1),"零壹贰叁肆伍陆柒捌玖")-1)*10^(5-COLUMN(A:G)))

学习一下，不过还是IFERROR更合适
=SUM(TEXT(FIND(MID(0&A2,FIND(MID("万仟佰拾元角分",ROW($1:7),1),A2&"万仟佰拾元角分"),1),"0整分万仟佰拾零壹贰叁肆伍陆柒捌玖")-8,"0;!0")*10^(5-ROW($1:7)))

gouweicao78 · 发表于 2009-7-27 08:36

佩服，赵兄的思路确实奇特。我也将自己简化的175字拿出来献丑吧：
=SUM((FIND(MID(A2&"零元",FIND(MID("万仟佰拾元角分",ROW($1:$7),1),SUBSTITUTE(A2,"元",0,2-COUNT(FIND({"万";"仟";"佰";"拾"}&"元",A2)))&"零万零仟零佰零拾零元零角零分")-1,1),"零壹贰叁肆伍陆柒捌玖")-1)*10^(5-ROW($1:$7)))

wshcw · 发表于 2009-7-27 12:58

原帖由 x.f.zhao 于 2009-7-27 07:40 发表

学习一下，不过还是IFERROR更合适
=SUM(TEXT(FIND(MID(0&A2,FIND(MID("万仟佰拾元角分",ROW($1:7),1),A2&"万仟佰拾元角分"),1),"0整分万仟佰拾零壹贰叁肆伍陆柒捌玖")-8,"0;!0")*10^(5-ROW($1:7)))

这公式超级的牛,学习了.我用Lookup公式自然很长(182字)

wjzwang · 发表于 2009-7-27 15:12

强,实在强,再借我一个脑袋也想不出来,看来脑袋会转弯真的不容易啊:::

冻豆腐 · 发表于 2009-7-27 17:06

=SUM((FIND(MID(A2,FIND({"万";"仟";"佰";"拾";"元";"角";"分"},A2&"零万仟佰拾元角分")-1,1),"零壹贰叁肆伍陆柒捌玖")-1)*10^(5-ROW($1:$7)))
我的公式答案是符合的,请大家找找那里有漏洞

gouweicao78 · 发表于 2009-7-27 17:13

8楼说了，没考虑：叁万元整、肆仟元整、玖百元整、贰拾元整等情况

chrisfang · 发表于 2009-7-27 18:33

14楼的公式真的不错，不过错误值处理的代价确实有点大，到07里面用iferror的话可以省不少字符。

我给另一种思路的公式，各位看看有没有问题：
=SUM((FIND(MID(SUBSTITUTE(A2,"零",),ROW($1:5)*2-1,1),"元整壹贰叁肆伍陆柒捌玖")-2)*10^(FIND(MID(SUBSTITUTE(A2,"零",),ROW($1:5)*2,1),"整00分角元拾佰仟万")-6))

这个结果需要保留两位小数显示，或者在外面再套一个round(..,2)

		自动登录	找回密码
密码			免费注册

[Excel 函数与公式] [开_118][已结}结贴在1楼]大写金额逆转换为数字金额

回复 11楼 wshcw 的帖子

评分

回复 18楼冻豆腐的帖子

[Excel 函数与公式] [开_118][已结}结贴在1楼]大写金额逆转换为数字金额

回复 11楼 wshcw 的帖子

评分

回复 18楼 冻豆腐 的帖子

回复 18楼冻豆腐的帖子