关于添加右键菜单的问题【有新疑问，见12楼，谢谢】

zhengrui-csb

如何添加多个右键菜单以及下一级的右键菜单【二级菜单的功能】，谢谢
【已解决，感谢：小fisher】

[ 本帖最后由 zhengrui-csb 于 2010-6-28 09:51 编辑 ]

dddw88

关注一下

Excel2003初学者

进来看看

[ 本帖最后由 Excel2003初学者 于 2010-6-26 00:34 编辑 ]

zhengrui-csb

哪位高手给支个招啊？

zhengrui-csb

哪位高手给支个招啊？谢谢

小fisher

'在单元格右键菜单中添加二级菜单
Sub addMenuItem()
    Dim oSubMenu As CommandBarPopup
    Dim oMenuItem As CommandBarButton
    Set oSubMenu = Application.CommandBars("cell").Controls.Add(msoControlPopup)
    oSubMenu.Caption = "导出选定区域..."
    oSubMenu.Tag = "Custom"
    Set oMenuItem = oSubMenu.Controls.Add(msoControlButton)
    oMenuItem.Caption = "文本文件"
    oMenuItem.OnAction = "ExportTxt"
    Set oMenuItem = oSubMenu.Controls.Add(msoControlButton)
    oMenuItem.Caption = "CSV文件"
    oMenuItem.OnAction = "ExportCSV"
End Sub


'去除单元格右键菜单中添加的二级菜单
'注：这里没有使用CommandBars("cell").Reset来恢复单元格右键菜单，是为了避免误删其他加载宏向菜单中添加的项目
Sub removeMenuItem()
    Dim oMenuItem As CommandBarControl
    For Each oMenuItem In CommandBars("cell").Controls
        If oMenuItem.Tag = "Custom" Then
            oMenuItem.Delete
        End If
    Next
End Sub

[ 本帖最后由 小fisher 于 2010-6-23 12:27 编辑 ]

zhengrui-csb

楼上高手太厉害了 万分感谢
请问如何将右键菜单中其他内容删除 只保留自定义的菜单 还比如我要在右键菜单中作两个选项怎么弄  谢谢

[ 本帖最后由 zhengrui-csb 于 2010-6-23 12:40 编辑 ]

小fisher

原帖由 zhengrui-csb 于 2010-6-23 12:38 发表
楼上高手太厉害了 万分感谢
请问如何将右键菜单中其他内容删除 只保留自定义的菜单 还比如我要在右键菜单中作两个选项怎么弄  谢谢

问：“何将右键菜单中其他内容删除 只保留自定义的菜单”？
答：这个可以实现，但不建议修改系统内置菜单，因为这样会影响到整个程序进程内的所有工作表，建议在工作表代码模块中使用以下代码屏蔽默认的单元格右键菜单，弹出自定义菜单，这样做的好处是菜单变动是局部性、临时性的，不会影响其他工作簿、工作表和整个工作环境：

Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, Cancel As Boolean)

Dim oPopup As CommandBar

Dim oSubMenu As CommandBarPopup

Dim oMenuItem As CommandBarControl

Cancel = True



On Error Resume Next

CommandBars("myRightMenu").Delete

On Error GoTo 0

Set oPopup = CommandBars.Add("myRightMenu", msoBarPopup)



Set oSubMenu = oPopup.Controls.Add(msoControlPopup)

oSubMenu.Caption = "一级子菜单1"

Set oMenuItem = oSubMenu.Controls.Add(msoControlButton)

oMenuItem.Caption = "菜单项1-1"

Set oMenuItem = oSubMenu.Controls.Add(msoControlButton)

oMenuItem.Caption = "菜单项1-2"

Set oMenuItem = oSubMenu.Controls.Add(msoControlButton)

oMenuItem.Caption = "菜单项1-3"



Set oSubMenu = oPopup.Controls.Add(msoControlPopup)

oSubMenu.Caption = "一级子菜单2"

Set oMenuItem = oSubMenu.Controls.Add(msoControlButton)

oMenuItem.Caption = "菜单项2-1"

Set oMenuItem = oSubMenu.Controls.Add(msoControlButton)

oMenuItem.Caption = "菜单项2-2"

Set oMenuItem = oSubMenu.Controls.Add(msoControlButton)

oMenuItem.Caption = "菜单项2-3"



oPopup.ShowPopup

oPopup.Delete
End Sub

zhengrui-csb

楼上的是放到 thisworkbook中吗？还是怎么弄？您是否可以帮我做个示例 我弄完没反应 还把以前的给带出来了

小fisher

CustomMenu.rar (9.45 KB, 下载次数: 308)

2010-6-23 16:19 上传

点击文件名下载附件

[ 本帖最后由 小fisher 于 2010-6-23 16:19 编辑 ]