合计问题(已经困扰我几个月了)

aerosmizh · 发表于 2009-1-21 16:19

因为不懂，所以来看看

smallpepper · 发表于 2009-1-21 19:03

还是需要打扰你，当我抹黑公式的时候countif（c2:c8,c2:c8)的数据是｛4；4；1；1；4；1；4｝所以是30000，为什么答案会是这个？而只有答案是｛5；5；5；1；5；1｝的时候，答案才是15000。会不会我的系统有错？

zixun258 · 发表于 2009-1-21 20:44

不可以分类汇总吗？搞的那么复杂

lstxyzh · 发表于 2009-1-21 21:38

原帖由 wddn 于 2009-1-19 16:12 发表
如果合约一列有空值，试试数组公式：
=SUM((MATCH(A2:A16&"",A2:A16&"",)=ROW(A2:A16)-1)*B2:B16)

用另一个公式也可以。
｛=SUM(IF($C$2:$C$9<>"",1/COUNTIF($C$2:$C$9,$C$2:$C$9)*$D$2:$D$9))｝

jueduizhengyi · 发表于 2009-1-21 23:43

新手，学习中

冰风萧萧 · 发表于 2009-1-22 09:24

07版的，看不到

fdd · 发表于 2009-1-22 15:04

原帖由 smallpepper 于 2009-1-21 19:03 发表
还是需要打扰你，当我抹黑公式的时候countif（c2:c8,c2:c8)的数据是｛4；4；1；1；4；1；4｝所以是30000，为什么答案会是这个？而只有答案是｛5；5；5；1；5；1｝的时候，答案才是15000。会不会我的系统有错？

我用的数据不一样，但不影响公式的说明：
公式：COUNTIF(C$2:C19,C$2:C19)的结果如下：
{1;1;1;1;1;1;1;1;2;1;1;2;1;2;1;2;1;1}

1/COUNTIF(C$2:C19,C$2:C19)的结果如下：
{1;1;1;1;1;1;1;1;0.5;1;1;0.5;1;0.5;1;0.5;1;1} 把它理解成：如果只有一个值，占的比例为100%，即1；如果有2 个，每个占的比例为：1/2，即0.5，……

D$2:D19/COUNTIF(C$2:C19,C$2:C19) 理解成：每个值按照自己重复次数的比例取值。

=SUMPRODUCT(D$2:D19/COUNTIF(C$2:C19,C$2:C19)) 就是把乘积加起来而已（因为只有一个数组，SUMPRODUCT相当于加）

这样，数值中虽然有重复，但由于各自只取了：1/重复次数的值，因为加起来相当于只取了1个100%。值不会被重复算。

还不懂的话，请问：1/2+1/2=? 1/3+1/3+1/3=? ……

ggsmart · 发表于 2009-1-22 16:31

一群牛人.............让我又学到一个新知识

wddn · 发表于 2009-1-23 17:08

原帖由 nyistjz 于 2009-1-19 18:42 发表
再给朋友提个难题.
在筛选的时候能,我的合约金额能不能也像请款金额一样,隐藏掉的数据不进行合计,只显示出现的金额合计?

请楼主测试：
Sheet1!D23的公式应用了定义的名称，因为超过了嵌套层数，也可不用定义名称，因为C列厂商合约号是纯数字的：
D23=SUM(SUBTOTAL(9,OFFSET(D$1,IF(MATCH(SUBTOTAL(3,OFFSET($C$1,ROW(C$2:C$19)-1,))*$C$2:$C$19,SUBTOTAL(3,OFFSET($C$1,ROW(C$2:C$19)-1,))*$C$2:$C$19,)=ROW(C$2:C$19)-1,ROW(C$2:C$19)-1,20),)))
数组公式。
4楼的思路非常好，模仿一个数组公式，比先前的简洁些：
D23=SUM(IF(SUBTOTAL(3,OFFSET($C$1,ROW(C$2:C$19)-1,)),$D2:$D19/MMULT(--($C$2:$C$19=TRANSPOSE($C$2:$C$19)),ROW(C$2:C$19)^0)))

[ 本帖最后由 wddn 于 2009-1-24 12:08 编辑 ]

ychh_wy · 发表于 2009-1-23 19:18

=IF(SUBTOTAL(2,D1:D19)>11,SUMPRODUCT(1/COUNTIF(C2:C19,C2:C19)*D2:D19),SUBTOTAL(9,D1:D19)/SUBTOTAL(2,D1:D19))

[ 本帖最后由 ychh_wy 于 2009-1-23 19:36 编辑 ]

		自动登录	找回密码
密码			免费注册

[求助] 合计问题(已经困扰我几个月了)

回复 25楼 fdd 的帖子

根据题目作答