[开_118][已结}结贴在1楼]大写金额逆转换为数字金额

wshcw · 发表于 2009-7-23 21:42

通过大家的参与,拓展了思路,一个好的主题,没有大家参与交流思路是写不出精妙的公式,自然也称不上好贴。现将较优的公式挑选至一楼,方便大家查阅.
一、适用于十万元内大写逆转换为数字的公式
适用于十万元内大写逆转换为数字的公式,只将经典公式结题如下:
x.f.zhao(14楼,通用公式,共121字)
=SUM(TEXT(FIND(MID(0&A3,FIND(MID("万仟佰拾元角分",ROW($1:8),1),A3&"万仟佰拾元角分"),1),"0整分万仟佰拾零壹贰叁肆伍陆柒捌玖")-8,"0;!0")*10^(5-ROW($1:8)))
wshcw(24楼,EXCEL2007版公式共98字)
=SUM(IFERROR(FIND(MID(A3,FIND(MID("分角元拾佰仟万",ROW($1:8),1),A3)-1,1),"壹贰叁肆伍陆柒捌玖"),)*10^(ROW($1:8)-3))

二、liuzj2s网友的公式最通用(37楼,适用于1000亿以内,03版的).
=IF(COUNT(FIND("亿",A2)),SUM(TEXT(FIND(MID(A2,FIND({"亿","拾","佰","仟"},A2&"整拾佰仟")-1,1),"拾佰仟整壹贰叁肆伍陆柒捌玖")-4,"0;!0")*10^{8,9,10,11}*(FIND({"亿","拾","佰","仟"},A2&"拾佰仟")<=FIND("亿",A2))))+IF(COUNT(FIND("万",A2)),SUM(TEXT(FIND(MID(A2,FIND({"万","拾","佰","仟"},A2&"整拾佰仟",IF(FIND("亿",A2&"亿")<LEN(A2),FIND("亿",A2),1))-1,1),"拾佰仟整壹贰叁肆伍陆柒捌玖")-4,"0;!0")*10^{4,5,6,7}*(FIND({"万","拾","佰","仟"},A2&"拾佰仟",IF(FIND("亿",A2&"亿")<LEN(A2),FIND("亿",A2),1))<=FIND("万",A2))))+SUM(TEXT(FIND(MID(MID(A2,MAX((FIND({"万","亿"},A2&{"万","亿"})<LEN(A2))*FIND({"万","亿"},A2&{"万","亿"}),1),99)&"分角元拾佰仟",FIND({"分","角","元","拾","佰","仟"},MID(A2,MAX((FIND({"万","亿"},A2&{"万","亿"})<LEN(A2))*FIND({"万","亿"},A2&{"万","亿"}),1),99)&"分角元拾佰仟")-1,1),"拾佰仟万亿元角分整壹贰叁肆伍陆柒捌玖")-9,"0;!0")*10^{-2,-1,0,1,2,3})

[ 本帖最后由 wshcw 于 2009-8-13 17:31 编辑 ]

wshcw · 发表于 2009-7-23 21:54

有兴趣的还可做一做这几题:

文本时间直接求和,公式长度不超过100字.
[已结贴]分段提取汉字,大家有时间做一做
看看公式长度<40个字符的你能列出几个公式来?

icydefender · 发表于 2009-7-23 22:10

哈哈先支持一下云南兄的技术相当高了

panjian318 · 发表于 2009-7-25 09:04

好像找不到突破口，楼主来点提示好吗？

wjzwang · 发表于 2009-7-25 11:40

=SUM(IF(ISERR(FIND({"万";"仟";"佰";"拾";"元";"角";"分"},A2,1)),0,MATCH(MID(A2,FIND({"万";"仟";"佰";"拾";"元";"角";"分"},A2,1)-1,1),TEXT(ROW($1:$9),"[DBNUM2]"),))*(10^(7-ROW($1:$7))))/100
......

[ 本帖最后由 wjzwang 于 2009-7-25 16:36 编辑 ]

wshcw · 发表于 2009-7-25 23:32

原帖由 wjzwang 于 2009-7-25 11:40 发表
=SUM(IF(ISERR(FIND({"万";"仟";"佰";"拾";"元";"角";"分"},A2,1)),0,MATCH(MID(A2,FIND({"万";"仟";"佰";"拾";"元";"角";"分"},A2,1)-1,1),TEXT(ROW($1:$9),"[DBNUM2]"),))*(10^(7-ROW($1:$7))))/100
......

不错,已大大简化到172字,再简可能就是160字以下了.

gouweicao78 · 发表于 2009-7-26 04:53

=SUM((FIND(MID(A2,FIND(MID("万仟佰拾元角分",COLUMN(A:G),1),A2&"零万零仟零佰零拾零元零角零分")-1,1),"零壹贰叁肆伍陆柒捌玖")-1)*10^(5-COLUMN(A:G)))

gouweicao78 · 发表于 2009-7-26 05:22

根据wshcw兄题目的数据，5、7楼公式是可以的。但都没考虑：叁万元整、肆仟元整、玖百元整、贰拾元整等情况。
=SUM((FIND(MID(SUBSTITUTE(A2,"元",IF(COUNT(FIND({"万";"仟";"百";"拾"}&"元",A2)),"零元","元")),FIND(MID("万仟佰拾元角分",COLUMN(A:G),1),SUBSTITUTE(A2,"元",IF(COUNT(FIND({"万";"仟";"百";"拾"}&"元",A2)),"零元","元"))&"零万零仟零佰零拾零元零角零分")-1,1),"零壹贰叁肆伍陆柒捌玖")-1)*10^(5-COLUMN(A:G)))

红字的部分定义为名称，字符就可以在220以内。

不过，既然定义了名称，不知道怎么算字符？比如整个公式定义为名称x，那算1个？

[ 本帖最后由 gouweicao78 于 2009-7-26 05:37 编辑 ]

wjzwang · 发表于 2009-7-26 09:40

确实没有考虑周全,不过狗尾草版主早上四五点还在上班工作,可真辛苦啊,是不是有三倍加班费?

gouweicao78 · 发表于 2009-7-26 10:31

我是夜里3点起来值班，顺便逛逛论坛，呵呵。

		自动登录	找回密码
密码			免费注册

[Excel 函数与公式] [开_118][已结}结贴在1楼]大写金额逆转换为数字金额

评分