Application.Run 的参数传递示例，测试通过

liucqa

Application.Run 的参数传递示例

工作簿1，在模块1中写代码：
Sub callrun()
    Dim x, y
    x = 2: y = 3
    Application.Run "test1", 4, 3
    Application.Run "'test1 " & x & "," & y & "'"
   
    Application.Run "工作簿2!test2", 1, 2
    Application.Run "工作簿2!test2", x, y
    Application.Run "工作簿2!sheet1.testSheet", 1, 2
    Application.Run "工作簿2!sheet1.testSheet", x, y

    Application.Run "'工作簿2'!test2", 1, 3
    Application.Run "'工作簿2'!test2", x, y
   
    Application.Run "'" & ThisWorkbook.Path & "\" & "工作簿2.xlsm'!test2", 1, 2
    Application.Run "'" & ThisWorkbook.Path & "\" & "工作簿2.xlsm'!sheet1.testSheet", x, y
End Sub

Sub test1(x, y)
    MsgBox x & y
End Sub

工作簿2，在模块1中写代码
Sub test2(x, y)
    MsgBox x & y
End Sub

工作簿2，在Sheet1中写代码
Sub testSheet(x, y)
    MsgBox x & y
End Sub

liucqa

除了工作簿带路径的情况，需要用单引号括起来之外，其他的情况尽量不要用单引号。

上述例子中，第二种方式调用，是把过程参数写到了Run方法的Macro参数里面，适用性受限。

******************************************************************************************************

Application.Run 方法
运行一个宏或者调用一个函数。该方法可用于运行用 Visual Basic 或 Microsoft Excel 宏语言编写的宏，或者运行 DLL 或 XLL 中的函数。

语法
表达式.Run(Macro, Arg1, Arg2, Arg3, Arg4, Arg5, Arg6, Arg7, Arg8, Arg9, Arg10, Arg11, Arg12, Arg13, Arg14, Arg15, Arg16, Arg17, Arg18, Arg19, Arg20, Arg21, Arg22, Arg23, Arg24, Arg25, Arg26, Arg27, Arg28, Arg29, Arg30)
表达式   一个代表 Application 对象的变量。

参数
名称 必选/可选 数据类型 说明
Macro 可选 Variant 要运行的宏。它可以是具有宏名称的字符串、表示函数所在位置的 Range 对象，或者是一个已注册的 DLL (XLL) 函数的注册号。如果使用字符串，将在当前工作表的上下文中对该字符串求值。
Arg1-Arg30 可选 Variant 应传递给函数的参数。

返回值
Variant

说明
此方法不可使用命名参数，参数必须通过位置进行传递。
Run 方法返回被调用的宏返回的任何值。如果将对象作为参数传递给宏，该对象将转换为相应的值（通过对该对象应用 Value 属性）。这意味着不能用 Run 方法将对象传递给宏。

*****************************************************
判断Run返回值可以知道是否运行正确。
Sub test()
     ret = Application.Run("test1(1,2)")       '错误写法，会导致两次调用
     MsgBox CStr(ret)                                 'Error 2015
     ret = Application.Run("test1", 1, 2)      '正确写法
     MsgBox CStr(ret)
      ret = Application.Run("'test1  1, 2'")   '另一种写法
     MsgBox CStr(ret)
End Sub

Sub test1(x As Integer, y As Integer)
    a = x + y
    MsgBox a
End Sub
         

zhaogang1960

请参考:
Application.Run "'" & ThisWorkbook.Path & "\" & "Book1.xls'!Macro1"

liucqa

zhaogang1960 发表于 2011-12-13 16:06
请参考:
Application.Run "'" & ThisWorkbook.Path & "\" & "Book1.xls'!Macro1"

如果我已经有了打开文件的workbook对象，假设是wb，调用wb.sheet1里面的宏Macro1

.run 如何写？

我试了   Application.Run "'" & wb.fullname &  "'!sheet1.Macro1"   不行

excelhomeljch

wb.sheet1里面的宏?
宏哪有分是哪个sheet的,除非是事件.

Application.Run   wb.name &  "'!Macro1"
即可

excelhomeljch

liucqa 发表于 2011-12-13 21:52
写在sheet中的宏不能直接调用，一般用sheet1.micro1的方式。

你在sheet里面写个宏，然后在菜单里面选开 ...

的确是,那就简单,注意Sheet中首字母大写
Application.Run   wb.name &  "'!Sheet1.Macro1"

liucqa

excelhomeljch 发表于 2011-12-13 21:39
wb.sheet1里面的宏?
宏哪有分是哪个sheet的,除非是事件.

写在sheet中的宏不能直接调用，一般用sheet1.micro1的方式。

你在sheet里面写个宏，然后在菜单里面选开发工具-宏，看看就明白了

liucqa

excelhomeljch 发表于 2011-12-13 21:57
的确是,那就简单,注意Sheet中首字母大写
Application.Run   wb.name &  "'!Sheet1.Macro1"

试过了，不好用，语句如下

Application.Run "'" & objWB.FullName & "'!Sheet9.rebuildSummary"

zhaogang1960

liucqa 发表于 2011-12-13 20:47
如果我已经有了打开文件的workbook对象，假设是wb，调用wb.sheet1里面的宏Macro1

.run 如何写？

Sub 宏1() 'b.xls不打开状态
    Application.Run "'" & ThisWorkbook.Path & "\" & "b.xls'!sheet1.Macro1"
End Sub

Sub 宏2()
    Dim wb As Workbook
    Set wb = Workbooks.Open(ThisWorkbook.Path & "\b.xls")
    Application.Run "'" & wb.FullName & "'!sheet1.Macro1"
End Sub
或
Sub 宏3()
    Dim wb As Workbook
    Set wb = Workbooks.Open(ThisWorkbook.Path & "\b.xls")
    Application.Run "'" & wb.Name & "'!sheet1.Macro1"
End Sub

excelhomeljch

liucqa 发表于 2011-12-13 22:07
试过了，不好用，语句如下

Application.Run "'" & objWB.FullName & "'!Sheet9.rebuildSummary"

不好用?方法是你选择的
为什么你还是用fullname?我的回答是name