方法"Paste"作用于对象_WorkSheet时失败

civim2000

我想实现把"原始单据.xls"里的"询价"工作表的所有文字和图片，拷贝到"单据汇总.xls"的表X00001中
可是，运行到下面红色代码newSh.Paste时报错，
“方法"Paste"作用于对象_WorkSheet时失败”


高手帮看下怎么回事？
源文件见附件。


代码如下

Sub 按钮2_单击()
  Application.DisplayAlerts = False
  Dim 询价单号 As String
  询价单号 = "X00001"

Rem 先拷贝
     Cells.Select
    Selection.Copy
  
Rem 检查"单据汇总.xls"是否打开
  Dim i As Integer
     Dim newSh As Worksheet
     Dim isOpen As Integer
     isOpen = 0
     For i = 1 To Workbooks.Count
         If Workbooks(i).Name = "工作表.xls" Then
              isOpen = 1
         End If
     Next
Rem 没有打开则打开"单据汇总.xls"
    If isOpen = 0 Then
         Workbooks.Open ThisWorkbook.Path & "\单据汇总.xls"
    End If
   

    Workbooks("单据汇总.xls").Activate
   
      Rem 检查"单据汇总.xls"中是否有以询价单号X00001为名称的工作表,有则删除
    For j = 1 To Worksheets.Count
          If Worksheets(j).Name = 询价单号 Then
                  Worksheets(j).Delete
           Exit For
            End If
      Next
Rem 添加工作表X00001
     Set newSh = Worksheets.Add(after:=Worksheets(Worksheets.Count))
    newSh.Name = 询价单号
   newSh.Activate
rem 下面这句报错
       newSh.Paste

   Rem 关闭
   Workbooks("单据汇总.xls").Close SaveChanges:=True
     Application.DisplayAlerts = True
End Sub

lbpp

Sub 按钮2_单击()
    Application.DisplayAlerts = False
    Dim 询价单号 As String
    询价单号 = "X00001"
    Dim rngSource As Range
    Set rngSource = Cells

    Rem 先拷贝
'    Cells.Select
'    Selection.Copy
    Rem 检查"单据汇总.xls"是否打开
    Dim i As Integer
    Dim newSh As Worksheet
    Dim isOpen As Integer
    isOpen = 0
    For i = 1 To Workbooks.Count
        If Workbooks(i).Name = "工作表.xls" Then
            isOpen = 1
        End If
    Next
    Rem 没有打开则打开
    If isOpen = 0 Then
        Workbooks.Open ThisWorkbook.Path & "\单据汇总.xls"
    End If

    Workbooks("单据汇总.xls").Activate
    Rem 检查"单据汇总.xls"中是否有以询价单号为名称的工作表,有则删除
    For j = 1 To Worksheets.Count
        If Worksheets(j).Name = 询价单号 Then
            Worksheets(j).Delete
            Exit For
        End If
    Next
    Rem 添加工作表
    Set newSh = Worksheets.Add(after:=Worksheets(Worksheets.Count))
    newSh.Name = 询价单号
    newSh.Activate
   
    rngSource.Copy
    newSh.Paste
    Rem 关闭
    Workbooks("单据汇总.xls").Close SaveChanges:=True
    Application.DisplayAlerts = True
End Sub

cflood

ThisWorkbook.Worksheets("询价").Cells.Copy
    newSh.Paste
拷贝得太早了，到粘贴时复制模式已经没有了。

lb_bn

paste之前先激活工作表。

kevinchengcw

试一下
newSh.[a1].Paste

可能复制的是单元格,粘贴时要指定个开始的单元格吧

civim2000

谢谢小熊加加,成功！
也谢谢以上的各位！

缪飞

civim2000 发表于 2010-3-20 21:25
谢谢小熊加加,成功！
也谢谢以上的各位！

我也遇到了同样的问题，请问怎么解决的。感谢