VBA常用技巧代码解析

xpm130 · 发表于 2009-2-16 20:23

基础太差,每天只能读一点点.
可是读后又如风吹水.....
努力吧,学总比不学强.
谢谢袁版.

yuanzhuping · 发表于 2009-2-16 20:49

技巧30 工作表中一次插入多行
在工作表的中插入多行空行，需要使用Insert方法，如下面的代码所示。

#001 Sub InSertRows_1()
#002 Dim i As Integer
#003 For i = 1 To 3
#004 Sheet1.Rows(3).Insert
#005 Next
#006 End Sub

复制代码

代码解析：
I nSertRows_1过程使用Insert方法在如图所示的数据区域的第2行和第3行之间插入三行空行。
数据区域.JPG

   Insert方法应用于Range对象时在工作表或宏表中插入一个单元格或单元格区域，其他单元格作相应移位以腾出空间，语法如下：
expression.Insert(Shift, CopyOrigin)
   参数expression是必需的，该表达式返回一个Range对象。
   参数Shift是可选的，指定单元格的移动方向。可为以下XlInsertShiftDirection常量之一：xlShiftToRight或xlShiftDown。如果省略本参数，Microsoft Excel将依据该区域的形状决定移动方向。
   参数CopyOrigin是可选的，复制的起点。
   还可以使用引用多行的方法，如下面的代码所示。

#001 Sub InSertRows_2()
#002 Sheet2.Range("A3").EntireRow.Resize(3).Insert
#003 End Sub

复制代码

代码解析：
   InSertRows_2过程通过引用多行区域的方法实现一次插入多行。
   第2行代码中的Range(“A3”).EntireRow属性返回Range(“A3”)单元格所在的一整行，然后使用Resize属性调整行数后插入三行空行。
   也可以直接指定相应行再调整行数后插入空行，如下面的示例代码：

#001 Sub InSertRows_3()
#002 Sheet3.Rows(3).Resize(3).Insert
#003 End Sub

复制代码

运行以上过程，工作表中如图所示。
插入三行空行.jpg

[ 本帖最后由 yuanzhuping 于 2009-2-16 22:48 编辑 ]

yuanzhuping · 发表于 2009-2-16 21:42

技巧31 删除工作表中的空行
如果需要删除如图所示的工作表中所有的空行，可以使用下面的代码。

#001 Sub DelBlankRow()
#002 Dim rRow As Long
#003 Dim LRow As Long
#004 Dim i As Long
#005 rRow = Sheet1.UsedRange.Row
#006 LRow = rRow + Sheet1.UsedRange.Rows.Count - 1
#007 For i = LRow To rRow Step -1
#008 If Application.WorksheetFunction.CountA(Rows(i)) = 0 Then
#009 Rows(i).Delete
#010 End If
#011 Next
#012 End Sub

复制代码

代码解析：
   DelBlankRow过程删除工作表中已使用的区域的所有空行。
   第5行代码获得工作表中已使用区域的首行行号，其中使用UsedRange属性返回工作表中已使用的区域。
   第6行代码获得工作表中已使用区域的最后一行行号。
   第7行到第11行代码从最大行数至最小行数循环判断指定行是否为空行，若为空行则删除该行。
   注意此处一定要从最大行数至最小行数开始循环判断，因为如果工作表中存在两行及两行以上的相邻空行，从最小行数开始循环删除的话，当第一行空行被删除后，被删除行下面的一行会往上移位，而此时For...Next循环的计数器已经加1，所以会出现漏删除的现象。
   其中第8、9行代码使用工作表CountA函数判断当前行已使用单元格的数量，如果为零说明此行是空行则使用Delete删除。
   应用于Range对象的Delete方法删除对象，语法如下：
expression.Delete(Shift)
   参数expression是必需的，返回一个Range对象。
   参数Shift是可选的，指定删除单元格时替补单元格的移位方式。可为以下 XlDeleteShiftDirection常量之一：xlShiftToLeft或xlShiftUp。如果省略该参数，则Microsoft Excel将根据区域的图形决定移位方式。
   运行DelBlankRow过程工作表区域如图所示。

[ 本帖最后由 yuanzhuping 于 2009-2-16 23:18 编辑 ]

elfen1985 · 发表于 2009-2-16 22:41

从头开始学VBA

yunk · 发表于 2009-2-16 23:52

ding 太强了

luye_66 · 发表于 2009-2-17 03:22

太感谢了
楼主真棒啊

yuanzhuping · 发表于 2009-2-17 08:29

技巧32 删除工作表的重复行
在实际应用中，可能需要删除如图所示的工作表中A列的重复内容而只保留一行，那么可以借助工作表CountIf函数来完成，如下面的代码所示。

#001 Sub DeleteRow()
#002 Dim R As Integer
#003 Dim i As Integer
#004 With Sheet1
#005 R = .[a65536].End(xlUp).Row
#006 For i = R To 1 Step -1
#007 If WorksheetFunction.CountIf(.Columns(1), .Cells(i, 1)) > 1 Then
#008 .Rows(i).Delete
#009 End If
#010 Next
#011 End With
#012 End Sub

复制代码

代码解析：
   DeleteRow过程删除工作表A列重复单元格所在的整行内容，只保留一行。
   第5行代码取得工作表中A列的最后一个非空单元格的行号，关于Range对象的End属性请参阅技巧3 。
   第6行到第10行代码从最大行数至最小行数循环判断A列单元格内容是否重复并删除重复单元格所在的整行。和技巧32 一样，此处For...Next循环也要从最大行数至最小行数开始循环判断，否则可能会删除不净。其中第7行代码使用工作表CountIf函数判断单元格内容是否重复，如果重复则删除该单元格所在的行。
   运行DeleteRow过程工作表区域如图所示。

yuanzhuping · 发表于 2009-2-17 08:31

技巧33 定位删除特定内容所在的行
如果需要删除如图所示的工作表区域中特定内容所在的行，可以使用定位的方法快速删除，无需使用For...Next循环对单元格逐个进行判断。

示例代码如下：

#001 Sub SpecialDelete()
#002 Dim R As Integer
#003 With Sheet1
#004 R = .Range("a65536").End(xlUp).Row
#005 .Range("a2:a" & R).Replace "Excel", "", 2
#006 .Columns(1).SpecialCells(4).EntireRow.Delete
#007 End With
#008 End Sub

复制代码

代码解析：
   SpecialDelete过程删除工作表A列单元格中显示为“Excel”的行。
   第5行代码使用Replace方法将工作表A列中显示为“Excel”的单元格内容替换成空白。关于Replace方法请参阅技巧6 。
   第6行代码使用SpecialCells方法定位到工作表A列中所有的空单元格，使用Range对象的EntireRow属性返回其所在的整个行一次性删除。关于SpecialCells方法请参阅技巧4 。
   运行SpecialDelete过程工作表区域如图所示。

[ 本帖最后由 yuanzhuping 于 2009-2-17 19:52 编辑 ]

yuanzhuping · 发表于 2009-2-17 08:56

技巧34 判断是否选中整行
通过当前选择的单元格区域的单元格数目与行数或列数相比较，判断用户是否选中了整行或整列，如下面的代码所示。

#001 Private Sub Worksheet_SelectionChange(ByVal Target As Range)
#002 If Target.Rows.Count = 1 Then
#003 If Target.Columns.Count = 256 Then
#004 MsgBox "您选中了整行,当前行号" & Target.Row
#005 End If
#006 End If
#007 End Sub

复制代码

代码解析：
   工作表的SelectionChange事件，判断用户是否选中了工作表中一整行单元格区域。
   第2行代码中的Target.Rows.Count返回目标区域的行数，确定用户当前选择区域的总行数是否为1。
   第3行代码中的Target.Columns.Count返回目标区域的列数，确定用户当前选择区域总列数是否为256。
   第4行代码当用户选中一整行时显示一个消息框，提示用户当前选择的行号，如图所示。

liusongs · 发表于 2009-2-17 09:27

经典，感谢奉献!!!!!!!!!!!!!!!!!!!

		自动登录	找回密码
密码			免费注册

VBA常用技巧代码解析

第2部分Worksheet（工作表）对象

评分

第2部分Worksheet（工作表）对象

第2部分Worksheet（工作表）对象

第2部分Worksheet（工作表）对象

第2部分Worksheet（工作表）对象