[第41期]根据<用量表>及<计划>计算出每日各种材料使用数量[已总结]

ultra · 发表于 2008-10-31 20:49

答案已发送到指定邮箱，发帖占位。168字符

ultra
=MMULT(TRANSPOSE(MMULT((用量表!A2:A18=计划!B1:F1)*用量表!C2:C18,TRANSPOSE(CHOOSE(MATCH(A2:A6,计划!A2:A6,),计划!B2:F2,计划!B3:F3,计划!B4:F4,计划!B5:F5,计划!B6:F6)))),N(用量表!B2:B18=合计!B1:E1))
多单元格数组公式(内存数组)，长度168字符，正确，评2分。公式中Chosse()这部份运用的欠妥。

--xcd

shaowu459 · 发表于 2008-11-3 09:08

答案已发送到指定邮箱，发帖占位。
更新答案为116字符，已发送邮件请查收。

-------------------------------------------------------------------------------

敬请关注：
思路相当的不错，此思路仅此一个，敬请关注...... --xcd

shaowu459
=MMULT(N(OFFSET(计划!A1,MATCH(A2:A6,计划!A2:A6,),TRANSPOSE(MATCH(用量表!A2:A18,计划!B1:F1,)))),用量表!C2:C18*(用量表!B2:B18=B1:E1))
多单元格数组公式(内存数组)，长度116字符，完全正确。思路很好，公式很简，评3分。

--xcd

lbzcc · 发表于 2008-11-3 10:36

答案已发送，请版主查收。126字符

lbzcc
=MMULT(MMULT(N(A2:A6=TRANSPOSE(计划!A2:A6)),计划!B2:F6),MMULT(TRANSPOSE(N(用量表!A2:A18=计划!B1:F1)),(用量表!B2:B18=合计!B1:E1)*用量表!C2:C18))
多单元格数组公式(内存数组)，长度126字符，完全正确，评2分。

--xcd

泓() · 发表于 2008-11-3 11:00

说实话，我还读不懂题目的意思，是否是未表达清楚，还是我自己行业的原因。

jyhxr · 发表于 2008-11-4 08:26

请教XCD版主
在B2:E6输入一个多单元格数组公式(生成内存数组)
如果是在第一行(b2:e2)输入数组公式,接着向下复制的算不算呢?

------------------------------------------------------------------------
不算 --xcd--
答案已发,请xcd版主查收,只是公式很长,仅当练功吧....223字符

jyhxr
=MMULT(N(OFFSET(计划!A1,MATCH(A2:A6,计划!A2:A6,),COLUMN(A:E))),TRANSPOSE(IF(ISNA(MATCH(计划!B1:F1&{"B";"C";"A";"D";"E"},用量表!A2:A18&用量表!B2:B18,)),0,N(OFFSET(用量表!C1,MATCH(计划!B1:F1&{"B";"C";"A";"D";"E"},用量表!A2:A18&用量表!B2:B18,),)))))
223字符，答案正确，虽到达彼岸，但过程充满曲折，评2分。
祝贺你,首获技术分!
--xcd

wouimk · 发表于 2008-11-4 23:36

占个位先。

没收到邮件

根据截图，25楼已补评分
--xcd

晕。。我发送邮件了啊。
有截图，，版主。。能重发吗。。

[ 本帖最后由 wouimk 于 2008-11-21 17:10 编辑 ]

zhanhewang · 发表于 2008-11-9 11:42

多谢版主提醒，更改答案已发。105字符及108个字符。再次感谢！！
这时才知道自己的无知：不知何为内存数组？
不过能做出也许是目前实现版主目的的多单元格数组公式中最短的一个，也值了。
优化为104个字符
=MMULT(INDEX(计划!B2:F6,{1;3;5;4;2},TRANSPOSE(MATCH(用量表!A2:A18,计划!B1:F1,))),(B1:E1=用量表!B2:B18)*用量表!C2:C18)

zhanhewang
=MMULT(INDEX(计划!B2:F6,{1;3;5;4;2},TRANSPOSE(MATCH(用量表!A2:A18,计划!B1:F1,))),IF(B1:E1=用量表!B2:B18,用量表!C2:C18,0))
多单元格数组公式，长度108字符，虽然计算结果正确，但不是内存数组，不符合要求1，故不得分。谢谢您的参与

--xcd

[ 本帖最后由 zhanhewang 于 2008-11-24 11:48 编辑 ]

wenshui2006 · 发表于 2008-11-9 12:20

占位，120字符。

wenshui2006
=SUM((用量表!$A$2:$A$18=计划!$B$1:$F$1)*(用量表!$B$2:$B$18=B$1)*(OFFSET(计划!$A$1,MATCH($A2,计划!$A$2:$A$6,),1,1,5))*用量表!$C$2:$C$18)
是一个右拉、下拉的单元格数组公式，119字符，虽然计算结果正确，但不是内存数组，不符合要求1，故不得分。谢谢您的参与

--xcd

chrisfang · 发表于 2008-11-15 15:42

答案已发送，发贴占位。130字符

chrisfang
=MMULT(MMULT(N(INDIRECT(""计划!R""&(MATCH(A2:A6,计划!A2:A6,)+1)&""C""&COLUMN(B:F),0)),TRANSPOSE(用量表!C2:C18*(用量表!A2:A18=计划!B1:F1))),N(用量表!B2:B18=B1:E1))
=MMULT(MMULT(N(OFFSET(计划!A1,MATCH(A2:A6,计划!A2:A6,),COLUMN(A:E))),TRANSPOSE(用量表!C2:C18*(用量表!A2:A18=计划!B1:F1))),N(用量表!B2:B18=B1:E1))
均属多单元格数组公式(内存数组)，两公式思路相同，长度分别为143、130字符，完全正确，评2分。
--xcd

willin2000 · 发表于 2008-11-17 09:12

答案已发送，跟贴占位.

--------------------------------------------------------------------------------------------------
隆重推荐，敬请关注：
公式长度113字符——是目前最简的、思路相当好的答案，“思路决定公式”... 此思路加我共2个，敬请关注 --xcd

willin2000
=MMULT(SUMIF(计划!B1:F1,TRANSPOSE(用量表!A2:A18),OFFSET(计划!B1,MATCH(A2:A6,计划!A2:A6,),)),(用量表!B2:B18=B1:E1)*用量表!C2:C18)
多单元格数组公式(内存数组)，长度113字符，完全正确。思路很好，公式很简，评3分。

--xcd

		自动登录	找回密码
密码			免费注册

[Excel 函数与公式] [第41期]根据<用量表>及<计划>计算出每日各种材料使用数量[已总结]

评分

评分

评分

评分

本帖子中包含更多资源

评分

评分