[第40期]斜角递增连续的个数评分帖.请补占位帖.

willin2000 · 发表于 2008-10-28 16:12

由于新系统不支持在投票帖中评分,故而请在老帖:http://club.excelhome.net/thread-357742-1-1.html
中跟过帖,并发送过答案给我的网友在本帖中跟贴,以便评分. 回帖中请不要发送答案,也不要重新将但发送给我.(即使发送也以21号前的为准).

[ 本帖最后由 willin2000 于 2008-10-29 11:13 编辑 ]

水平一般 · 发表于 2008-10-28 16:26

占个位，答案已发。

=SUM((A1:A92+1=B2:B93)*(B2:B93+1=C3:C94)*(C3:C94+1=D4:D95)*(D4:D95+1=E5:E96)*(E5:E96+1=F6:F97)*(F6:F97+1=G7:G98)*(G7:G98+1=H8:H99)*(H8:H99+1=I9:I100))

[ 本帖最后由 willin2000 于 2008-11-15 21:36 编辑 ]

syz105729913 · 发表于 2008-10-28 16:28

占位，答案已发

=SUM((MMULT(N(TRANSPOSE(SUMIF(OFFSET(INDIRECT("A"&COLUMN(A:CR)),ROW(1:9)-1,ROW(1:9)-1),"<>@"))=(A1:A96+COLUMN(A:I)-1)),ROW(1:9)^0)=9)*1)

[ 本帖最后由 willin2000 于 2008-11-15 22:07 编辑 ]

xcd · 发表于 2008-10-28 17:05

占位
=SUM(N(MMULT(N(N(OFFSET(A1,COLUMN(A:I)+ROW(1:100)-2,COLUMN(A:I)-1))-A1:A100+1=COLUMN(A:I)),ROW(1:9)^0)=9))

[ 本帖最后由 willin2000 于 2008-11-15 21:41 编辑 ]

shaowu459 · 发表于 2008-10-28 17:11

答案已发，跟帖确认。幸亏装了个rss阅读器，要不然就发现不了这个帖子拉……
回头看了一下，可以到105字符了……
=SUM(N(MMULT(--(N(OFFSET(A1,ROW(1:92)-1+COLUMN(A:I)-1,COLUMN(A:I)-1))=N(OFFSET(A1,ROW(1:92)-1,))+COLUMN(A:I)-1),ROW(1:9)^0)=9))

[ 本帖最后由 willin2000 于 2008-11-15 21:56 编辑 ]

wouimk · 发表于 2008-10-28 17:25

占位，。。
=SUM(IF((B2:B93-A1:A92=1)*(C3:C94-B2:B93=1)*(D4:D95-C3:C94=1)*(E5:E96-D4:D95=1)*(F6:F97-E5:E96=1)*(G7:G98-F6:F97=1)*(H8:H99-G7:G98=1)*(I9:I100-H8:H99=1),1,0))

[ 本帖最后由 willin2000 于 2008-11-15 21:58 编辑 ]

lws · 发表于 2008-10-28 18:45

占位，答案已发送。
=SUM(N(MMULT(N(A1:A100+COLUMN(A:I)-1=N(INDIRECT(TEXT(COLUMN(A:I)*11+ROW(1:100)*10-10,"R0C0"),))),ROW(1:9)^0)=9))
=SUM(N(MMULT(N(A1:A100+COLUMN(A:I)-1=N(OFFSET(OFFSET(A1,COLUMN(A:I)-1,COLUMN(A:I)-1),ROW(1:100)-1,))),ROW(1:9)^0)=9))

[ 本帖最后由 willin2000 于 2008-11-15 22:03 编辑 ]

ychexcel · 发表于 2008-10-28 19:06

占位!
=SUM(N(MMULT(N(COLUMN(A:I)-1+A1:A92=N(OFFSET(A1,COLUMN(A:I)+ROW(1:92)-2,COLUMN(A:I)-1))),ROW(1:9)^0)=9))

[ 本帖最后由 willin2000 于 2008-11-15 22:11 编辑 ]

AD5000 · 发表于 2008-10-28 19:16

站位，我第二次答案是21号中午发的，能算上不？

106字符
=SUM(N(MMULT(N(COLUMN(A:I)+A1:A100-N(OFFSET(A1,ROW(1:100)+COLUMN(A:I)-2,COLUMN(A:I)-1))=1),ROW(1:9)^0)=9))

101字符
=SUM(N(MMULT(A1:A100-1+COLUMN(A:I)-N(OFFSET(A1,ROW(1:100)+COLUMN(A:I)-2,COLUMN(A:I)-1)),ROW(1:9))=0))

106个字符答案正确.

101个字符,答案错误.
比如当斜角是14,24,16,17,18,19,20,21,20,那么公式的第一行结果就会是MMULT({0,-9,0,0,0,0,0,0,2},{1;2;3;4;5;6;7;8;9})=0,这样该斜角就是被认为是连续的. 而实际上不是.

[ 本帖最后由 willin2000 于 2008-11-15 22:46 编辑 ]

wawbt · 发表于 2008-10-28 19:28

最笨办法的那个,占位

没有收到含wawbt会员ID的邮件,请告诉我你用的邮件发送人姓名. -willin2000

[ 本帖最后由 willin2000 于 2008-11-15 22:54 编辑 ]

		自动登录	找回密码
密码			免费注册

[Excel 函数与公式] [第40期]斜角递增连续的个数 评分帖.请补占位帖.

评分

评分

评分

评分

评分

评分

评分

评分

[Excel 函数与公式] [第40期]斜角递增连续的个数评分帖.请补占位帖.